Проблемы с использованием чисел в переменных / переменные отображаются неправильно

Question

Вчера я решил немного повеселиться с командной строкой: я хотел создать случайно сгенерированный "лабиринт" с юникодом, и был очень взволнован.Я почти все сделал, но у меня есть некоторые проблемы с моей системой координат, чтобы сделать изображение с помощью символов.По какой-то причине в моем множестве переменных не отображаются их значения.Я не знаю что не так.Это может быть синтаксис, когда я создаю переменные (в имени переменной есть переменные), это может быть способ, которым я их настраиваю, когда пытаюсь их отобразить, я не знаю.

@echo off
:restart
set x=0
set y=0
:next
set /a chance=%random% %%2
if chance==1 (
    set %x%l%y%=00
)
if chance==2 (
    set %x%l%y%=11
)
set /a x=%x%+1
if x GEQ 10 (
    set x=0
    goto display
    set /a y=%y%+1
    if y GEQ 11 (
        goto display
    )
)
goto next
:display
echo %0l0%%1l0%%2l0%%3l0%%4l0%%5l0%%6l0%%7l0%%8l0%%9l0%
echo %0l1%%1l1%%2l1%%3l1%%4l1%%5l1%%6l1%%7l1%%8l1%%9l1%
echo %0l2%%1l2%%2l2%%3l2%%4l2%%5l2%%6l2%%7l2%%8l2%%9l2%
echo %0l3%%1l3%%2l3%%3l3%%4l3%%5l3%%6l3%%7l3%%8l3%%9l3%
echo %0l4%%1l4%%2l4%%3l4%%4l4%%5l4%%6l4%%7l4%%8l4%%9l4%
echo %0l5%%1l5%%2l5%%3l5%%4l5%%5l5%%6l5%%7l5%%8l5%%9l5%
echo %0l6%%1l6%%2l6%%3l6%%4l6%%5l6%%6l6%%7l6%%8l6%%9l6%
echo %0l7%%1l7%%2l7%%3l7%%4l7%%5l7%%6l7%%7l7%%8l7%%9l7%
echo %0l8%%1l8%%2l8%%3l8%%4l8%%5l8%%6l8%%7l8%%8l8%%9l8%
echo %0l9%%1l9%%2l9%%3l9%%4l9%%5l9%%6l9%%7l9%%8l9%%9l9%
echo:
pause
cls
goto restart

Поскольку я еще не заменил «00» и «11» на Юникод, желаемый результат будет выглядеть примерно так:

00110000111100111111
11110011110000111100
00000011111111001100
11000000111100110011
00110000111100111111
00110000111100111111
11110011110000111100
00000011111111001100
11000000111100110011
00110000111100111111

Press any key to continue...

Вместо этого это беспорядок.

"C:\Users\***\Documents\array.bat"l0%1l0%2l0%3l0%4l0%5l0%6l0%7l0%8l0%9l0
"C:\Users\***\Documents\array.bat"l1%1l1%2l1%3l1%4l1%5l1%6l1%7l1%8l1%9l1
"C:\Users\***\Documents\array.bat"l2%1l2%2l2%3l2%4l2%5l2%6l2%7l2%8l2%9l2
"C:\Users\***\Documents\array.bat"l3%1l3%2l3%3l3%4l3%5l3%6l3%7l3%8l3%9l3
"C:\Users\***\Documents\array.bat"l4%1l4%2l4%3l4%4l4%5l4%6l4%7l4%8l4%9l4
"C:\Users\***\Documents\array.bat"l5%1l5%2l5%3l5%4l5%5l5%6l5%7l5%8l5%9l5
"C:\Users\***\Documents\array.bat"l6%1l6%2l6%3l6%4l6%5l6%6l6%7l6%8l6%9l6
"C:\Users\***\Documents\array.bat"l7%1l7%2l7%3l7%4l7%5l7%6l7%7l7%8l7%9l7
"C:\Users\***\Documents\array.bat"l8%1l8%2l8%3l8%4l8%5l8%6l8%7l8%8l8%9l8
"C:\Users\***\Documents\array.bat"l9%1l9%2l9%3l9%4l9%5l9%6l9%7l9%8l9%9l9

Press any key to continue . . .

У меня есть планы расширить эту концепцию, но я не могу идти дальше без решения этой проблемы.Пожалуйста, помогите!

Answer 1

Я настоятельно рекомендую вам использовать стандартную запись массива при использовании массивов, то есть с индексами, заключенными в квадратные скобки.Дальнейшие подробности вы можете прочитать в Массивы, связанные списки и другие структуры данных в скрипте cmd.exe (batch)

. Я предлагаю вам использовать команду for /L для сборки циклов.

Например:

@echo off
setlocal EnableDelayedExpansion

:restart
for /L %%x in (0,1,9) do (
   for /L %%y in (0,1,9) do (
      set /A chance=!random! %% 2
      if !chance! == 1 (
         set "p[%%x][%%y]=00"
      ) else (
         set "p[%%x][%%y]=11"
      )
   )
)

:display
for /L %%x in (0,1,9) do (
   set "out="
   for /L %%y in (0,1,9) do (
      set "out=!out!!p[%%x][%%y]!
   )
   echo !out!
)
echo/
pause
cls
goto restart