Лучший способ определить версию продукта сервера и выполнить SQL соответственно? - PullRequest
Новая
       19

Лучший способ определить версию продукта сервера и выполнить SQL соответственно?

2 голосов
/ 24 июня 2009

Это двусторонний вопрос: Сценарий:

У меня есть скрипт для запроса MSDB и получения подробных графиков работы. Очевидно, что таблицы отличаются от SQL 2000 до SQL 2005. Поэтому я хочу проверить версию, запущенную в окне, и запросить соответственно. Теперь вопросы:

Вопрос 1:

Это то, что я делаю. 

IF LEFT(CAST(SERVERPROPERTY('ProductVersion') As Varchar),1)='8'
BEGIN
PRINT 'SQL 2000'--Actual Code Goes Here
END
IF LEFT(CAST(SERVERPROPERTY('ProductVersion') As Varchar),1)='9'
BEGIN
PRINT 'SQL 2005'--Actual Code Goes Here
END

Есть ли лучший способ сделать это?

Вопрос 2:

Несмотря на то, что приведенный выше скрипт отлично работает на блоках 2000 и 2005, когда я заменяю операторы «Print ..» моим реальным кодом, он отлично работает на блоках 2000, но при выполнении на блоках 2005 года пытается выполнить блок кода рассчитан на 2000 и возвращает ошибки.

Вот фактический код: 

USE [msdb]
GO
SET ANSI_NULLS ON
GO
SET QUOTED_IDENTIFIER ON
GO
--Check SQL Server Version
IF LEFT(CAST(SERVERPROPERTY('ProductVersion') As Varchar),1)='9'
BEGIN
SELECT @@SERVERNAME
,sysjobs.name
,dbo.udf_schedule_description(dbo.sysschedules.freq_type, dbo.sysschedules.freq_interval,  
dbo.sysschedules.freq_subday_type, dbo.sysschedules.freq_subday_interval, dbo.sysschedules.freq_relative_interval,  
dbo.sysschedules.freq_recurrence_factor, dbo.sysschedules.active_start_date, dbo.sysschedules.active_end_date,  
dbo.sysschedules.active_start_time, dbo.sysschedules.active_end_time) AS [Schedule Description]
, CONVERT(CHAR(8), CASE WHEN LEN(msdb.dbo.sysschedules.Active_Start_Time) = 3
                         THEN CAST('00:0' + LEFT(msdb.dbo.sysschedules.Active_Start_Time, 1) + ':'
                              + SUBSTRING(CAST(msdb.dbo.sysschedules.Active_Start_Time AS VARCHAR(6)),
                                          2, 2) AS VARCHAR(8))
                         WHEN LEN(msdb.dbo.sysschedules.Active_Start_Time) = 4
                         THEN CAST('00:' 
                              + SUBSTRING(CAST(msdb.dbo.sysschedules.Active_Start_Time AS VARCHAR(6)),
                                          1, 2) + ':'
                              + SUBSTRING(CAST(msdb.dbo.sysschedules.Active_Start_Time AS VARCHAR(6)),
                                          3, 2) AS VARCHAR(8))
                         WHEN LEN(msdb.dbo.sysschedules.Active_Start_Time) = 5
                         THEN CAST('0' + LEFT(msdb.dbo.sysschedules.Active_Start_Time, 1) + ':'
                              + SUBSTRING(CAST(msdb.dbo.sysschedules.Active_Start_Time AS VARCHAR(6)),
                                          2, 2) + ':'
                              + SUBSTRING(CAST(msdb.dbo.sysschedules.Active_Start_Time AS VARCHAR(6)),
                                          4, 2) AS VARCHAR(8))
                         WHEN msdb.dbo.sysschedules.Active_Start_Time = 0
                         THEN '00:00:00'
                         ELSE CAST(LEFT(msdb.dbo.sysschedules.Active_Start_Time, 2) + ':'
                              + SUBSTRING(CAST(msdb.dbo.sysschedules.Active_Start_Time AS VARCHAR(6)),
                                          3, 2) + ':'
                              + SUBSTRING(CAST(msdb.dbo.sysschedules.Active_Start_Time AS VARCHAR(6)),
                                          5, 2) AS VARCHAR(8))
                    END, 108) AS Start_Time,
       CONVERT(CHAR(8), CASE WHEN LEN(msdb.dbo.sysschedules.active_end_time) = 3
                         THEN CAST('00:0' + LEFT(msdb.dbo.sysschedules.active_end_time, 1) + ':'
                              + SUBSTRING(CAST(msdb.dbo.sysschedules.active_end_time AS VARCHAR(6)),
                                          2, 2) AS VARCHAR(8))
                         WHEN LEN(msdb.dbo.sysschedules.active_end_time) = 4
                         THEN CAST('00:' 
                              + SUBSTRING(CAST(msdb.dbo.sysschedules.active_end_time AS VARCHAR(6)),
                                          1, 2) + ':'
                              + SUBSTRING(CAST(msdb.dbo.sysschedules.active_end_time AS VARCHAR(6)),
                                          3, 2) AS VARCHAR(8))
                         WHEN LEN(msdb.dbo.sysschedules.active_end_time) = 5
                         THEN CAST('0' + LEFT(msdb.dbo.sysschedules.active_end_time, 1) + ':'
                              + SUBSTRING(CAST(msdb.dbo.sysschedules.active_end_time AS VARCHAR(6)),
                                          2, 2) + ':'
                              + SUBSTRING(CAST(msdb.dbo.sysschedules.active_end_time AS VARCHAR(6)),
                                          4, 2) AS VARCHAR(8))
                         WHEN msdb.dbo.sysschedules.active_end_time = 0
                         THEN '00:00:00'
                         ELSE CAST(LEFT(msdb.dbo.sysschedules.active_end_time, 2) + ':'
                              + SUBSTRING(CAST(msdb.dbo.sysschedules.active_end_time AS VARCHAR(6)),
                                          3, 2) + ':'
                              + SUBSTRING(CAST(msdb.dbo.sysschedules.active_end_time AS VARCHAR(6)),
                                          5, 2) AS VARCHAR(8))
                    END, 108) AS End_Time
