Счетчик строк XSLT, исключая ноль и ноль

Question

<Rows>
    <Row RowNo="1" Amount="0,0"/>
    <Row RowNo="2" Amount="12"/>
    <Row RowNo="3" Amount=""/>
    <Row RowNo="4" Amount="00"/>
    <Row RowNo="5" Amount="33"/>
    <Row RowNo="6" Amount="0,00"/>
    <Row RowNo="7" Amount="0"/>
    <Row RowNo="8" Amount="00,2"/>
</Rows>

Эти строки - мой вклад.Я хочу, чтобы выходные данные исключали строки, где @Amount равно '' или 0. И также не подсчитывали строку, когда @Amount = '' и = 0. Ожидаемый результат:

<Rows>
    <Row RowNo="1" Amount="12"/>
    <Row RowNo="2" Amount="33"/>
    <Row RowNo="3" Amount="00,2"/>
</Rows> 

Как я могу это сделать

Answer 1

Как насчет чего-то простого, для разнообразия?

XSLT 1.0

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>
<xsl:strip-space elements="*"/>

<xsl:template match="/Rows">
    <xsl:copy>
        <xsl:for-each select="Row[translate(@Amount, ',0', '')]">
            <Row RowNo="{position()}" Amount="{@Amount}"/>
        </xsl:for-each>
    </xsl:copy>
</xsl:template>

</xsl:stylesheet>

Answer 2

При заданном вами входном значении конкретное (на основе входных данных) решение в XSLT 1.0 может быть следующим:

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

<xsl:template match="/">
    <Rows>
        <xsl:for-each select="Rows/Row">
            <xsl:choose>
                <xsl:when test="@Amount != '' and (number(@Amount) * 1) != '0' and translate(@Amount, '0', '') != ','">
                    <xsl:copy>
                        <xsl:attribute name="RowNo">
                            <xsl:value-of select="count(preceding-sibling::*[@Amount != '' and (number(@Amount) * 1) != '0' and translate(@Amount, '0', '') != ',']) + 1" />
                        </xsl:attribute>
                        <xsl:for-each select="@*">
                            <xsl:if test="name() != 'RowNo'">
                                <xsl:attribute name="{name()}"><xsl:value-of select="." /></xsl:attribute>
                            </xsl:if>
                        </xsl:for-each>
                        <xsl:apply-templates select="node()" />
                    </xsl:copy>
                </xsl:when>
            </xsl:choose>
        </xsl:for-each>
    </Rows>
</xsl:template>