Файл не открывается в MQL4 - PullRequest
Новая
       11

Файл не открывается в MQL4

0 голосов
/ 08 октября 2018

Я надеялся, что кто-нибудь сможет взглянуть на мой код и сказать, почему он не открывает файл.Это в мета-редакторе, программном обеспечении для MQL4.Все остальное работает правильно.Также нет ошибок.Он просто не откроет файл.Значение Handle равно единице при открытии файла.Эта функция прекрасно работает на MQL5, а не на MQL4.Это проблема исключительно с MQL4 или что-то с моим кодом 

//+------------------------------------------------------------------+
//|                                                  DailyReport.mq4 |
//|                        Copyright 2018, MetaQuotes Software Corp. |
//|                                             https://www.mql5.com |
//+------------------------------------------------------------------+
#property copyright "Copyright 2018, MetaQuotes Software Corp."
#property link      "https://www.mql5.com"
#property version   "1.00"
#property strict

int OnStart()
  {

  int Handle;
  Handle = FileOpen("Indicator Output", FILE_WRITE|FILE_TXT);

  if(Handle == INVALID_HANDLE){
      Alert("Error while opening file");
      return(-1);
  }

  int count = 0;
  int end_value = count + 100;

  double open_value; 
  while (count < end_value){

   string string1, string2, string3, string4, string5, final_string;
   double values[5]; 

   values[0] = iMomentum(0, 0, 14, 0, count); //calculated at closing
   values[1] = iStochastic(0, 0, 5, 3, 3, 0, 0, 0, count);
   values[2] = iMA(0,0, 14, 0, 0, 0, count); //this is calculating at close
   values[3] = iMFI(0, 0, 14,count);
   values[4] = iOpen(0, 0, count);

   open_value = iOpen(0, 0, count + 1);

   if (values[0] >= 100){
      values[0] = 1;
   }
   else{
      values[0] = 0;
   }

   if (values[1] >= 50){
      values[1] = 1;
   }
   else{
      values[1] = 0;
   } 

   if (values[2] >= values[4]){
      values[2] = 1;
   }
   else{
      values[2] = 0;
   }   

   if (values[3] >= 50){
      values[3] = 1;
   }
   else{
      values[3] = 0;
   }   

   if (values[4] >= open_value){
      values[4] = 1;
   }
   else{
      values[4] = 0;
   }   

   string1 = IntegerToString(values[0], 1, " ");
   string2 = IntegerToString(values[1], 1, " ");
   string3 = IntegerToString(values[2], 1, " ");
   string4 = IntegerToString(values[3], 1, " ");
   string5 = IntegerToString(values[4], 1, " ");

   final_string = string1 + " " + string2 + " " + string3 + " " + string4 + " " + string5;
   printf(final_string);

   FileWrite(Handle, final_string);

   count = count + 1;
  }
  FileClose(Handle);
  return(1);
  }

Ответы [ 2 ]

0 голосов
/ 09 октября 2018

Вот несколько советов:

  • Обработчик события OnStart имеет тип void.void OnStart(){}

  • Цикл while можно улучшить с помощью цикла for

  • Вы открываете свой файл как текстовый файл без соответствующего файларасширение.то есть .txt, и вы используете FileWrite, который предназначен для CSV-файлов.Возможно, вы захотите взглянуть на документы и открыть файл как CSV и использовать FileWrite так, как он предназначен, для автоматической вставки разделителей.

  • При желании вы можете использовать объект CFile для работы с файлами, поскольку он автоматически закрывает файлы.

  • Вам не нужно использовать массив для временного хранениязначения индикатора.Это сбивает с толку.Вместо этого используйте описательные имена переменных.
  • троичные операторы могут значительно упростить и сократить ваш код.

Вот так это выглядит при рефакторинге.

#property strict

#include <Files\File.mqh>
#include <stdlib.mqh>

void OnStart()
{
   CFile file;
   file.Open("indicator_output.csv", FILE_WRITE|FILE_CSV, ',');
   if(file.Handle() == INVALID_HANDLE){
      Print("FileOpenError: ", ErrorDescription(_LastError));
      return;
   }
   for(int i=0; i<100; i++){
      double mom = iMomentum(NULL, 0, 14, 0, i); //calculated at closing
      double sto = iStochastic(NULL, 0, 5, 3, 3, 0, 0, 0, i);
      double sma = iMA(NULL, 0, 14, 0, 0, 0, i); //this is calculating at close
      double mfi = iMFI(NULL, 0, 14, i);
      double open = iOpen(NULL, 0, i);
      double prev = iOpen(NULL, 0, i + 1);  
      uint row_bytes = FileWrite(file.Handle(),
         mom >= 100   ? 1 : 0,
         sto >= 50    ? 1 : 0,
         sma > open   ? 1 : 0,
         mfi >= 50    ? 1 : 0,
         open >= prev ? 1 : 0
      );
      if(row_bytes == 0){
         Print("FileWriteError: ", ErrorDescription(_LastError));
         break;
      }
   }
   Alert(StringFormat("%s written with a size of %d bytes.",
      file.FileName(),
      file.Size()
   ));
}
0 голосов
/ 08 октября 2018

File функции работают одинаково в MQL4 и MQL5.Во-первых, вы должны проверить причину, по которой вы не можете открыть файл (в противном случае у вас не будет никакой ошибки, как вы написали). 

if(Handle==INVALID_HANDLE){
   Alert("failed to open file. error=",GetLastError());
   return;}

Далее, имя файла должно быть передано с расширением, в противном случае это может быть проблемойоткрыть его в редакторе.string fileName = "Индикатор Output.txt";int handle = FileOpen (fileName, FILE_WRITE | FILE_TXT);

Основная причина может заключаться в том, что вы открыли файл и забыли закрыть его во время работы над кодом.Самый простой способ проверить это - закрыть MT4, снова открыть и попробовать скрипт.Все открытые МТ4 файлы закрываются при выключении МТ4.Если это не поможет - проверьте ошибку.

...