,CAST(CASE WHEN LEN(msdb.dbo.sysjobservers.last_run_duration) = 1
                         THEN CAST('00:00:0' + LEFT(msdb.dbo.sysjobservers.last_run_duration, 1)AS VARCHAR(8))
                         WHEN LEN(msdb.dbo.sysjobservers.last_run_duration) = 2
                         THEN CAST('00:00:' + LEFT(msdb.dbo.sysjobservers.last_run_duration, 2)AS VARCHAR(8))
                         WHEN LEN(msdb.dbo.sysjobservers.last_run_duration) = 3
                         THEN CAST('00:0' + LEFT(msdb.dbo.sysjobservers.last_run_duration, 1) + ':'
                              + SUBSTRING(CAST(msdb.dbo.sysjobservers.last_run_duration AS VARCHAR(6)),
                                          2, 2) AS VARCHAR(8))
                         WHEN LEN(msdb.dbo.sysjobservers.last_run_duration) = 4
                         THEN CAST('00:' 
                              + SUBSTRING(CAST(msdb.dbo.sysjobservers.last_run_duration AS VARCHAR(6)),
                                          1, 2) + ':'
                              + SUBSTRING(CAST(msdb.dbo.sysjobservers.last_run_duration AS VARCHAR(6)),
                                          3, 2) AS VARCHAR(8))
                         WHEN LEN(msdb.dbo.sysjobservers.last_run_duration) = 5
                         THEN CAST('0' + LEFT(msdb.dbo.sysjobservers.last_run_duration, 1) + ':'
                              + SUBSTRING(CAST(msdb.dbo.sysjobservers.last_run_duration AS VARCHAR(6)),
                                          2, 2) + ':'
                              + SUBSTRING(CAST(msdb.dbo.sysjobservers.last_run_duration AS VARCHAR(6)),
                                          4, 2) AS VARCHAR(8))
                         WHEN msdb.dbo.sysjobservers.last_run_duration = 0
                         THEN '00:00:00'
                         ELSE CAST(LEFT(msdb.dbo.sysjobservers.last_run_duration, 2) + ':'
                              + SUBSTRING(CAST(msdb.dbo.sysjobservers.last_run_duration AS VARCHAR(6)),
                                          3, 2) + ':'
                              + SUBSTRING(CAST(msdb.dbo.sysjobservers.last_run_duration AS VARCHAR(6)),
                                          5, 2) AS VARCHAR(8))
                    END AS VARCHAR(8))  AS LastRunDuration
