Загрузчик дает разные результаты после lgdt на разных виртуальных машинах - PullRequest
Новая
       79

Загрузчик дает разные результаты после lgdt на разных виртуальных машинах

0 голосов
/ 05 июня 2018

Я пишу простой загрузчик.Загрузчик компилируется из двух файлов сборки: boot.asm, protected_start.asm.boot.asm загружает protected_start в 0x10000, устанавливает GDTR, входит в защищенный режим и переходит в 0x10000.Таким образом, кодировка установлена ​​на 16-битный в boot.asm, 32-битный в protected_start.asm.

Я использую QEMU, VMware и NASM в Windows.Обе виртуальные машины имеют 128 МБ памяти.После входа в защищенный режим QEMU успешно переходит к 0x10000 и печатает заданную строку, но VMWare перезагружается.Я использовал «jmp $» для поиска места возникновения ошибки и обнаружил «jmp dword 0x08: 0x0000» в boot.asm. Ошибка:

Версия QEMU - 20180519, VMware - Workstation Player 14.1.2.build-8497320.

Почему "jmp dword 0x08: 0x0000" после того, как LGDT делает ошибку?Что мне нужно сделать, чтобы решить эту проблему?

boot.asm : 

[org 0x7c00]
[bits 16]

load:
    mov     ax,     0x1000
    mov     es,     ax
    mov     bx,     0x0000;

    mov     ah,     0x02;   Read sectors from drive
    mov     al,     0x08;   Number of sectors to read
    mov     ch,     0x00;   Cylinder index
    mov     cl,     0x02;   Sector
    mov     dh,     0x00;   Head
    mov     dl,     0x00;   Drive

    int     0x13
    jc      load

    cli

    lgdt    [gdtr]
    mov     eax,    cr0
    or      eax,    0x00000001
    mov     cr0,    eax

    jmp     dword   0x08:0x0000

gdt_list:
    dw      0
    dw      0
    db      0
    db      0
    db      0
    db      0

.gdt_code:
    dw      0xFFFF
    dw      0x0000
    db      0x01
    db      0x9A
    db      0xCF
    db      0x00

.gdt_data:
    dw      0xFFFF
    dw      0x0000
    db      0x00
    db      0x92
    db      0xCF
    db      0x00

.gdt_video:
    dw      0xFFFF
    dw      0x8000
    db      0x0B
    db      0x92
    db      0xCF
    db      0x00

gdtr:
    dw      4*8
    dd      gdt_list
    times 510 - ($ - $$) db 0
    dw 0xAA55

protected_start.asm : 

[org 0x10000]
[bits 32]

protected:

    mov     ax,     0x10

    mov     ds,     ax
    mov     fs,     ax
    mov     gs,     ax
    mov     ss,     ax
    mov     esp,    0xFFFF
    mov     ebp,    0xFFFF

    mov     ax,     0x18
    mov     es,     ax

    mov     edi,    0x0000
    mov     esi,    my_str
    call    write

    jmp     $
write:
    push    eax
    push    ebx
    mov     ah,     0x0e
    mov     bx,     0x0007
.loop:
    lodsb
    or      al,     al
    jz      .end
    mov     byte [es:edi],  al
    inc     di
    mov     byte [es:edi],  0x0f
    inc     di
    jmp     .loop
.end:
    pop     ebx
    pop     eax
    ret

my_str:
    db "Protected", 0x0 

times 512 - ($ - $$) db 0

Что я использовал для вызова виртуальных машин в PowerShell: 

qemu-system-x86_64 -m 128 -smp 1 -fda ".\bin\os.img"
Invoke-Item ".\virtual\os.vmx"

1 Ответ

0 голосов
/ 06 июня 2018

Инициализация ds до того, как lgdt решит проблему.Поскольку lgdt [gdtr] фактически означает lgdt [ds: gdtr], если ds не задано, может произойти ошибка.Поскольку я использовал [org 0x7c00], я установил ds в 0x0000.Он работает как в QEMU, так и в VMware.

Отредактированная версия boot.asm: 

[org 0x7c00]
[bits 16]

load:
    ; edited part: initialize ds
    mov     ax,     0x0000
    mov     ds,     ax

    mov     ax,     0x1000
    mov     es,     ax
    mov     bx,     0x0000;

    mov     ah,     0x02;   Read sectors from drive
    mov     al,     0x08;   Number of sectors to read
    mov     ch,     0x00;   Cylinder index
    mov     cl,     0x02;   Sector
    mov     dh,     0x00;   Head
    mov     dl,     0x00;   Drive

    int     0x13
    jc      load

    cli

    lgdt    [gdtr]
    mov     eax,    cr0
    or      eax,    0x00000001
    mov     cr0,    eax

    jmp     dword   0x08:0x0000

gdt_list:
    dw      0
    dw      0
    db      0
    db      0
    db      0
    db      0

.gdt_code:
    dw      0xffff
    dw      0x0000
    db      0x01
    db      0x9a
    db      0xcf
    db      0x00

.gdt_data:
    dw      0xffff
    dw      0x0000
    db      0x00
    db      0x92
    db      0xcf
    db      0x00

.gdt_video:
    dw      0xffff
    dw      0x8000
    db      0x0b
    db      0x92
    db      0xcf
    db      0x00

gdtr:
    dw      4*8
    dd      gdt_list

    times 510 - ($ - $$) db 0
    dw 0xAA55
...