Разбор имени файла с помощью пакетной автоматизации

Question

Это может быть достаточно просто, но я не специалист по компьютерным языкам.Я застрял в поисках решения в Интернете почти 3 часа.

Предполагается, что все мои mp3-файлы имеют название "Имя исполнителя - название песни.mp3" Я быхотите вывести его в текстовый файл, который содержит:Исполнитель: Имя исполнителя Песня: Название песни

Как мне разобрать имя файла на две части, разделенные дефисом?Я пытался сделать какую-то автоматизацию с пакетными файлами для целей архивации, и вот мой код, с которым я застрял:

@echo off
for /r %%a in (*.mp3) do (
(
for %%b in ("%%~na") do echo ^Artist: %%~b
echo ^Song:
)>"%%~dpna.txt"
) 

Answer 1

Измените начальную папку после PushD, чтобы она подходила для вашей среды.

:: Q:\Test\2018\06\03\SO_50666632.cmd
@echo off
PushD "%USERPROFILE%\Music" || (Echo can't locate folder&Pause&exit /B 1)

for /r %%a in (*.mp3) do (
    if exist "%%~dpna.txt" (
        Echo "%%~dpna.txt" already present, skip
    ) else (
       for /f "tokens=1,*delims=-" %%b in ("%%~na") do (
           echo Artist: %%b
           echo Song  :%%c
       )>"%%~dpna.txt"
    )
)

Пример вывода на моем ramdrive a:

> tree /F
Auflistung der Ordnerpfade
Volumeseriennummer : 5566-7788
A:.
│   Name of Artist - Title of Song.mp3
│   Name of Artist - Title of Song.txt
│
└───Music
        Survivor - Eye of the Tiger.mp3
        Survivor - Eye of the Tiger.txt


> type "Name of Artist - Title of Song.txt"
Artist: Name of Artist
Song  : Title of Song

> type "Music\Survivor - Eye of the Tiger.txt"
Artist: Survivor
Song  : Eye of the Tiger

Answer 2

Как мне разобрать имя файла на две части, разделенные дефисом?

Я бы хотел, чтобы оно выводилось в текстовый файл, содержащий:

Artist: Name of Artist
Song: Title of Song

Используйте следующий пакетный файл в качестве отправной точки:

@echo off
setlocal enabledelayedexpansion
for /f "tokens=1,2 delims=-" %%i in ('dir /b name*') do (
  echo Artist: %%i 
  echo Song: %%j
 )>>file.txt
endlocal

Пример использования:

> dir name*
 Volume in drive F is Expansion
 Volume Serial Number is 3656-BB63

 Directory of F:\test

03/06/2018  14:06                 0 Name of Artist - Title of Song.mp3
03/06/2018  14:07                 0 Name of Artist 1 - Title of Song 1.mp3
               2 File(s)              0 bytes
               0 Dir(s)  1,269,011,574,784 bytes free

> test

> type file.txt
Artist: Name of Artist
Song:  Title of Song.mp3
Artist: Name of Artist 1
Song:  Title of Song 1.mp3    
>

---

Я бы хотел, чтобы для каждого mp3-файла был один текстовый файл.,Возможно ли это?

Да Используйте следующий пакетный файл:

@echo off
setlocal enabledelayedexpansion
for /f "tokens=*" %%a in ('dir /b name*.mp3') do (
  set _filename=%%~dpna.txt
  for /f "tokens=1,2 delims=-" %%i in ("%%a") do (
    echo Artist: %%i 
    echo Song: %%j
    )>!_filename!
  )
endlocal

Пример использования:

> dir *.mp3
 Volume in drive F is Expansion
 Volume Serial Number is 3656-BB63

 Directory of F:\test

03/06/2018  14:06                 0 Name of Artist - Title of Song.mp3
03/06/2018  14:07                 0 Name of Artist 1 - Title of Song 1.mp3
               2 File(s)              0 bytes
               0 Dir(s)  1,269,022,654,464 bytes free

> test

> type name*.txt

Name of Artist - Title of Song.txt


Artist: Name of Artist 1
Song:  Title of Song 1.mp3

Name of Artist 1 - Title of Song 1.txt


Artist: Name of Artist 1
Song:  Title of Song 1.mp3

---

• Индекс AZкомандной строки Windows CMD
• Категоризованный список команд Windows CMD
• dir - отображение списка файлов и подпапок.
• for / f - Циклическая команда с результатами другой команды.