Terraform создает виртуальную машину из образа управляемого диска

Question

Я хочу получить образ торговой площадки на управляемый диск, а затем подключить этот управляемый диск к виртуальной машине Azure с помощью Terraform.

Это позволяет изменить конфигурацию виртуальной машины, после которой удаляются и восстанавливаютсявиртуальная машина не повреждена.

Я нашел людей с похожими проблемами, но проблемы закрываются, и не остается примера того, как этого добиться.

Для образа платформы

data "azurerm_platform_image" "2016-Datacenter" {
  location  = "West Europe"
  publisher = "MicrosoftWindowsServer"
  offer     = "WindowsServer"
  sku       = "2016-Datacenter"
}

Создайте управляемый диск с образом платформы

resource "azurerm_managed_disk" "Server-osdisk" {
  resource_group_name  = "rgroup"
  location             = "West Europe"
  create_option        = "FromImage"
  image_reference_id   = "${data.azurerm_platform_image.server2016.id}"
  disk_size_gb         = "127"
  name                 = "Server-osdisk"
  storage_account_type = "Standard_LRS"
}

Затем укажите его в azurerm_virtual_machine

resource "azurerm_virtual_machine" "main" {
  # ...

  os_profile {
    computer_name  = "Server"
    admin_username = ""
    admin_password = ""
  }

  storage_os_disk {
    managed_disk_id = "${azurerm_managed_disk.Server-osdisk.id}"

    # os_type           = "Windows"
    managed_disk_type = "Premium_LRS"
    caching           = "ReadWrite"
    create_option     = "Attach"
    name              = "Server"
  }
}

Броски

Статус =400 Code = "InvalidParameter" Message = "Обязательный параметр 'osDisk.osType' отсутствует (null)."Target = "osDisk.osType"

Если вы добавите в него os_type, вы увидите, что у вас не может быть os_profile, что необходимо для имени компьютера, имени пользователя и пароля

Peopleс той же проблемой

Terraform создает виртуальную машину из образа управляемого диска, созданного в Packer

Пробное решение, но выдает ошибку, упомянутую выше

Чего мне не хватаетна этом?

Answer 1

По вашему вопросу, я попробую разобраться.Вы меняете вещи на свои, это просто пример.Файл здесь:

resource "azurerm_resource_group" "main" {
  name = "acctestRG"
  location = "West Europe"
}

data "azurerm_platform_image" "linux" {
  location  = "West Europe"
  publisher = "Canonical"
  offer     = "UbuntuServer"
  sku       = "16.04-LTS"
}

resource "azurerm_managed_disk" "source" {
  name = "acctestmd1"
  location = "West Europe"
  resource_group_name = "${azurerm_resource_group.main.name}"
  storage_account_type = "Standard_LRS"
  create_option = "FromImage"
  image_reference_id = "${data.azurerm_platform_image.linux.id}"

  tags {
    environment = "staging"
  }
}

resource "azurerm_virtual_network" "main" {
  name                = "azuretestvnet"
  address_space       = ["10.0.0.0/16"]
  location            = "${azurerm_resource_group.main.location}"
  resource_group_name = "${azurerm_resource_group.main.name}"
}

resource "azurerm_subnet" "internal" {
  name                 = "internal"
  resource_group_name  = "${azurerm_resource_group.main.name}"
  virtual_network_name = "${azurerm_virtual_network.main.name}"
  address_prefix       = "10.0.2.0/24"
}

resource "azurerm_network_interface" "main" {
  name                = "azuretestnic"
  location            = "${azurerm_resource_group.main.location}"
  resource_group_name = "${azurerm_resource_group.main.name}"

  ip_configuration {
    name                          = "testconfiguration1"
    subnet_id                     = "${azurerm_subnet.internal.id}"
    private_ip_address_allocation = "dynamic"
  }
}

resource "azurerm_virtual_machine" "main" {
  name  = "azurevm"
  location = "West Europe"
  resource_group_name = "${azurerm_resource_group.main.name}"
  network_interface_ids = ["${azurerm_network_interface.main.id}"]
  vm_size = "Standard_DS1_v2"


  storage_os_disk {
    os_type = "Linux"
    name = "acctestmd1"
    managed_disk_type = "Standard_LRS"
    caching           = "ReadWrite"
    create_option     = "Attach"
    managed_disk_id   = "${azurerm_managed_disk.source.id}"
  }
  os_profile_linux_config {
    disable_password_authentication = false
  }
}

И есть некоторые вещи, с которыми я встречался, и я думаю, что вам следует обратить на них внимание.управляемый диск должен быть одинаковым.

имя управляемого диска должно быть одинаковым в обоих.

Надеюсь, это поможет вам.