В Perl, как вы динамически выбираете, какой метод использовать в качестве обратного вызова?

Question

В Perl довольно просто указывать обратный вызов или ссылку на код, если известен его пакет:

package Foo;

sub foo { print "in foo" }

# and then
package main;

sub baz {
    my $code = shift;
    $code->();
}

baz( \&Foo::foo );

А это печатает in foo.

Допустим, у вас есть какой-то тривиальный объект, подобный этому:

package Foo;

sub new { bless {}, shift }
sub bar { print "in bar" }
sub baz { print "in baz" }

Вы можете найти метод, используя вышеуказанный способ (\ & Package: Method), и вызвать его как

package main;
my $foo = Foo->new();
my $ref = \&Foo::bar;
$foo->$ref();

Но иногда (хорошо, часто) вы не знаете явный тип. Допустим, есть Foo, Bar, Baz, и все они имеют свой собственный метод blat. Вы хотели бы получить ссылку на соответствующий метод, основываясь на объекте, а не на пакете. Как бы вы поступили об этом?

Answer 1

my $ref = $obj->can('blat');

Если $ ref не определен, ваш объект не может всплыть. Если $ ref не undef, это действительная ссылка на CODE для рассматриваемой функции, подходящая для вызова «$ obj -> $ ref (@args)».

Answer 2

Пусть поиск метода сделает всю работу за вас:

$ cat try
#! /usr/bin/perl

use warnings;
use strict;

package Foo;
sub new { bless {} => shift }
sub blat { "Foo blat" }

package Bar;
sub new { bless {} => shift }
sub blat { "Bar blat" }

package Baz;
sub new { bless {} => shift }
sub blat { "Baz blat" }

package main;

my $method = "blat";
foreach my $obj (Foo->new, Bar->new, Baz->new) {
  print $obj->$method, "\n";
}

$ ./try
Foo blat
Bar blat
Baz blat

Если вам нужна ссылка, имейте в виду, что в Perl нет делегатов, но вы можете подойти ближе:

my @objs = (Foo->new, Bar->new, Baz->new);

my $method = "blat";
my $obj = $objs[rand @objs];
my $ref = $obj->can($method);

if ($ref) {
  print $ref->($obj), "\n";
}
else {
  print "$obj: no can $method\n";
}

Еще ближе было бы:

my $delegate = sub { $obj->$ref };
#           or sub { $obj->$method }
print $delegate->(), "\n";