Clojure: преобразование вложенных карт в пользовательскую карту с сохранением только определенных атрибутов - PullRequest
Новая
       7

Clojure: преобразование вложенных карт в пользовательскую карту с сохранением только определенных атрибутов

0 голосов
/ 08 октября 2018

У меня есть вектор карт (результат xml / parse), который содержит следующий вектор вложенных карт (я уже избавился от некоторых частей, которые не хочу сохранять): 

[
{:tag :SoapObject, :attrs nil, :content [
    {:tag :ObjectData, :attrs nil, :content [
        {:tag :FieldName, :attrs nil, :content ["ID"]}
        {:tag :FieldValue, :attrs nil, :content ["8d8edbb6-cb0f-11e8-a8d5-f2801f1b9fd1"]}
    ]}
    {:tag :ObjectData, :attrs nil, :content [
        {:tag :FieldName, :attrs nil, :content ["Attribute_1"]}
        {:tag :FieldValue, :attrs nil, :content ["Value_1a"]}
    ]} 
    {:tag :ObjectData, :attrs nil, :content [
        {:tag :FieldName, :attrs nil, :content ["Attribute_2"]}
        {:tag :FieldValue, :attrs nil, :content ["Value_2a"]}
    ]} 
]}
{:tag :SoapObject, :attrs nil, :content [
    {:tag :ObjectData, :attrs nil, :content [
        {:tag :FieldName, :attrs nil, :content ["ID"]}
        {:tag :FieldValue, :attrs nil, :content ["90e39036-cb0f-11e8-a8d5-f2801f1b9fd1"]}
    ]}
    {:tag :ObjectData, :attrs nil, :content [
        {:tag :FieldName, :attrs nil, :content ["Attribute_1"]}
        {:tag :FieldValue, :attrs nil, :content ["Value_1b"]}
    ]}
    {:tag :ObjectData, :attrs nil, :content [
        {:tag :FieldName, :attrs nil, :content ["Attribute_2"]}
        {:tag :FieldValue, :attrs nil, :content ["Value_2b"]}
    ]}
]}
]

Теперь я хочу извлечь только некоторые конкретные данные из этой структуры, получив результат, который выглядит следующим образом: 

[
{"ID" "8d8edbb6-cb0f-11e8-a8d5-f2801f1b9fd1",
"Attribute_1" "Value_1a",
"Attribute_2" "Value_1a"}

{"ID" "90e39036-cb0f-11e8-a8d5-f2801f1b9fd1",
"Attribute_1" "Value_1b",
"Attribute_2" "Value_1b"}
]

Какой инструмент clojure мог бы помочь мне достичь этого?

Я нашел другой вопрос , который немного похож, но всякий раз, когда я пробовал какую-то версию вызова карты, я получал какой-то тип clojure.lang.LazySeq или clojure.core $ map, которую я не смог правильно распечатать, чтобы проверить результат.

Ответы [ 5 ]

0 голосов
/ 08 июля 2019

Используя perc, вы можете сделать что-то вроде этого: 

(->> original-data
  (mapv
    #%/%(->> %:content
          (map
            #%/$(->> $:content
                  (apply
                    #%/?{(first ?1:content)
                         (first ?2:content)})))
          (apply merge))))

Это может показаться немного более идиоматичным, но по-другому.

0 голосов
/ 09 октября 2018

Здесь не нужны модные инструменты.Вы можете уйти с простейшей частью кода. 

