Джулия: почему многопоточность разделяемой памяти не дает мне ускорения? - PullRequest
Новая
       42

Джулия: почему многопоточность разделяемой памяти не дает мне ускорения?

0 голосов
/ 01 октября 2018

Я хочу использовать многопоточность совместно используемой памяти в Julia.Как и в макросе Threads. @ Threads, я могу использовать ccall (: jl_threading_run ...) для этого.И хотя мой код теперь работает параллельно, я не получил ожидаемого ускорения.

Следующий код предназначен в качестве минимального примера подхода, который я использую, и проблемы с производительностью, которую я испытываю: [РЕДАКТИРОВАТЬ: см. Позже для еще более минимального примера] 

nthreads = Threads.nthreads()
test_size = 1000000
println("STARTED with ", nthreads, " thread(s) and test size of ", test_size, ".")
# Something to be processed:
objects = rand(test_size)
# Somewhere for our results
results = zeros(nthreads)
counts = zeros(nthreads)
# A function to do some work.
function worker_fn()
    work_idx = 1
    my_result = results[Threads.threadid()]
    while work_idx > 0
        my_result += objects[work_idx]
        work_idx += nthreads
        if work_idx > test_size
            break
        end
        counts[Threads.threadid()] += 1
    end
end

# Call our worker function using jl_threading_run
@time ccall(:jl_threading_run, Ref{Cvoid}, (Any,), worker_fn)

# Verify that we made as many calls as we think we did.
println("\nCOUNTS:")
println("\tPer thread:\t", counts)
println("\tSum:\t\t", sum(counts))

На i7-7700 типичный однопоточный результат: 

STARTED with 1 thread(s) and test size of 1000000.
 0.134606 seconds (5.00 M allocations: 76.563 MiB, 1.79% gc time)

COUNTS:
    Per thread:     [999999.0]
    Sum:            999999.0

И с 4 потоками: 

STARTED with 4 thread(s) and test size of 1000000.
  0.140378 seconds (1.81 M allocations: 25.661 MiB)

COUNTS:
    Per thread:     [249999.0, 249999.0, 249999.0, 249999.0]
    Sum:            999996.0

Многопоточность замедляет работу!Почему?

РЕДАКТИРОВАТЬ: можно создать лучший минимальный пример самого макроса @threads. 

a = zeros(Threads.nthreads())
b = rand(test_size)
calls = zeros(Threads.nthreads())
@time Threads.@threads for i = 1 : test_size
    a[Threads.threadid()] += b[i]
    calls[Threads.threadid()] += 1
end

Я ошибочно предположил, что включение макроса @threads в Юлию означало бы, что было преимущество длябыть имел.

1 Ответ

0 голосов
/ 01 октября 2018

Скорее всего, у вас есть проблема ложное совместное использование .

Вы можете решить эту проблему, разделив области, которые вы пишете, на достаточно большое расстояние, как это (вот «быстрая и грязная» реализация)чтобы показать суть изменения): 

julia> function f(spacing)
           test_size = 1000000
           a = zeros(Threads.nthreads()*spacing)
           b = rand(test_size)
           calls = zeros(Threads.nthreads()*spacing)
           Threads.@threads for i = 1 : test_size
               @inbounds begin
                   a[Threads.threadid()*spacing] += b[i]
                   calls[Threads.threadid()*spacing] += 1
               end
           end
           a, calls
       end
f (generic function with 1 method)

julia> @btime f(1);
  41.525 ms (35 allocations: 7.63 MiB)

julia> @btime f(8);
  2.189 ms (35 allocations: 7.63 MiB)

или выполнение накопления для каждого потока для локальной переменной, как это (это предпочтительный подход, поскольку он должен быть равномерно быстрее): 

function getrange(n)
    tid = Threads.threadid()
    nt = Threads.nthreads()
    d , r = divrem(n, nt)
    from = (tid - 1) * d + min(r, tid - 1) + 1
    to = from + d - 1 + (tid ≤ r ? 1 : 0)
    from:to
end

function f()
    test_size = 10^8
    a = zeros(Threads.nthreads())
    b = rand(test_size)
    calls = zeros(Threads.nthreads())
    Threads.@threads for k = 1 : Threads.nthreads()
        local_a = 0.0
        local_c = 0.0
        for i in getrange(test_size)
            for j in 1:10
                local_a += b[i]
                local_c += 1
            end
        end
        a[Threads.threadid()] = local_a
        calls[Threads.threadid()] = local_c
    end
    a, calls
end

Также обратите внимание, что вы, вероятно, используете 4 шага на машине с 2 физическими ядрами (и только 4 виртуальными ядрами), поэтому выигрыш от потоков не будет линейным.

...