Обработка событий MSWinsock.Winsock в VisualBasic - PullRequest
Новая
       28

Обработка событий MSWinsock.Winsock в VisualBasic

6 голосов
/ 24 сентября 2008

Я пытаюсь обработать событие Winsock_Connect (на самом деле оно мне нужно в макросе Excel), используя следующий код: 

Dim Winsock1 As Winsock 'Object type definition

Sub Init()
    Set Winsock1 = CreateObject("MSWinsock.Winsock") 'Object initialization
    Winsock1.RemoteHost = "MyHost"
    Winsock1.RemotePort = "22"
    Winsock1.Connect

    Do While (Winsock1.State <> sckConnected)
        Sleep 200
    Loop
End Sub

'Callback handler
Private Sub Winsock1_Connect()
    MsgBox "Winsock1::Connect"
End Sub

Но это никогда не идет в подпрограмму Winsock1_Connect, хотя Winsock1.State "Подключен". Я хочу использовать стандартную библиотеку MS, потому что у меня нет прав администратора на моем компьютере, и я не могу зарегистрировать некоторые пользовательские библиотеки. Кто-нибудь может сказать мне, где я не прав?

Ответы [ 2 ]

3 голосов
/ 24 сентября 2008

Вы застряли с помощью MSWinsock?
Здесь - сайт / учебное пособие с использованием пользовательского объекта winsock.

Также ... Вам нужно объявить Winsock1 WithEvents в модуле "Класс": 

Private WithEvents Winsock1 As Winsock

И, наконец, убедитесь, что вы ссылаетесь на элемент управления ocx winsock.
Сервис -> Ссылки -> Обзор ->% SYSEM% \ MSWINSCK.OCX

0 голосов
/ 08 декабря 2014

Документация о Winsock Control :
http://msdn.microsoft.com/en-us/library/aa228119%28v=vs.60%29.aspx
Пример здесь:
http://support.microsoft.com/kb/163999/en-us

Мой короткий пример с обработкой событий в VBscript: 

Dim sock
Set sock = WScript.CreateObject("MSWinsock.Winsock","sock_")
sock.RemoteHost = "www.yandex.com"
sock.RemotePort = "80"
sock.Connect

Dim received
received = 0

Sub sock_Connect()
    WScript.Echo "[sock] Connection Successful!"
    sock.SendData "GET / HTTP/1.1"& vbCrLf & "Host: " & sock.RemoteHost  & vbCrLf & vbCrLf
End Sub

Sub sock_Close()
    WScript.Echo "[sock] Connection closed!"
End Sub

Sub sock_DataArrival(Byval b)
    Dim data
    sock.GetData data, vbString
    received = received + b
    WScript.Echo "---------------------------------------"
    WScript.Echo " Bytes received: " & b  & " ( Total: " & received & " )"
    WScript.Echo "---------------------------------------"
    WScript.Echo data
End Sub

'Wait for server close connection
Do While sock.State <> 8
    rem WScript.Echo sock.State
    WScript.Sleep 1000
Loop

Вывод будет:

cscript /nologo sockhttp.vbs

[sock] Connection Successful!
-------------------------------
 Bytes received: 1376 ( Total: 1376 )
-------------------------------
HTTP/1.1 200 Ok
Date: Mon, 08 Dec 2014 15:41:36 GMT
Content-Type: text/html; charset=UTF-8
Cache-Control: no-cache,no-store,max-age=0,must-revalidate
Expires: Mon, 08 Dec 2014 15:41:36 GMT
...
...