Как сохранить отчет MS Access в формате PDF / A (архивная версия PDF ISO 19005)

Question

Мой клиент попросил, чтобы я вывел отчет MS-Access в формате PDF / A (Архивная версия PDF ISO 19005).Я нашел старую ветку 2008 года, в которой говорится, что это можно сделать в Word, Excel, PPT, Publisher, Visio и Infopath, но не в Access.Я надеюсь, что у кого-то будет недавнее обновление, что теперь это возможно.

В настоящее время мой код

 'output report to pdf
DoCmd.OutputTo acOutputReport, strReportName, acFormatPDF, strPDF, False, , , acExportQualityPrint

, который отлично подходит для создания обычных PDF-файлов.

Answer 1

Это длинный план, и он не изящен, но, возможно, может сработать для вас:

Экспортируйте отчет в виде обычного файла PDF, а затем с помощью автоматизации Word откройте файл и экспортируйте его в формате PDF / A..

Каким-то образом формат запутался в процессе, поэтому сведите его к минимуму в отчете о доступе.

Sub ExportPDF_A()

    ' Set references in VBA IDE to MS Word before executing this code

    ' Declare object variables
    Dim wordApp As New Word.Application
    Dim wordDoc As Word.Document

    ' Declare other variables
    Dim strReportName As String
    Dim strPDF As String

    ' Customize variables
    strReportName = "TableReport"
    strPDF = "E:\Temp\pdfreport.pdf"

    'output report to pdf
    DoCmd.OutputTo acOutputReport, strReportName, acFormatPDF, strPDF, False, , , acExportQualityPrint

    ' Temporary set word visible (because there are some confirmation in the next step)
    wordApp.Visible = True

    ' Here are some additional confirmations that you'd have to figure out how to overcome them
    Set wordDoc = wordApp.Documents.Open(FileName:=strPDF, Format:="PDF Files", ConfirmConversions:=False)

    ' Export to the desired format
    wordDoc.ExportAsFixedFormat OutputFileName:="E:\Temp\pdfreportPDFA.pdf", ExportFormat:=WdExportFormat.wdExportFormatPDF, OpenAfterExport:=True, UseISO19005_1:=True


End Sub

Я не тратил много времени на его кодированиетак что, если это сработает, дайте мне знать, и я смогу отполировать.