Как составить сводную статистическую таблицу

Question

Я хотел бы создать сводную статистическую таблицу, похожую на приведенную ниже:

       Female    Male
p1
p10
p50 
p99 

Однако с estpost и esttab я могу создать только таблицу, подобную следующей:

        (1)         (2)
      p1/p10/p5~99  p1/p10/p5~99
       -3.756124    -4.159476
        1.009338    -1.210738
        .3221763    .2945236
        .8658271    .8658271
        .9871135    .9871135

Я использую следующий код:

estpost summarize math_std if female == 1 , detail
eststo  female

estpost summarize math_std if female == 0 , detail
eststo  male

esttab female male , cells(p1 p10 p50 p95 p99) noobs

Как разместить метки столбцов в нужном месте?

Answer 1

Вот решение, основанное на создании матрицы с соответствующими результатами:

sysuse auto, clear

quietly summarize price if foreign == 1 , detail
matrix foreign = r(p1) \ r(p10) \ r(p50) \ r(p95) \ r(p99)

quietly summarize price if foreign == 0 , detail
matrix domestic = r(p1) \ r(p10) \ r(p50) \ r(p95) \ r(p99)

matrix both = foreign , domestic
matrix rownames both = p1 p10 p50 p95 p99
matrix colnames both = foreign domestic

esttab matrix(both), mlabels(none)

--------------------------------------            
                  foreign     domestic
--------------------------------------
p1                   3748         3291
p10                  3895         3955
p50                  5759       4782.5
p95                 11995        13594
p99                 12990        15906
--------------------------------------