FROM msdb.dbo.sysjobs INNER JOIN
msdb.dbo.syscategories ON msdb.dbo.sysjobs.category_id = msdb.dbo.syscategories.category_id LEFT OUTER JOIN
msdb.dbo.sysoperators ON msdb.dbo.sysjobs.notify_page_operator_id = msdb.dbo.sysoperators.id LEFT OUTER JOIN
msdb.dbo.sysjobservers ON msdb.dbo.sysjobs.job_id = msdb.dbo.sysjobservers.job_id LEFT OUTER JOIN
msdb.dbo.sysjobschedules ON msdb.dbo.sysjobschedules.job_id = msdb.dbo.sysjobs.job_id LEFT OUTER JOIN
msdb.dbo.sysschedules ON msdb.dbo.sysjobschedules.schedule_id = msdb.dbo.sysschedules.schedule_id
WHERE sysjobs.enabled = 1 AND msdb.dbo.sysschedules.Active_Start_Time IS NOT NULL
ORDER BY Start_time,sysjobs.name
END

IF LEFT(CAST(SERVERPROPERTY('ProductVersion') As Varchar),1)='8'
BEGIN
SELECT @@SERVERNAME
,sysjobs.name
,dbo.udf_schedule_description(sysjobschedules.freq_type, sysjobschedules.freq_interval,  
sysjobschedules.freq_subday_type, sysjobschedules.freq_subday_interval, sysjobschedules.freq_relative_interval,  
sysjobschedules.freq_recurrence_factor, sysjobschedules.active_start_date, sysjobschedules.active_end_date,  
sysjobschedules.active_start_time, sysjobschedules.active_end_time) AS [Schedule Description]
, CONVERT(CHAR(8), CASE WHEN LEN(msdb.dbo.sysjobschedules.Active_Start_Time) = 3
                         THEN CAST('00:0' + LEFT(msdb.dbo.sysjobschedules.Active_Start_Time, 1) + ':'
                              + SUBSTRING(CAST(msdb.dbo.sysjobschedules.Active_Start_Time AS VARCHAR(6)),
                                          2, 2) AS VARCHAR(8))
                         WHEN LEN(msdb.dbo.sysjobschedules.Active_Start_Time) = 4
                         THEN CAST('00:' 
                              + SUBSTRING(CAST(msdb.dbo.sysjobschedules.Active_Start_Time AS VARCHAR(6)),
                                          1, 2) + ':'
                              + SUBSTRING(CAST(msdb.dbo.sysjobschedules.Active_Start_Time AS VARCHAR(6)),
                                          3, 2) AS VARCHAR(8))
                         WHEN LEN(msdb.dbo.sysjobschedules.Active_Start_Time) = 5
                         THEN CAST('0' + LEFT(msdb.dbo.sysjobschedules.Active_Start_Time, 1) + ':'
                              + SUBSTRING(CAST(msdb.dbo.sysjobschedules.Active_Start_Time AS VARCHAR(6)),
                                          2, 2) + ':'
                              + SUBSTRING(CAST(msdb.dbo.sysjobschedules.Active_Start_Time AS VARCHAR(6)),
                                          4, 2) AS VARCHAR(8))
                         WHEN msdb.dbo.sysjobschedules.Active_Start_Time = 0
                         THEN '00:00:00'
                         ELSE CAST(LEFT(msdb.dbo.sysjobschedules.Active_Start_Time, 2) + ':'
                              + SUBSTRING(CAST(msdb.dbo.sysjobschedules.Active_Start_Time AS VARCHAR(6)),
                                          3, 2) + ':'
                              + SUBSTRING(CAST(msdb.dbo.sysjobschedules.Active_Start_Time AS VARCHAR(6)),
                                          5, 2) AS VARCHAR(8))
                    END, 108) AS Start_Time,
       CONVERT(CHAR(8), CASE WHEN LEN(msdb.dbo.sysjobschedules.active_end_time) = 3
                         THEN CAST('00:0' + LEFT(msdb.dbo.sysjobschedules.active_end_time, 1) + ':'
                              + SUBSTRING(CAST(msdb.dbo.sysjobschedules.active_end_time AS VARCHAR(6)),
                                          2, 2) AS VARCHAR(8))
                         WHEN LEN(msdb.dbo.sysjobschedules.active_end_time) = 4
                         THEN CAST('00:' 
                              + SUBSTRING(CAST(msdb.dbo.sysjobschedules.active_end_time AS VARCHAR(6)),
                                          1, 2) + ':'
                              + SUBSTRING(CAST(msdb.dbo.sysjobschedules.active_end_time AS VARCHAR(6)),
                                          3, 2) AS VARCHAR(8))
                         WHEN LEN(msdb.dbo.sysjobschedules.active_end_time) = 5
                         THEN CAST('0' + LEFT(msdb.dbo.sysjobschedules.active_end_time, 1) + ':'
                              + SUBSTRING(CAST(msdb.dbo.sysjobschedules.active_end_time AS VARCHAR(6)),
                                          2, 2) + ':'
                              + SUBSTRING(CAST(msdb.dbo.sysjobschedules.active_end_time AS VARCHAR(6)),
                                          4, 2) AS VARCHAR(8))
                         WHEN msdb.dbo.sysjobschedules.active_end_time = 0
                         THEN '00:00:00'
                         ELSE CAST(LEFT(msdb.dbo.sysjobschedules.active_end_time, 2) + ':'
                              + SUBSTRING(CAST(msdb.dbo.sysjobschedules.active_end_time AS VARCHAR(6)),
                                          3, 2) + ':'
                              + SUBSTRING(CAST(msdb.dbo.sysjobschedules.active_end_time AS VARCHAR(6)),
                                          5, 2) AS VARCHAR(8))
                    END, 108) AS End_Time
