CSV в XML XSLT: как передать канал - PullRequest
Новая
       7

CSV в XML XSLT: как передать канал

0 голосов
/ 04 июня 2018

Я пытаюсь преобразовать данные, разделенные разделителями, в токенизацию и анализ в xml с использованием xsl.В настоящее время у меня есть это

XML 

abc|"x|y|z"|gh|ij

XSL 

<xsl:template match="/">
    <client:SplitString>
        <xsl:call-template name="tokenize">
            <xsl:with-param name="text"
                            select="/client:CSVString/client:CSV_Value"/>
        </xsl:call-template>
    </client:SplitString>
</xsl:template>
<xsl:template match="text/text()" name="tokenize">
    <xsl:param name="text" select="$text"/>
    <xsl:param name="separator"
               select="|"/>
    <xsl:choose>
        <xsl:when test="not(contains($text, $separator))">
            <client:Value>
                <xsl:value-of select="normalize-space($text)"/>
            </client:Value>
        </xsl:when>
        <xsl:otherwise>
            <client:Value>
                <xsl:value-of select="normalize-space(substring-before($text, $separator))"/>
            </client:Value>
            <xsl:call-template name="tokenize">
                <xsl:with-param name="text"
                                select="substring-after($text, $separator)"/>
            </xsl:call-template>
        </xsl:otherwise>
    </xsl:choose>
</xsl:template>

Это прекрасно работает для значений, разделенных обычным разделителем, но не работает на трубах внутри разделителя.У меня есть регулярное выражение для распознавания канала внутри кавычек как единого значения.Но я как-то не могу его использовать. 

"([^"]*)",?|([^|]+),?

Я хочу, чтобы результат был 

<result>abc</result>
<result>x|y|z</result>
<result>gh</result>
<result>ij</result>

Любая помощь будет оценена.Спасибо!

1 Ответ

0 голосов
/ 04 июня 2018

Что вы можете сделать, это проверить, начинается ли строка для токенизации с кавычки.Если это так, выведите то, что находится в кавычках.Если это не так, токенизируйте его как обычно.

Пример ...

Ввод XML 

<doc>
    <value>abc|"x|y|z"|gh|ij</value>
    <value>"x|y|z"|abc|gh|ij</value>
    <value>abc|"x|y|z"|gh|"x|y|z"|ij</value>
    <value>"x|y|z"|abc|"x|y|z"|gh|ij|"x|y|z"</value>    
</doc>

XSLT 1.0 

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
  <xsl:output indent="yes"/>
  <xsl:strip-space elements="*"/>

  <xsl:template match="value">
    <SplitString>
      <xsl:call-template name="tokenize">
        <xsl:with-param name="input" select="normalize-space()"/>
      </xsl:call-template>      
    </SplitString>
  </xsl:template>

  <xsl:template name="tokenize">
    <xsl:param name="delimiter" select="'|'"/>
    <xsl:param name="input"/>
    <xsl:choose>
      <xsl:when test="starts-with($input, '&quot;')">
        <xsl:variable name="value" select="substring-before(substring-after($input,'&quot;'),'&quot;')"/>
        <result>
          <xsl:value-of select="normalize-space($value)"/>
        </result>
        <xsl:call-template name="tokenize">
          <xsl:with-param name="input" select="normalize-space(substring($input,string-length($value)+3))"/>
        </xsl:call-template>
      </xsl:when>
      <xsl:otherwise>
        <xsl:variable name="value" select="substring-before(concat($input,$delimiter),$delimiter)"/>
        <xsl:if test="string($value)">
          <result>
            <xsl:value-of select="normalize-space($value)"/>
          </result>          
        </xsl:if>
        <xsl:if test="string(substring-after($input,$delimiter))">
          <xsl:call-template name="tokenize">
            <xsl:with-param name="input" select="normalize-space(substring-after($input,$delimiter))"/>
          </xsl:call-template>
        </xsl:if>
      </xsl:otherwise>
    </xsl:choose>
  </xsl:template>

</xsl:stylesheet>

Выход 

<SplitString>
   <result>abc</result>
   <result>x|y|z</result>
   <result>gh</result>
   <result>ij</result>
</SplitString>
<SplitString>
   <result>x|y|z</result>
   <result>abc</result>
   <result>gh</result>
   <result>ij</result>
</SplitString>
<SplitString>
   <result>abc</result>
   <result>x|y|z</result>
   <result>gh</result>
   <result>x|y|z</result>
   <result>ij</result>
</SplitString>
<SplitString>
   <result>x|y|z</result>
   <result>abc</result>
   <result>x|y|z</result>
   <result>gh</result>
   <result>ij</result>
   <result>x|y|z</result>
</SplitString>

Fiddle: http://xsltfiddle.liberty -development.net / bFDb2C9 / 2

...