EXCEL возвращает диапазон значений на основе критериев

Question

У меня есть функция VBA, которой я хотел бы передавать пользовательский диапазон данных (в отличие от полного диапазона столбцов таблицы) только при соблюдении определенных критериев в этой таблице.Например:

          Table_1                            Table_2
    A        B         C                A          B
1 Policy    Data     Status     |   1 Policy    Function
  --------------------------    |     -------------------
2   AA      25      approved    |   2   AA      [25, 35]
3   AA      19      unapproved  |   3   BB      [16]
4   BB      16      approved    |
5   CC      27      approved    |
6   CC      30      unapproved  |
7   AA      35      approved

В таблице 2, ячейка B2, я хотел бы вернуть диапазон всех значений Data из таблицы Table1, где Policy = AA и Status = approved.Впоследствии в ячейке B3 диапазон значений, где Policy = BB и Status = approved и т. Д.

Возможно ли это с формулой?

Answer 1

Если у вас Office 365 Excel или более поздней версии, вы можете использовать TEXTJOIN в качестве формулы массива:

="[" & TEXTJOIN(",",TRUE,IF(($A$2:$A$7=F2)*($C$2:$C$7="approved"),$B$2:$B$7,"")) & "]"

Будучи формулой массива, ее необходимо подтвердить с помощью Ctrl-Shift-Enter вместо Enter при выходе из редактированияmode.

---

Если у вас не установлен Office 365 Excel или более поздней версии, вот UDF, который будет делать то, что вы хотите:

Function TEXTJOINIFS(rng As Range, delim As String, ParamArray arr() As Variant)
    Dim rngarr As Variant
    rngarr = Intersect(rng, rng.Parent.UsedRange).Value

    Dim condArr() As Boolean
    ReDim condArr(1 To Intersect(rng, rng.Parent.UsedRange).Rows.Count) As Boolean


    Dim i As Long
    For i = LBound(arr) To UBound(arr) Step 2
        Dim colArr() As Variant
        colArr = Intersect(arr(i), arr(i).Parent.UsedRange).Value
        Dim j As Long
        For j = LBound(colArr, 1) To UBound(colArr, 1)

            If Not condArr(j) Then
                Dim charind As Long
                charind = Application.Max(InStr(arr(i + 1), ">"), InStr(arr(i + 1), "<"), InStr(arr(i + 1), "="))
                Dim opprnd As String
                If charind = 0 Then
                    opprnd = "="
                Else
                    opprnd = Left(arr(i + 1), charind)
                End If
                Dim t As String
                t = """" & colArr(j, 1) & """" & opprnd & """" & Mid(arr(i + 1), charind + 1) & """"
                If Not Application.Evaluate(t) Then condArr(j) = True
            End If
        Next j
    Next i

    For i = LBound(rngarr, 1) To UBound(rngarr, 1)
        If Not condArr(i) Then
            TEXTJOINIFS = TEXTJOINIFS & rngarr(i, 1) & delim
        End If
    Next i

    TEXTJOINIFS = Left(TEXTJOINIFS, Len(TEXTJOINIFS) - Len(delim))

End Function

Вы бы назвали его похожим на SUMIFS:

=TEXTJOINIFS(B:B,",",A:A,F2,C:C,"approved")

Работает только со столбцами, а не со строками.