,CAST(CASE WHEN LEN(msdb.dbo.sysjobservers.last_run_duration) = 1
                         THEN CAST('00:00:0' + LEFT(msdb.dbo.sysjobservers.last_run_duration, 1)AS VARCHAR(8))
                         WHEN LEN(msdb.dbo.sysjobservers.last_run_duration) = 2
                         THEN CAST('00:00:' + LEFT(msdb.dbo.sysjobservers.last_run_duration, 2)AS VARCHAR(8))
                         WHEN LEN(msdb.dbo.sysjobservers.last_run_duration) = 3
                         THEN CAST('00:0' + LEFT(msdb.dbo.sysjobservers.last_run_duration, 1) + ':'
                              + SUBSTRING(CAST(msdb.dbo.sysjobservers.last_run_duration AS VARCHAR(6)),
                                          2, 2) AS VARCHAR(8))
                         WHEN LEN(msdb.dbo.sysjobservers.last_run_duration) = 4
                         THEN CAST('00:' 
                              + SUBSTRING(CAST(msdb.dbo.sysjobservers.last_run_duration AS VARCHAR(6)),
                                          1, 2) + ':'
                              + SUBSTRING(CAST(msdb.dbo.sysjobservers.last_run_duration AS VARCHAR(6)),
                                          3, 2) AS VARCHAR(8))
                         WHEN LEN(msdb.dbo.sysjobservers.last_run_duration) = 5
                         THEN CAST('0' + LEFT(msdb.dbo.sysjobservers.last_run_duration, 1) + ':'
                              + SUBSTRING(CAST(msdb.dbo.sysjobservers.last_run_duration AS VARCHAR(6)),
                                          2, 2) + ':'
                              + SUBSTRING(CAST(msdb.dbo.sysjobservers.last_run_duration AS VARCHAR(6)),
                                          4, 2) AS VARCHAR(8))
                         WHEN msdb.dbo.sysjobservers.last_run_duration = 0
                         THEN '00:00:00'
                         ELSE CAST(LEFT(msdb.dbo.sysjobservers.last_run_duration, 2) + ':'
                              + SUBSTRING(CAST(msdb.dbo.sysjobservers.last_run_duration AS VARCHAR(6)),
                                          3, 2) + ':'
                              + SUBSTRING(CAST(msdb.dbo.sysjobservers.last_run_duration AS VARCHAR(6)),
                                          5, 2) AS VARCHAR(8))
                    END AS VARCHAR(8))  AS LastRunDuration
