Вывод эха для каждого значения в данном списке в файле bat

Question

С кодом ниже я изо всех сил пытаюсь напечатать расчет для каждого значения в данном списке.В настоящее время он печатает общее объединенное время для обоих пользователей, я хочу отобразить индивидуальное время для каждого пользователя, которое указано во 2-й строке этого кода. \ Любая помощь будет оценена.

@Echo off
For %%U in (a3rgcw shukla) Do (

PushD "H:\Syslogs\" ||(Echo couldn't find dir & Pause & Exit /B 1)

Set "TotalSecs=0"

For %%F in ("*%U%*.txt") Do For /F "delims=" %%A in ('
    findstr /I "system.log.created End.of.session" "%%F"
') Do (
    Set "Flag="
    Echo=%%A|findstr /I "system.log.created" 2>&1>Nul && Set "Flag=Start"
    if defined Flag (
        FOR /F "tokens=11" %%T in ("%%A") Do Call :TimeToSecs Start "%%T"
    ) Else (
        FOR /F "tokens=8" %%T in ("%%A") Do Call :TimeToSecs Stop "%%T"
    )
)
Echo TotalDuration for %%U:%TotalDur%
)
Echo:
PopD
Goto :Eof

:TimeToSecs
Set "%1_HMS=%~2"
Echo:%~2|Findstr "[0-2][0-9]:[0-5][0-9]:[0-5][0-9]" 2>&1>Nul || (Echo wrong format %2&Goto :Eof)
For /F "tokens=1-3 delims=:" %%H in ("%~2"
) Do Set /A "%1=(1%%H-100)*60*60+(1%%I-100)*60+(1%%J-100)"
If %1 neq Stop Goto :Eof
Set /A "Diff=Stop-Start,TotalSecs+=Diff"
Call :Secs2HMS Dur %Diff%
Call :Secs2HMS TotalDur %TotalSecs%
::Echo Session from %Start_HMS% to %Stop_HMS% Duration:%Dur%      TotalDuration:%TotalDur%


Goto :Eof

:Secs2HMS var value
setlocal
set /a "HH=%2/3600,mm=(%2-HH*3600)/60+100,ss=%2 %% 60+100"
Set "HHmmss=   %HH%:%mm:~-2%:%ss:~-2%"
endlocal&set "%1=%HHmmss:~-10%
Goto :Eof

Текущий вывод:

TotalDuration for a3rgcw:   7:15:00
TotalDuration for shukla:   7:15:00

Желаемый вывод:

TotalDuration for a3rgcw:   5:15:00
TotalDuration for shukla:   2:00:00

Пример файла с именем shukladfdf для второго пользователя:

sdsdf system log created on  ghg Thursday, 9 August 2018, 20:30:45 on India 
Standard Time
dfg
drdwewed
end of session as 9 August 2018, 22:30:45 on India Standard Time

Answer 1

@Echo off
Setlocal

PushD "H:\Syslogs\" ||(Echo couldn't find dir & Pause & Exit /B 1)

For %%U in (a3rgcw shukla) Do (

    Set "TotalDur="
    Set "TotalSecs=0"

    For %%F in ("*%%U*.txt") Do For /F "delims=" %%A in ('
        findstr /I "system.log.created End.of.session" "%%F"
    ') Do (
        Set "FileName=%%F"
        Set "Flag="
        Echo=%%A|findstr /I "system.log.created" 2>&1>Nul && Set "Flag=Start"
        if defined Flag (
            FOR /F "tokens=11" %%T in ("%%A") Do Call :TimeToSecs Start "%%T"
        ) Else (
            FOR /F "tokens=8" %%T in ("%%A") Do Call :TimeToSecs Stop "%%T"
        )
    )

    Set "UsrName=%%U:          "
    Call :Print UsrName
)
Echo:
PopD
Goto :Eof

:Print
If /i "%~1" == "UsrName" (
    Echo TotalDuration for %UsrName:~,10% %TotalDur%
) else If /i "%~1" == "FileName" (
    Echo Session (%FileName%^) from %Start_HMS% to %Stop_HMS% Duration:%Dur%      TotalDuration:%TotalDur%
)
Goto :Eof

:TimeToSecs
Set "%1_HMS=%~2"
Echo:%~2|Findstr "[0-2][0-9]:[0-5][0-9]:[0-5][0-9]" 2>&1>Nul || (Echo wrong format %2&Goto :Eof)
For /F "tokens=1-3 delims=:" %%H in ("%~2"
) Do Set /A "%1=(1%%H-100)*60*60+(1%%I-100)*60+(1%%J-100)"
If %1 neq Stop Goto :Eof
Set /A "Diff=Stop-Start,TotalSecs+=Diff"
Call :Secs2HMS Dur %Diff%
Call :Secs2HMS TotalDur %TotalSecs%
Call :Print FileName
Goto :Eof

:Secs2HMS var value
setlocal
set /a "HH=%2/3600,mm=(%2-HH*3600)/60+100,ss=%2 %% 60+100"
Set "HHmmss=   %HH%:%mm:~-2%:%ss:~-2%"
endlocal&set "%1=%HHmmss:~-10%"
Goto :Eof

Изменено %U% на %%U.

Изменено Echo TotalDuration for %%U:%TotalDur% на Call Echo TotalDuration for %%U:%%TotalDur%%, что задерживает расширение до времени выполнения вместо времени разбора.

Добавлено пропущенодвойная кавычка с закрытием 2-ой последней строки.

Добавлен Setlocal в начало сценария, так как, возможно, 2-й запуск сценария в том же сеансе CMD может установить предопределенные переменные со значениями.

Добавленометка :Print для вывода вывода во избежание использования отложенного расширения.