xPath, XSLT.Получить максимум по атрибуту в другом наборе узлов

Question

У меня есть:

<Data>
  <DocumentCodebook>
    <C4505>
      <Item Value="1" ABSpriority="1" />
      <Item Value="2" ABSpriority="4" />
      <Item Value="3" ABSpriority="2" />
      <Item Value="4" ABSpriority="3"/>
    </C4505>
  <DocumentCodebook>
  <ApplicationData>
     <SelectedInsurance>
        <Insurance ProductId="2"/>
        <Insurance ProductId="3"/>
        <Insurance ProductId="1"/>
     </SelectedInsurance>
  </ApplicationData>
 </Data>

Мне нужно получить Данные / ApplicationData / SelectedInsurance / Insurance / @ ProductId , которые имеют самый высокий @ ABSpriority в C4505.@ Значение похоже на @ProductId.

Для этого xml результат равен "2".Потому что ProductId = "2" имеют самый высокий ABSPriority = "4" (больше, чем ProductId = 1 и 3).

Пример 2

<Data>
  <DocumentCodebook>
    <C4505>
      <Item Value="1" ABSpriority="1" />
      <Item Value="2" ABSpriority="4" />
      <Item Value="3" ABSpriority="2" />
      <Item Value="4" ABSpriority="3"/>
    </C4505>
  <DocumentCodebook>
  <ApplicationData>
     <SelectedInsurance>
        <Insurance ProductId="1"/>
        <Insurance ProductId="4"/>
     </SelectedInsurance>
  </ApplicationData>
 </Data>

Результат равен "4" .ProductId = "4" имеет самый высокий ABSPriority = "3".

Answer 1

Я нашел способ сделать это.Результат в элементе Insurance_Type .

<xsl:variable name="ProductList">
    <xsl:for-each select="/Data/ApplicationData/SelectedInsurance/Insurance">
        <xsl:if test="position()!=1">
            <!--<xsl:value-of select=","/>-->
            <xsl:value-of select="&quot;,&quot;" />
        </xsl:if>
        <!--<xsl:value-of select="@ProductId"/>-->
        <xsl:value-of select="@ProductId" />
    </xsl:for-each>
</xsl:variable>
<xsl:variable name="MaxABS" select="max(/Data/DocumentCodebook/C4505/Item[contains($ProductList,@Value)]/@ABSpriority)" />
<xsl:element name="Types">
    <xsl:element name="Insurance_Type">
        <xsl:value-of select="/Data/DocumentCodebook/C4505/Item[@ABSpriority=$MaxABS]/@Value" />
    </xsl:element>
</xsl:element>

Answer 2

Во-первых, вы должны использовать ключи для разрешения перекрестных ссылок.

Теперь, поскольку нам говорят, что XSLT 2.0 здесь не дает особых преимуществ, я бы вернулся к более примитивному методу, использующему XSLT 1.0:

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>
<xsl:strip-space elements="*"/>

<xsl:key name="item" match="Item" use="@Value" />

<xsl:template match="/Data">
    <result>
        <xsl:for-each select="ApplicationData/SelectedInsurance/Insurance">
            <xsl:sort select="key('item', @ProductId)/@ABSpriority" data-type="number" order="descending"/>
            <xsl:if test="position() = 1">
                <xsl:value-of select="@ProductId"/>
            </xsl:if>
        </xsl:for-each>
    </result>
</xsl:template>

</xsl:stylesheet>

---

Обратите внимание, что это предполагаетбудет только один Insurance с максимальным ABSpriority.В случае связи будет возвращен только первый в порядке документа.

Answer 3

Учитывая последовательность узлов S, чтобы найти узел, который имеет наибольшее значение для некоторой величины Q, «грубый» способ сделать это -

<xsl:variable name="max" selecy="max(S / Q)"/>
<xsl:for-each select="S[Q = $max]">...</xsl:for-each>

Это не очень элегантно, поскольку включает обработку Sдважды.Saxon имеет функцию более высокого порядка saxon: самый высокий (), которая делает это за один шаг, но включает в себя расширения (и функции более высокого порядка), поэтому она работает только в коммерческих версиях продукта.

Другой способ сделать это за один проход - с помощью рекурсии.

<xsl:function name="f:highest">
  <xsl:param name="input" as="node()*"/>
  <xsl:param name="max-so-far"/>
  <xsl:param name="top-nodes"/>
  <xsl:choose>
    <xsl:when test="empty($input)">
      <xsl:sequence select="$top-nodes"/>
    </xsl:when>
    <xsl:when test="Q($input[1]) = $max-so-far">
      <xsl:sequence select="f:highest(remove($input, 1), $max-so-far, ($top-nodes, $input[1])"/>
    </xsl:when>
    <xsl:when test="Q($input[1]) > $max-so-far">
      <xsl:sequence select="f:highest(remove($input, 1), Q($input[1]), $input[1]"/>
    </xsl:when>
    <xsl:otherwise>
      <xsl:sequence select="f:highest(remove($input, 1), $max-so-far, $top-nodes"/>
    </xsl:otherwise>
</xsl:function>

Здесь Q (узел) представляет любое выражение, которое вы оцениваете на узле, чтобы получить интересующее значение, например, number($node/@ABSPriority).

В XSLT 3.0 вы можете заменить рекурсивную функцию эквивалентным циклом xsl: iterate.