FROM sysjobs LEFT OUTER JOIN 
msdb.dbo.sysjobservers ON msdb.dbo.sysjobs.job_id = msdb.dbo.sysjobservers.job_id INNER JOIN
sysjobschedules ON sysjobs.job_id = sysjobschedules.job_id 
WHERE sysjobs.enabled = 1
ORDER BY Start_time,sysjobs.name
END

Этот скрипт требует udf в MSDB. Вот код для функции: 

USE [msdb]
GO
SET ANSI_NULLS ON
GO
SET QUOTED_IDENTIFIER ON
GO
CREATE FUNCTION [dbo].[udf_schedule_description] (@freq_type INT ,
 @freq_interval INT ,
 @freq_subday_type INT ,
 @freq_subday_interval INT ,
 @freq_relative_interval INT ,
 @freq_recurrence_factor INT ,
 @active_start_date INT ,
 @active_end_date INT,
 @active_start_time INT ,
 @active_end_time INT ) 
RETURNS NVARCHAR(255) AS 
BEGIN
DECLARE @schedule_description NVARCHAR(255)
DECLARE @loop INT
DECLARE @idle_cpu_percent INT
DECLARE @idle_cpu_duration INT

IF (@freq_type = 0x1) -- OneTime
 BEGIN
 SELECT @schedule_description = N'Once on ' + CONVERT(NVARCHAR, @active_start_date) + N' at ' + CONVERT(NVARCHAR, cast((@active_start_time / 10000) as varchar(10)) + ':' + right('00' + cast((@active_start_time % 10000) / 100 as varchar(10)),2))
 RETURN @schedule_description
 END
IF (@freq_type = 0x4) -- Daily
 BEGIN
 SELECT @schedule_description = N'Every day '
 END
IF (@freq_type = 0x8) -- Weekly
 BEGIN
 SELECT @schedule_description = N'Every ' + CONVERT(NVARCHAR, @freq_recurrence_factor) + N' week(s) on '
 SELECT @loop = 1
 WHILE (@loop <= 7)
 BEGIN
 IF (@freq_interval & POWER(2, @loop - 1) = POWER(2, @loop - 1))
 SELECT @schedule_description = @schedule_description + DATENAME(dw, N'1996120' + CONVERT(NVARCHAR, @loop)) + N', '
 SELECT @loop = @loop + 1
 END
 IF (RIGHT(@schedule_description, 2) = N', ')
 SELECT @schedule_description = SUBSTRING(@schedule_description, 1, (DATALENGTH(@schedule_description) / 2) - 2) + N' '
 END
