Функция PL / SQL возвращает исключение пользовательского типа - PullRequest
Новая
       55

Функция PL / SQL возвращает исключение пользовательского типа

0 голосов
/ 05 декабря 2018

Я создал пакет, который содержит пользовательский тип и функцию, которая возвращает пользовательский тип, как показано ниже; 

create or replace 
PACKAGE INHOUSE_CUST_API
AS
TYPE doc_rec
IS
  RECORD
  (
    doc_Title    doc_issue_reference.title%Type,
    doc_Number   DOC_ISSUE_REFERENCE.DOC_NO%TYPE,
    doc_Type    DOC_ISSUE_REFERENCE.FILE_TYPE%TYPE,
    doc_FileName DOC_ISSUE_REFERENCE.FILE_NAME%TYPE,
    doc_Path     DOC_ISSUE_REFERENCE.PATH%TYPE);
  FUNCTION Get_Budget_Doc(
      company             IN VARCHAR2,
      budget_process_id   IN VARCHAR2,
      budget_ptemplate_id IN VARCHAR2)
    RETURN doc_rec;
END INHOUSE_CUST_API;

, после этого я создал тело функции, как показано ниже 

create or replace 
PACKAGE BODY INHOUSE_CUST_API
AS
FUNCTION Get_Budget_Doc(
    company             IN VARCHAR2,
    budget_process_id   IN VARCHAR2,
    budget_ptemplate_id IN VARCHAR2)
  RETURN doc_rec
IS
  enhDocItem ENHANCED_DOC_REFERENCE_OBJECT%ROWTYPE;
  docIssueRef DOC_ISSUE_REFERENCE%ROWTYPE;
  docKeyValue VARCHAR2(150);
  docIssueRef_rec  doc_rec;
BEGIN
  docKeyValue := company||'^'||budget_process_id||'^'||budget_ptemplate_id||'^';
  --dbms_output.put_line(docKeyValue);
  SELECT *
  INTO enhDocItem
  FROM ENHANCED_DOC_REFERENCE_OBJECT
  WHERE KEY_VALUE= docKeyValue;
  SELECT *
  INTO docIssueRef
  FROM DOC_ISSUE_REFERENCE
  WHERE DOC_NO               = enhDocItem.DOC_NO;
  docIssueRef_rec.doc_Title :=docIssueRef.Title;
  docIssueRef_rec.doc_Number:=docIssueRef.DOC_NO;
  docIssueRef_rec.doc_Type  :=docIssueRef.FILE_TYPE;
  docIssueRef_rec.doc_Path  :=docIssueRef.PATH;
  RETURN docIssueRef_rec;
END Get_Budget_Doc;
END INHOUSE_CUST_API;

когда я пытаюсь вызвать функцию как, выберите INHOUSE_CUST_API.Get_Budget_Doc ('param1', 'param2', 'param3') из двойного;

Я получаю это исключение

ORA-00902: неверный тип данных 00902. 00000 - "неверный тип данных" * Причина:
* Действие:

любая помощь приветствуется.

Ответы [ 2 ]

0 голосов
/ 06 декабря 2018

Возможно, вы захотите использовать табличную функцию для возврата вашего пользовательского типа.Вот очень простой пример: 

CREATE OR REPLACE PACKAGE brianl.deleteme AS
TYPE doc_rec_t IS RECORD
(
    name    VARCHAR2( 10 )
  , age     NUMBER( 3 )
);

TYPE doc_rec_tt IS TABLE OF doc_rec_t;

FUNCTION age( p_name IN VARCHAR2, p_age IN NUMBER, p_years IN INTEGER )
    RETURN doc_rec_tt
    PIPELINED;
END deleteme;

CREATE OR REPLACE PACKAGE BODY brianl.deleteme AS
  FUNCTION age( p_name IN VARCHAR2, p_age IN NUMBER, p_years IN INTEGER )
      RETURN doc_rec_tt
      PIPELINED AS
      l_ret   doc_rec_t;
  BEGIN
    l_ret.name   := p_name;
    l_ret.age    := p_age;

    FOR i IN 1 .. p_years
    LOOP
        PIPE ROW (l_ret);
        l_ret.age   := l_ret.age + 1;
    END LOOP;
  END age;
END deleteme;

Вызовите следующим образом: 

SELECT * FROM TABLE( brianl.deleteme.age( 'Brian', 67, 3 ) );

Результаты: 

NAME    AGE
Brian   67
Brian   68
Brian   69
0 голосов
/ 06 декабря 2018

оператор SELECT в прямом режиме не может возвращать сложный тип данных, например запись.

...