Заменить элементы в массиве с помощью глагола J `I.`

Question

Вот простая замена для списка ранга 1 с использованием глагола I.:

y=: _3 _2 _1 1 2 3
0 (I. y<0) } y

Результат:

0 0 0 1 2 3

Как мне сделать такую ​​замену дляматрица ранга 2?

Например,

y2 =: 2 3 $ _3 _2 _1 1 2 3
0 (I. y2<0) } y2

Я получил (J806)

|index error
|   0    (I.y2<2)}y2

Причина, по-видимому,

(I. y2 < 0)

дает

0 1 2
0 0 0

, что не очень хорошо к }.

Answer 1

Самый простой ответ для этой проблемы - использовать двоичную >. ( Больше ) ...

   0 >. y2
0 0 0
1 2 3

Если вы хотите использовать более общие критерии условной замены,тогда может пригодиться следующая форма:

   (0 > y2)} y2 ,: 0
0 0 0
1 2 3

Если вы хотите использовать ее как глагол, вы можете использовать форму gerund (v1`v2)} y ↔ (v1 y)} (v2 y):

   (0 > ])`(0 ,:~ ])} y2
0 0 0
1 2 3

Если ваш вопрос больше касается замены индекса разброса, то это тоже возможно.Вам нужно получить двумерные индексы позиций, которые вы хотите заменить, например:

   4 $. $. 0 > y2
0 0
0 1
0 2

Теперь пометьте эти индексы и используйте двоичные числа }:

   0 (<"1 (4 $. $. 0 > y2)) } y2
0 0 0
1 2 3

Снова вы можете повернутьэто в глагол, используя аргумент с левой стороны от герунди к диадическому } (x (v0`v1`v2)} y ↔ (x v0 y) (x v1 y)} (x v2 y)), например:

   0  [`([: (<"1) 4 $. [: $. 0 > ])`]} y2
0 0 0
1 2 3

или

   100 101 102  [`([: (<"1) 4 $. [: $. 0 > ])`]} y2
100 101 102
  1   2   3

Чтобы привести в порядок это, вы можете определитьgetIdx как отдельный глагол ...

   getIdx=: 4 $. $.
   0 [`([: <"1@getIdx 0 > ])`]} y2
0 0 0
1 2 3

Answer 2

Это не хорошее решение.Мой первоначальный подход состоял в том, чтобы изменить ранг теста так, чтобы он смотрел на каждую строку отдельно, но в общем случае это не работает (см. Комментарии ниже).

 [y2 =: 2 3 $ _3 _2 _1 1 2 3  
_3 _2 _1
 1  2  3


   I. y2<0
0 1 2
0 0 0


   0 (I. y2<0)"1 } y2  NB. Rank of 1 applies to each row of y2
0 0 0
1 2 3