IF (@freq_type = 0x10) -- Monthly
 BEGIN
 SELECT @schedule_description = N'Every ' + CONVERT(NVARCHAR, @freq_recurrence_factor) + N' months(s) on day ' + CONVERT(NVARCHAR, @freq_interval) + N' of that month '
 END
IF (@freq_type = 0x20) -- Monthly Relative
 BEGIN
 SELECT @schedule_description = N'Every ' + CONVERT(NVARCHAR, @freq_recurrence_factor) + N' months(s) on the '
 SELECT @schedule_description = @schedule_description +
 CASE @freq_relative_interval
 WHEN 0x01 THEN N'first '
 WHEN 0x02 THEN N'second '
 WHEN 0x04 THEN N'third '
 WHEN 0x08 THEN N'fourth '
 WHEN 0x10 THEN N'last '
 END +
 CASE
 WHEN (@freq_interval > 00)
 AND (@freq_interval < 08) THEN DATENAME(dw, N'1996120' + CONVERT(NVARCHAR, @freq_interval))
 WHEN (@freq_interval = 08) THEN N'day'
 WHEN (@freq_interval = 09) THEN N'week day'
 WHEN (@freq_interval = 10) THEN N'weekend day'
 END + N' of that month '
 END
IF (@freq_type = 0x40) -- AutoStart
 BEGIN
 SELECT @schedule_description = FORMATMESSAGE(14579)
 RETURN @schedule_description
 END
IF (@freq_type = 0x80) -- OnIdle
 BEGIN
 EXECUTE master.dbo.xp_instance_regread N'HKEY_LOCAL_MACHINE',
 N'SOFTWARE\Microsoft\MSSQLServer\SQLServerAgent',
 N'IdleCPUPercent',
 @idle_cpu_percent OUTPUT,
 N'no_output'
 EXECUTE master.dbo.xp_instance_regread N'HKEY_LOCAL_MACHINE',
 N'SOFTWARE\Microsoft\MSSQLServer\SQLServerAgent',
 N'IdleCPUDuration',
 @idle_cpu_duration OUTPUT,
 N'no_output'
 SELECT @schedule_description = FORMATMESSAGE(14578, ISNULL(@idle_cpu_percent, 10), ISNULL(@idle_cpu_duration, 600))
 RETURN @schedule_description
 END
-- Subday stuff
 SELECT @schedule_description = @schedule_description +
 CASE @freq_subday_type
 WHEN 0x1 THEN N'at ' + CONVERT(NVARCHAR, cast(
 CASE WHEN LEN(cast((@active_start_time / 10000)as varchar(10)))=1
     THEN  '0'+cast((@active_start_time / 10000) as varchar(10))
     ELSE cast((@active_start_time / 10000) as varchar(10))
     END    
as varchar(10)) + ':' + right('00' + cast((@active_start_time % 10000) / 100 as varchar(10)),2))
 WHEN 0x2 THEN N'every ' + CONVERT(NVARCHAR, @freq_subday_interval) + N' second(s)'
 WHEN 0x4 THEN N'every ' + CONVERT(NVARCHAR, @freq_subday_interval) + N' minute(s)'
 WHEN 0x8 THEN N'every ' + CONVERT(NVARCHAR, @freq_subday_interval) + N' hour(s)'
 END
 IF (@freq_subday_type IN (0x2, 0x4, 0x8))
 SELECT @schedule_description = @schedule_description + N' between ' +
CONVERT(NVARCHAR, cast(
CASE WHEN LEN(cast((@active_start_time / 10000)as varchar(10)))=1
     THEN  '0'+cast((@active_start_time / 10000) as varchar(10))
     ELSE cast((@active_start_time / 10000) as varchar(10))
     END    
as varchar(10)) + ':' + right('00' + cast((@active_start_time % 10000) / 100 as varchar(10)),2) ) 
+ N' and ' +
CONVERT(NVARCHAR, cast(
 CASE WHEN LEN(cast((@active_end_time / 10000)as varchar(10)))=1
     THEN  '0'+cast((@active_end_time / 10000) as varchar(10))
     ELSE cast((@active_end_time / 10000) as varchar(10))
     END    
as varchar(10)) + ':' + right('00' + cast((@active_end_time % 10000) / 100 as varchar(10)),2) )


