Диапазон электронной почты Excel с VBA

Question

Мне понадобится помощь с кодом VBA в Excel (Office 365), который будет принимать Excel диапазон или таблицу и добавлять его в тело письма при отправке почты.Важно, чтобы он работал в фоновом режиме без открытого почтового клиента (Outlook).

У меня есть рабочий код (отлично работает с Outlook в фоновом режиме).Недостатком является то, что я могу связывать только определенные или объединенные ячейки с телом почты (что по сути означает текст, а не простую таблицу).При связывании правильного диапазона (скажем, с 3 столбцами и 5 строками) я получаю сообщение об ошибке

«Ошибка времени выполнения« 13 »: несоответствие типов»

Sub Email()

Dim xOutApp As Object
Dim xOutMail As Object
Dim xMailBody As String

Set xOutApp = CreateObject("Outlook.Application")
Set xOutMail = xOutApp.CreateItem(0)
xMailBody = "E-MAIL BODY TEXT" & vbNewLine & _
Range("ARRAY")

On Error Resume Next

With xOutMail
    .To = "test@mail.com"
    .CC = ""
    .BCC = ""
    .Subject = "Mail subject"
    .Body = xMailBody
    .Send
End With
On Error GoTo 0

Set xOutMail = Nothing
Set xOutApp = Nothing

End Sub

Я выполняю другой код, который действительно может получить диапазон (своего рода) из листа и отправить его в виде таблицы, однако он, к сожалению, работает только тогда, когда Outlook также открыт и работает и выдает сообщение об ошибкев противном случае.

Sub Email2()

Dim sh As Worksheet
Set sh = ThisWorkbook.Sheets("Sheet1")

Dim lr As Integer

lr = sh.Range("D" & Application.Rows.Count).End(xlUp).Row

sh.Range("D5:F" & lr).Select

With Selection.Parent.MailEnvelope.Item
.to = "test@mail.com"
.bcc = ""
.Subject = ""
.send

End With
End Sub

Какие-либо советы по корректировке существующего кода или по новому подходу?

Answer 1

Этот код немного сложнее того, что вы показали, но он должен хорошо выполнять свою работу.Очевидно, измените его в соответствии с вашими потребностями.

Sub Mail_Selection_Range_Outlook_Body()
'For Tips see: http://www.rondebruin.nl/win/winmail/Outlook/tips.htm
'Don't forget to copy the function RangetoHTML in the module.
'Working in Excel 2000-2016
    Dim rng As Range
    Dim OutApp As Object
    Dim OutMail As Object

    Set rng = Nothing
    On Error Resume Next
    'Only the visible cells in the selection
    Set rng = Selection.SpecialCells(xlCellTypeVisible)
    'You can also use a fixed range if you want
    'Set rng = Sheets("YourSheet").Range("D4:D12").SpecialCells(xlCellTypeVisible)
    On Error GoTo 0

    If rng Is Nothing Then
        MsgBox "The selection is not a range or the sheet is protected" & _
               vbNewLine & "please correct and try again.", vbOKOnly
        Exit Sub
    End If

    With Application
        .EnableEvents = False
        .ScreenUpdating = False
    End With

    Set OutApp = CreateObject("Outlook.Application")
    Set OutMail = OutApp.CreateItem(0)

    On Error Resume Next
    With OutMail
        .To = "ron@debruin.nl"
        .CC = ""
        .BCC = ""
        .Subject = "This is the Subject line"
        .HTMLBody = RangetoHTML(rng)
        .Send   'or use .Display
    End With
    On Error GoTo 0

    With Application
        .EnableEvents = True
        .ScreenUpdating = True
    End With

    Set OutMail = Nothing
    Set OutApp = Nothing
End Sub


Function RangetoHTML(rng As Range)
' Changed by Ron de Bruin 28-Oct-2006
' Working in Office 2000-2016
    Dim fso As Object
    Dim ts As Object
    Dim TempFile As String
    Dim TempWB As Workbook

    TempFile = Environ$("temp") & "\" & Format(Now, "dd-mm-yy h-mm-ss") & ".htm"

    'Copy the range and create a new workbook to past the data in
    rng.Copy
    Set TempWB = Workbooks.Add(1)
    With TempWB.Sheets(1)
        .Cells(1).PasteSpecial Paste:=8
        .Cells(1).PasteSpecial xlPasteValues, , False, False
        .Cells(1).PasteSpecial xlPasteFormats, , False, False
        .Cells(1).Select
        Application.CutCopyMode = False
        On Error Resume Next
        .DrawingObjects.Visible = True
        .DrawingObjects.Delete
        On Error GoTo 0
    End With

    'Publish the sheet to a htm file
    With TempWB.PublishObjects.Add( _
         SourceType:=xlSourceRange, _
         Filename:=TempFile, _
         Sheet:=TempWB.Sheets(1).Name, _
         Source:=TempWB.Sheets(1).UsedRange.Address, _
         HtmlType:=xlHtmlStatic)
        .Publish (True)
    End With

    'Read all data from the htm file into RangetoHTML
    Set fso = CreateObject("Scripting.FileSystemObject")
    Set ts = fso.GetFile(TempFile).OpenAsTextStream(1, -2)
    RangetoHTML = ts.readall
    ts.Close
    RangetoHTML = Replace(RangetoHTML, "align=center x:publishsource=", _
                          "align=left x:publishsource=")

    'Close TempWB
    TempWB.Close savechanges:=False

    'Delete the htm file we used in this function
    Kill TempFile

    Set ts = Nothing
    Set fso = Nothing
    Set TempWB = Nothing
End Function