Excel VBA - хранимая процедура (SQL Server)

Question

У меня небольшая проблема с получением нескольких наборов записей (с именами столбцов) и вставкой данных в лист Excel, как показано на рисунке ниже

Код VBA, который у меня только что получает первый набор записей, но не остальные

Любая помощь будет высоко ценится, спасибо

Sub CProcedure()

    Dim Conn As ADODB.Connection, RecordSet As ADODB.RecordSet
    Dim Command As ADODB.Command
    Dim ConnectionString As String, StoredProcName As String
    Dim range1 As ADODB.Parameter, range2 As ADODB.Parameter
    Dim SP_Param1 As String
    Dim SP_Param2 As String

    Application.ScreenUpdating = False

    Set Conn = New ADODB.Connection
    Set RecordSet = New ADODB.RecordSet
    Set Command = New ADODB.Command

    ServerName = "1111"
    DatabaseName = "dataReporting"
    UserId = "88888"
    Password = "88888"
    SP_Param1 = "StartDate"
    SP_Param2 = "EndDate"
    StoredProcName = "KPI_Report"

    ConnectionString = "PROVIDER=SQLOLEDB;DATA SOURCE=" & ServerName & _
                       ";INITIAL CATALOG=" & DatabaseName & "; User Id=" & _
                       UserId & "; Password=" & Password & ";"
    Conn.Open ConnectionString

    With Command
        .ActiveConnection = Conn
        .CommandType = adCmdStoredProc
        .CommandText = StoredProcName
        .CommandTimeout = 0
    End With

    Set range1 = Command.CreateParameter(SP_Param1, adDBDate, adParamInput, , DateSerial(2018, 1, 1))
    Command.Parameters.Append range1

    Set range2 = Command.CreateParameter(SP_Param2, adDBDate, adParamInput, , DateSerial(2018, 4, 1))
    Command.Parameters.Append range2

    Set RecordSet = Command.Execute
    Sheets("Sheet1").Range("A2").CopyFromRecordset RecordSet

    RecordSet.Close
    Conn.Close
    On Error GoTo 0
    Application.ScreenUpdating = True
    Exit Sub


End Sub

Обновление

Я добавил нижецикл, но все равно не повезло

'Loop through recordset and place values
RecordSet.MoveFirst
Do While RecordSet.EOF = False
    For i = 0 To RecordSet.Fields.Count - 1
        ActiveCell.Value = RecordSet.Fields(i).Value
        ActiveCell.Offset(0, 1).Activate
    Next i
    ActiveCell.Offset(1, -i).Activate
RecordSet.MoveNext
Loop

Это код хранимой процедуры:

Sub storedproc()

Dim Conn As ADODB.Connection
Dim ADODBCmd As ADODB.Command
Dim rs As ADODB.RecordSet
Dim i As Integer
Dim sConnect As String

    ServerName = "1111"
    DatabaseName = "dataReporting"
    UserId = "88888"
    Password = "88888"
    SP_Param1 = "StartDate"
    SP_Param2 = "EndDate"
    StoredProcName = "KPI_Report"

 sConnect = "PROVIDER=SQLOLEDB;DATA SOURCE=" & ServerName & 
";INITIAL CATALOG=" & DatabaseName & "; User Id=" & UserId & 
"; Password=" & Password & ";"


'Establish connection
Set Conn = New ADODB.Connection
Conn.ConnectionString = sConnect
Conn.Open

'Open recordset
Set ADODBCmd = New ADODB.Command
ADODBCmd.ActiveConnection = Conn
ADODBCmd.CommandText = StoredProcName
ADODBCmd.CommandType = adCmdStoredProc
ADODBCmd.CommandTimeout = 0

Set range1 = ADODBCmd.CreateParameter(SP_Param1, adDBDate, adParamInput, , DateSerial(2018, 1, 1))
ADODBCmd.Parameters.Append range1

Set range2 = ADODBCmd.CreateParameter(SP_Param2, adDBDate, adParamInput, , DateSerial(2018, 4, 1))
ADODBCmd.Parameters.Append range2

Set rs = ADODBCmd.Execute()

'Loop through recordset and place values
rs.MoveFirst
Do While rs.EOF = False
    For i = 0 To rs.Fields.Count - 1
        ActiveCell.Value = rs.Fields(i).Value  
        ActiveCell.Offset(0, 1).Activate        
    Next i
    ActiveCell.Offset(1, -i).Activate           
rs.MoveNext
Loop


'Clean up
rs.Close
Set rs = Nothing

 End Sub

Answer 1

Ответ S Meaden с упоминанием GetNextRecordSet решает вашу проблему с несколькими наборами записей в результате сохраненного процесса.
Следующий код сбрасывает все наборы записей, включая имена полей, на лист(не забудьте сначала очистить лист, если вы запускаете его несколько раз).

...
Set rs = Command.Execute
Dim startcol As Long
startcol = 1
With ThisWorkbook.Sheets(1)
    Do While Not rs Is Nothing

        Dim col As Long
        For col = 0 To rs.Fields.Count - 1
            .Cells(1, startcol + col) = rs.Fields(col).Name
        Next col
        .Cells(2, startcol).CopyFromRecordset rs

        startcol = startcol + rs.Fields.Count + 1
        Set rs = rs.NextRecordset
    Loop
End With

Answer 2

Таким образом, хранимой процедуре необходимо вернуть более одного набора записей, например

CREATE PROCEDURE GetCarsAndCategories
AS
BEGIN
SELECT * FROM Cars
SELECT * FROM Categories
END

, а затем код VBA первоначально имеет доступ к набору записей Cars и для доступа к набору записей категорий один раз вызывает GetNextRecordSet