Замена почтовых доменов - PullRequest
0 голосов
/ 07 октября 2018

Я пытаюсь изменить введенное доменное имя на новое доменное имя, например, «hotmail.com» становится «outlook.com».Я считаю, что я на правильном пути, просто моя подстрока выключена.

CREATE OR REPLACE PROCEDURE PR_ChangeDomain
(P_Email_Address varchar2)
IS
Cursor C_Email IS
  Select Email_Address, Broker_Number
  From Customer
  Where Email_Address = P_Email_Address;

  V_Email varchar2(50);

BEGIN
  Open C_Email;
  Fetch C_Email into V_Email;

  While C_Email%FOUND LOOP 
  Update Customer 
  Set Email_Address = SUBSTR((Email_Address), V_Email)
  Where Email_Address = P_Email_Address; 

  Fetch C_Email into V_Email;
  End Loop;
  Close C_Email;
  End PR_ChangeDomain;
  /

1 Ответ

0 голосов
/ 08 октября 2018

Код, который вы написали, не имеет особого смысла;слишком много выборок, которые не будут работать (два столбца в одной переменной?).

Вот пример: тестовая таблица:

SQL> create table test (email varchar2(30));

Table created.

SQL> insert into test
  2    select 'lf@hotmail.com' from dual union all
  3    select 'bigfoot@net.hr' from dual union all
  4    select 'stack@gmail.com' from dual union all
  5    select 'overflow@gmail.com' from dual;

4 rows created.

Как отделить часть домена от нее (2-йследующий столбец SELECT) и обновить адреса электронной почты для нового домена (3-й столбец):

SQL> select email,
  2    substr(email, instr(email, '@') + 1) domain,
  3    replace(email,
  4            substr(email, instr(email, '@') + 1),
  5            'new_domain.com'
  6           ) result
  7  from test;

EMAIL                     DOMAIN          RESULT
------------------------- --------------- -------------------------
lf@hotmail.com            hotmail.com     lf@new_domain.com
bigfoot@net.hr            net.hr          bigfoot@new_domain.com
stack@gmail.com           gmail.com       stack@new_domain.com
overflow@gmail.com        gmail.com       overflow@new_domain.com

SQL>

Давайте обновим только адреса электронной почты Gmail для нового домена:

SQL> update test set
  2    email = replace(email,
  3                    substr(email, instr(email, '@') + 1),
  4                    'new_domain.com'
  5                   )
  6  where substr(email, instr(email, '@') + 1) = 'gmail.com';

2 rows updated.

SQL> select * From test;

EMAIL
-------------------------
lf@hotmail.com
bigfoot@net.hr
stack@new_domain.com
overflow@new_domain.com

SQL>

Если вы хотите преобразовать его в процедуру, нет проблем:

SQL> rollback;

Rollback complete.

SQL> create or replace procedure p_change_domain
  2    (par_old_domain in varchar2,
  3     par_new_domain in varchar2)
  4  is
  5  begin
  6    update test set
  7      email = replace(email,
  8                      substr(email, instr(email, '@') + 1),
  9                      par_new_domain
 10                     )
 11    where substr(email, instr(email, '@') + 1) = par_old_domain;
 12  end;
 13  /

Procedure created.

SQL> exec p_change_domain('gmail.com', 'new_domain_2.com');

PL/SQL procedure successfully completed.

SQL> select * From test;

EMAIL
-------------------------
lf@hotmail.com
bigfoot@net.hr
stack@new_domain_2.com
overflow@new_domain_2.com

SQL>

Если вы отчаянно хотите использовать курсоры (я не знаю, зачем вам это делать; вероятно, это будетсамый неэффективный вариант), здесь вы идете:

SQL> rollback;

Rollback complete.

SQL> create or replace procedure p_change_domain
  2    (par_old_domain in varchar2,
  3     par_new_domain in varchar2)
  4  is
  5  begin
  6    for cur_r in (select email from test
  7                  where substr(email, instr(email, '@') + 1) = par_old_domain
  8                 )
  9    loop
 10      update test set
 11        email = replace(email,
 12                        substr(email, instr(email, '@') + 1),
 13                        par_new_domain
 14                       )
 15        where email = cur_r.email;
 16    end loop;
 17  end;
 18  /

Procedure created.

SQL> exec p_change_domain('gmail.com', 'new_domain_3.com');

PL/SQL procedure successfully completed.

SQL> select * From test;

EMAIL
-------------------------
lf@hotmail.com
bigfoot@net.hr
stack@new_domain_3.com
overflow@new_domain_3.com

SQL>

Цикл курсора FOR легче поддерживать, чем ваша попытка (создание курсора и переменной курсора, открытие курсора, выборка из него, забота о выходецикл, закрывающий курсор).

Но, если вы не можете без него жить, вы идете:

SQL> rollback;

Rollback complete.

SQL> create or replace procedure p_change_domain
  2    (par_old_domain in varchar2,
  3     par_new_domain in varchar2)
  4  is
  5    cursor c1 is
  6      select email from test
  7      where substr(email, instr(email, '@') + 1) = par_old_domain;
  8    c1r c1%rowtype;
  9  begin
 10    open c1;
 11    loop
 12      fetch c1 into c1r;
 13      exit when c1%notfound;
 14
 15      update test set
 16        email = replace(email,
 17                        substr(email, instr(email, '@') + 1),
 18                        par_new_domain
 19                       )
 20        where email = c1r.email;
 21    end loop;
 22    close c1;
 23  end;
 24  /

Procedure created.

SQL> exec p_change_domain('gmail.com', 'new_domain_4.com');

PL/SQL procedure successfully completed.

SQL> select * From test;

EMAIL
-------------------------
lf@hotmail.com
bigfoot@net.hr
stack@new_domain_4.com
overflow@new_domain_4.com

SQL>

Мое предложение?Используйте чистый SQL, если это возможно.Или первая процедура PL / SQL.Не используйте курсоры для этой цели.

...