RETURN @schedule_description
END

Я зашел так далеко и потратил слишком много времени, пытаясь выяснить, в чем проблема. Пожалуйста, помогите.

Ответы [ 3 ]

5 голосов
/ 24 июня 2009

ошибки времени компиляции (я запускал 2005): 

Msg 207, Level 16, State 1, Line 106
Invalid column name 'freq_type'.
Msg 207, Level 16, State 1, Line 106
Invalid column name 'freq_interval'.
Msg 207, Level 16, State 1, Line 107
Invalid column name 'freq_subday_type'.
Msg 207, Level 16, State 1, Line 107
Invalid column name 'freq_subday_interval'.
Msg 207, Level 16, State 1, Line 107
Invalid column name 'freq_relative_interval'.
Msg 207, Level 16, State 1, Line 108
Invalid column name 'freq_recurrence_factor'.
Msg 207, Level 16, State 1, Line 108
Invalid column name 'active_start_date'.
Msg 207, Level 16, State 1, Line 108
Invalid column name 'active_end_date'.
Msg 207, Level 16, State 1, Line 109
Invalid column name 'active_start_time'.
Msg 207, Level 16, State 1, Line 109
Invalid column name 'active_end_time'.
Msg 207, Level 16, State 1, Line 110

Я добавил ПЕЧАТИ, и они никогда не появляются.

Ваш код имеет проблемы, потому что имена столбцов несовместимы с базой данных, которую вы используете. В SQL Server 2005 отсутствует столбец «sysjobschedules.freq_type».

Создайте хранимую процедуру XYZ, поместите версию 2000 в базу данных 2000, поместите ту же процедуру XYZ на компьютер 2005 года и вставьте в нее версию 2005 Если ЕСЛИ не нужно ...

EDIT

запустите этот код: 

PRINT 'Works'

теперь запустите этот код 

PRINT 'will not see this'
error

попробуйте это: 

PRINT 'will not see this'
SELECT xyz from sysjobschedules

Теперь попробуйте запустить это, но выделите только строку PRINT: 

PRINT 'you can see this'  --only select this line of code and run it
SELECT xyz from sysjobschedules

посмотрите, как ошибки компиляции мешают запуску чего-либо

EDIT

Вы можете попробовать что-то вроде этого ... 

DECLARE @Query varchar(max)

IF LEFT(CAST(SERVERPROPERTY('ProductVersion') As Varchar),1)='8'
BEGIN
    SET @Query=......
END
IF LEFT(CAST(SERVERPROPERTY('ProductVersion') As Varchar),1)='9'
BEGIN
    SET @Query=......
END

EXEC (@Query)
2 голосов
/ 12 января 2011

Оригинальный вопрос относится только к 2000,2005, но вот код, который должен работать в 2000, 2005, 2008 и далее 

DECLARE @ver NVARCHAR(128)
DECLARE @majorVersion int
SET @ver = CAST(SERVERPROPERTY('productversion') AS NVARCHAR)
SET @ver = SUBSTRING(@ver,1,CHARINDEX('.',@ver)-1)
SET @majorVersion  = CAST(@ver AS INT)
IF @majorVersion < 11
    PRINT 'Plesae Upgrade'
ELSE
    PRINT @majorVersion
0 голосов
/ 24 июня 2009

Я пробовал код на 2008, и он работал нормально.Вы находитесь в базе данных msdb при запуске?

, чтобы получить версию, вы также можете сделать это 

SELECT 
PARSENAME(CONVERT(VARCHAR(100),SERVERPROPERTY('ProductVersion')),4) 
 AS SqlServerVersion
Добро пожаловать на сайт PullRequest, где вы можете задавать вопросы и получать ответы от других членов сообщества.

Нет похожих вопросов

...