(use '[plumbing.core])
(let [A ...your-data...]
    (map (fn->> :content
            (mapcat :content)
            (mapcat :content)
            (apply hash-map)) 
         A))
0 голосов
/ 08 октября 2018

Вы можете легко решать задачи на основе дерева, используя библиотеку Tupelo Forest.Вы можете посмотреть видео-введение из прошлогоднего Clojure Conj здесь .

Для вашей проблемы я подхожу к этому следующим образом.Сначала данные: 

(dotest
  (let [data-enlive
        {:tag   :root
         :attrs nil
         :content
            [{:tag     :SoapObject, :attrs nil,
              :content 
                 [{:tag     :ObjectData, :attrs nil,
                   :content [{:tag :FieldName, :attrs nil, :content ["ID"]}
                             {:tag :FieldValue, :attrs nil, :content ["8d8edbb6-cb0f-11e8-a8d5-f2801f1b9fd1"]}]}
                  {:tag     :ObjectData, :attrs nil,
                   :content [{:tag :FieldName, :attrs nil, :content ["Attribute_1"]}
                             {:tag :FieldValue, :attrs nil, :content ["Value_1a"]}]}
                  {:tag     :ObjectData, :attrs nil,
                   :content [{:tag :FieldName, :attrs nil, :content ["Attribute_2"]}
                             {:tag :FieldValue, :attrs nil, :content ["Value_2a"]}]}]}
             {:tag     :SoapObject, :attrs nil,
              :content
                 [{:tag     :ObjectData, :attrs nil,
                   :content [{:tag :FieldName, :attrs nil, :content ["ID"]}
                             {:tag :FieldValue, :attrs nil, :content ["90e39036-cb0f-11e8-a8d5-f2801f1b9fd1"]}]}
                  {:tag     :ObjectData, :attrs nil,
                   :content [{:tag :FieldName, :attrs nil, :content ["Attribute_1"]}
                             {:tag :FieldValue, :attrs nil, :content ["Value_1b"]}]}
                  {:tag     :ObjectData, :attrs nil,
                   :content [{:tag :FieldName, :attrs nil, :content ["Attribute_2"]}
                             {:tag :FieldValue, :attrs nil, :content ["Value_2b"]}]}]}]}]

, а затем код 

(with-debug-hid
  (with-forest (new-forest)
    (let [root-hid     (add-tree-enlive data-enlive)
          soapobj-hids (find-hids root-hid [:root :SoapObject])
          objdata->map (fn [objdata-hid]
                         (let [fieldname-node  (hid->node (find-hid objdata-hid [:ObjectData :FieldName]))
                               fieldvalue-node (hid->node (find-hid objdata-hid [:ObjectData :FieldValue]))]
                           { (grab :value fieldname-node) (grab :value fieldvalue-node) }))
          soapobj->map (fn [soapobj-hid]
                         (apply glue
                           (for [objdata-hid (hid->kids soapobj-hid)]
                             (objdata->map objdata-hid))))
          results      (mapv soapobj->map soapobj-hids)]

с промежуточными результатами: 

          (is= (hid->bush root-hid)
            [{:tag :root}
             [{:tag :SoapObject}
              [{:tag :ObjectData}
               [{:tag :FieldName, :value "ID"}]
               [{:tag :FieldValue, :value "8d8edbb6-cb0f-11e8-a8d5-f2801f1b9fd1"}]]
              [{:tag :ObjectData}
               [{:tag :FieldName, :value "Attribute_1"}]
               [{:tag :FieldValue, :value "Value_1a"}]]
              [{:tag :ObjectData}
               [{:tag :FieldName, :value "Attribute_2"}]
               [{:tag :FieldValue, :value "Value_2a"}]]]
             [{:tag :SoapObject}
              [{:tag :ObjectData}
               [{:tag :FieldName, :value "ID"}]
               [{:tag :FieldValue, :value "90e39036-cb0f-11e8-a8d5-f2801f1b9fd1"}]]
              [{:tag :ObjectData}
               [{:tag :FieldName, :value "Attribute_1"}]
               [{:tag :FieldValue, :value "Value_1b"}]]
              [{:tag :ObjectData}
               [{:tag :FieldName, :value "Attribute_2"}]
               [{:tag :FieldValue, :value "Value_2b"}]]]])
          (is= soapobj-hids [:0009 :0013])

и окончательными результатами: 

          (is= results
            [{"ID"          "8d8edbb6-cb0f-11e8-a8d5-f2801f1b9fd1",
              "Attribute_1" "Value_1a",
              "Attribute_2" "Value_2a"}
             {"ID"          "90e39036-cb0f-11e8-a8d5-f2801f1b9fd1",
              "Attribute_1" "Value_1b",
              "Attribute_2" "Value_2b"}]))))))

Дальнейшая документация еще продолжается, но вы можете посмотреть документацию по API здесь и живой пример вашей проблемы здесь .

0 голосов
/ 09 октября 2018

Вы также можете создавать преобразователи.На днях я читал в блоге JUXT кое-что о создании функциональности, подобной xpath, с помощью преобразователей.

(def children (map :content))

(defn tagp [pred]
  (filter (comp pred :tag)))

(defn tag= [tag-name]
  (tagp (partial = tag-name)))

(def text (comp (mapcat :content) (filter string?)))

(defn fields [obj-datas]
  (sequence (comp
             (tag= :ObjectData)
             (mapcat :content)
             text)
            obj-datas))

(defn clean [xml-map]
  (let [fields-list (sequence (comp
                               (tag= :SoapObject)
                               children
                               (map fields))
                              xml-map)]
    (map (partial apply hash-map) fields-list)))
0 голосов
/ 08 октября 2018

обычно вы можете начинать снизу, постепенно увеличиваясь:

сначала вы хотите проанализировать атрибут attr: 

(def first-content (comp first :content))

(defn get-attr [{[k v] :content}]
  [(first-content k)
   (first-content v)])

user> (get-attr {:tag :ObjectData, :attrs nil, :content [
        {:tag :FieldName, :attrs nil, :content ["ID"]}
        {:tag :FieldValue, :attrs nil, :content ["90e39036-cb0f-11e8-a8d5-f2801f1b9fd1"]}
        ]})
;;=> ["ID" "90e39036-cb0f-11e8-a8d5-f2801f1b9fd1"]

, затем вы превратите каждый элемент в картуattrs: 

(defn parse-item [item]
  (into {} (map get-attr (:content item))))

(parse-item {:tag :SoapObject, :attrs nil, :content [
    {:tag :ObjectData, :attrs nil, :content [
        {:tag :FieldName, :attrs nil, :content ["ID"]}
        {:tag :FieldValue, :attrs nil, :content ["90e39036-cb0f-11e8-a8d5-f2801f1b9fd1"]}
    ]}
    {:tag :ObjectData, :attrs nil, :content [
        {:tag :FieldName, :attrs nil, :content ["Attribute_1"]}
        {:tag :FieldValue, :attrs nil, :content ["Value_1b"]}
    ]}
    {:tag :ObjectData, :attrs nil, :content [
        {:tag :FieldName, :attrs nil, :content ["Attribute_2"]}
        {:tag :FieldValue, :attrs nil, :content ["Value_2b"]}
    ]}
]})

;;=> {"ID" "90e39036-cb0f-11e8-a8d5-f2801f1b9fd1", "Attribute_1" "Value_1b", "Attribute_2" "Value_2b"}

поэтому последнее, что вам нужно сделать, это отобразить форму верхнего уровня, чтобы получить требуемый результат: 

(mapv parse-item data)

;;=> [{"ID" "8d8edbb6-cb0f-11e8-a8d5-f2801f1b9fd1", "Attribute_1" "Value_1a", "Attribute_2" "Value_2a"} 
;;    {"ID" "90e39036-cb0f-11e8-a8d5-f2801f1b9fd1", "Attribute_1" "Value_1b", "Attribute_2" "Value_2b"}]
Добро пожаловать на сайт PullRequest, где вы можете задавать вопросы и получать ответы от других членов сообщества.

Похожие темы

...