Чистое обновление полей класса deftype'd - PullRequest
Новая
       26

Чистое обновление полей класса deftype'd

0 голосов
/ 30 мая 2018

Я впервые использую deftype, потому что пишу очередь с приоритетами, а defrecord мешает реализации ISeq.

Чтобы избежать необходимости деконструкции "«Класс, изменить поле и« реконструировать »его с помощью явных обращений к его конструктору постоянно , я обнаружил, что мне нужно написать update -подобные функции для каждого поля, которое мне нужно alter: 

(deftype Priority-Queue [root size priority-comparator])

(defn- alter-size [^Priority-Queue queue, f]
  (->Priority-Queue (.root queue) (f (.size queue)) (.priority_comparator queue)))

(defn- alter-root [^Priority-Queue queue, f]
  (->Priority-Queue (f (.root queue)) (.size queue) (.priority_comparator queue)))

Конечно, я мог бы написать функцию, позволяющую использовать синтаксис ближе к update, но необходимость в этом вообще напоминает запах.

Это типичный способ изменитьне-запись?Я извлек столько, сколько могу в другом месте, поэтому количество раз, которое мне нужно для изменения самой очереди, ограничено несколькими местами, но все равно кажется громоздким.Является ли единственным чистым решением написать функцию / макрос, подобный Scala copy для классов case ?

1 Ответ

0 голосов
/ 31 мая 2018

Я бы предложил создать для этого какой-нибудь макрос. Я закончил с этим: 

(defmacro attach-updater [deftype-form]
  (let [T (second deftype-form)
        argnames (nth deftype-form 2)
        self (gensym "self")
        k (gensym "k")
        f (gensym "f")
        args (gensym "args")]
    `(do ~deftype-form
         (defn ~(symbol (str "update-" T))
           ^{:tag ~T} [^{:tag ~T} ~self ~k ~f & ~args]
           (new ~T ~@(map (fn [arg]
                            (let [k-arg (keyword arg)]
                              `(if (= ~k ~k-arg)
                                 (apply ~f (. ~self ~arg) ~args)
                                 (. ~self ~arg))))
                          argnames))))))

он просто обрабатывает список аргументов формы deftype и создает функцию update-%TypeName%, котораяимеет семантику, аналогичную простой update, с использованием варианта ключевого слова для имени поля и возвращает клон объекта с измененным полем.

быстрый пример: 

(attach-updater
 (deftype MyType [a b c]))

, который расширяется доследующее: 

(do
  (deftype MyType [a b c])
  (defn update-MyType [self14653 k14654 f14655 & args14656]
    (new
      MyType
      (if (= k14654 :a)
        (apply f14655 (. self14653 a) args14656)
        (. self14653 a))
      (if (= k14654 :b)
        (apply f14655 (. self14653 b) args14656)
        (. self14653 b))
      (if (= k14654 :c)
        (apply f14655 (. self14653 c) args14656)
        (. self14653 c)))))

и может использоваться следующим образом: 

(-> (MyType. 1 2 3)
    (update-MyType :a inc)
    (update-MyType :b + 10 20 30)
    ((fn [item] [(.a item) (.b item) (.c item)])))
;;=> [2 62 3]

(attach-updater
  (deftype SomeType [data]))

(-> (SomeType. {:a 10 :b 20})
    (update-SomeType :data assoc :x 1 :y 2 :z 3)
    (.data))
;;=> {:a 10, :b 20, :x 1, :y 2, :z 3}

Вы также можете избежать генерации функции update-%TypeName% для каждого типа, используя протокол (скажем Reconstruct) и autoреализовав его в макросе, но это лишит вас возможности использовать varargs, поскольку они не поддерживаются для функций протокола (например, вы не сможете сделать это: (update-SomeType :data assoc :a 10 :b 20 :c 30))

ОБНОВЛЕНИЕ

есть также один способ, которым я могу придумать, чтобы вообще не использовать здесь макрос.Хотя он обманчив (поскольку использует метаданные конструктора ->Type), а также, вероятно, медленный (так как он также использует отражение).Но все равно он работает: 

(defn make-updater [T constructor-fn]
  (let [arg-names (-> constructor-fn meta :arglists first)]
    (fn [self k f & args]
      (apply constructor-fn
             (map (fn [arg-name]
                    (let [v (-> T (.getField (name arg-name)) (.get self))]
                      (if (= (keyword (name arg-name))
                             k)
                        (apply f v args)
                        v)))
                  arg-names)))))

и может использоваться следующим образом: 

user> (deftype TypeX [a b c])
;;=> user.TypeX

user> (def upd-typex (make-updater TypeX #'->TypeX))
;;=> #'user/upd-typex

user> (-> (TypeX. 1 2 3)
          (upd-typex :a inc)
          (upd-typex :b + 10 20 30)
          (#(vector (.a %) (.b %) (.c %))))
;;=> [2 62 3]
...