Использовать beginBitmapFill с существующим мувиклипом / формой?(Animate CC)

Question

Все учебники по использованию beginBitmapFill, по-видимому, сосредоточены вокруг динамического рисования объекта.Можно ли просто применить растровое заполнение к существующей фигуре, которая находится внутри фрагмента ролика?Я знаю, что могу сделать это вручную, выбрав форму и выбрав растровое изображение на панели «Цвет». Но возможно ли это сделать с помощью кода?Это то, что я пытаюсь, и это не дает ошибок, но это также не работает:

grl.tops.shapes.graphics.beginBitmapFill(new cubepattern(), null, true, false);

Answer 1

Как прокомментировали другие, вы можете использовать readGraphicsData и drawGraphicsData соответственно.Это даже не слишком сложно.Просто переберите IGraphicsData нужной формы, остановитесь, как только вы найдете экземпляр класса GraphicsBitmapFill, создайте новый экземпляр с другим BitmapFill и, наконец, примените изменения к исходной форме.

Хорошо,одна картинка стоит тысячи слов.Вот пример.Это может показаться немного длинным, но есть всего много кода для подготовки формы и загрузки изображений для использования в качестве растровых заливок.

Обратите внимание на функцию process () .

package
{
    import flash.display.Sprite;
    import flash.display.Shape;
    import flash.display.Graphics;
    import flash.display.Loader
    import flash.display.LoaderInfo;
    import flash.display.IGraphicsData;
    import flash.display.GraphicsBitmapFill;
    import flash.display.Bitmap;
    import flash.display.BitmapData;
    import flash.events.Event;
    import flash.net.URLRequest;
    import flash.utils.getQualifiedClassName;

    public class Main extends Sprite
    {
        private var bitmapData1:BitmapData;
        private var bitmapData2:BitmapData;
        private var masterSprite:Sprite = new Sprite();
        private var texturesLoaded:int = 0;
        private var loader:Loader = new Loader();

        public function Main():void
        {
            if (stage)
                init();
            else
                addEventListener(Event.ADDED_TO_STAGE, init);
        }

        private function init(e:Event = null):void
        {
            removeEventListener(Event.ADDED_TO_STAGE, init);
            loader.contentLoaderInfo.addEventListener(Event.COMPLETE, onComplete);
            loader.load(new URLRequest("textureA.jpg"));
            addChild(masterSprite);
            masterSprite.x = masterSprite.y = 200;
        }

        private function onComplete(event:Event):void
        {
            switch (texturesLoaded)
            {
                case 0: 
                    bitmapData1 = Bitmap(LoaderInfo(event.target).content).bitmapData;
                    loader.load(new URLRequest("textureB.jpg"));
                    break;
                case 1: 
                    bitmapData2 = Bitmap(LoaderInfo(event.target).content).bitmapData;
                    loader.contentLoaderInfo.removeEventListener(Event.COMPLETE, onComplete);
                    drawStar();
                    process();
            }
            texturesLoaded++;
        }

        private function process():void
        {
            var tempShape:Shape = Shape(masterSprite.getChildAt(0));

            var graphicsData:Vector.<IGraphicsData> = tempShape.graphics.readGraphicsData();
            for (var a:int = 0; a < graphicsData.length; a++)
            {
                if (getQualifiedClassName(graphicsData[a]) == "flash.display::GraphicsBitmapFill")
                {
                    var bitmapFill:GraphicsBitmapFill = new GraphicsBitmapFill(bitmapData2);
                    graphicsData[a] = bitmapFill; break;
                }
            }
            tempShape.graphics.drawGraphicsData(graphicsData);
        }

        private function drawStar():void
        {
            var angles:Array = new Array(0, 36, 72, 108, 144, 180, 216, 252, 288, 324, 360);
            var innerRadius:int = 40;
            var outerRadius:int = 80;
            var shape:Shape = new Shape();
            shape.graphics.beginBitmapFill(bitmapData1);
            shape.graphics.moveTo(0 + Math.cos(angles[a] * (Math.PI / 180)) * outerRadius, 0 + Math.sin(angles[a] * (Math.PI / 180)) * outerRadius);
            for (var a:int = 0; a < angles.length; a++)
            {
                angles[a] -= 90;
                if (a % 2 == 0)
                {
                    shape.graphics.lineTo(0 + Math.cos(angles[a] * (Math.PI / 180)) * outerRadius, 0 + Math.sin(angles[a] * (Math.PI / 180)) * outerRadius);
                }
                else
                {
                    shape.graphics.lineTo(0 + Math.cos(angles[a] * (Math.PI / 180)) * innerRadius, 0 + Math.sin(angles[a] * (Math.PI / 180)) * innerRadius);
                }
            }
            shape.graphics.endFill();
            masterSprite.addChild(shape);
        }
    }
}