Android - Получение нескольких ошибок при сборке проекта

Question

Я получаю эти ошибки при сборке проекта

1. Не удалось разрешить: firebase-core
2. Не удалось разрешить: multidex
3. Не удалось разрешить: play-services-ads
4. Не удалось разрешить: play-services-auth
5. Не удалось разрешить: firebase-auth-license
6. Не удалось разрешить: общие

Пожалуйста, проверьте и дайте мне знать, как решить эту проблему?

plugins {
    id 'com.onesignal.androidsdk.onesignal-gradle-plugin' version '0.8.1'
}
apply plugin: 'com.onesignal.androidsdk.onesignal-gradle-plugin'
apply plugin: 'com.android.application'

android {
    compileSdkVersion 26
    buildToolsVersion '27.0.3'
    defaultConfig {
        applicationId "com.test.android"
        minSdkVersion 15
        targetSdkVersion 26
        versionCode 3
        versionName "1.0.2"
        testInstrumentationRunner "android.support.test.runner.AndroidJUnitRunner"
        vectorDrawables.useSupportLibrary = true
        multiDexEnabled true
        manifestPlaceholders = [onesignal_app_id : "65f11821-8462-4ec4-9e41-XXXXXXXX",
                                // Project number pulled from dashboard, local value is ignored.
                                onesignal_google_project_number: "91629XXXXX00"]
    }
    buildTypes {
        release {
            minifyEnabled false
            proguardFiles getDefaultProguardFile('proguard-android.txt'), 'proguard-rules.pro'
        }
    }
    compileOptions {
        targetCompatibility 1.8
        sourceCompatibility 1.8
    }
}

dependencies {
    implementation 'com.google.firebase:firebase-auth:11.6.0'
    implementation fileTree(include: ['*.jar'], dir: 'libs')
    androidTestImplementation('com.android.support.test.espresso:espresso-core:2.2.2', {
        exclude group: 'com.android.support', module: 'support-annotations'
    })
    // applovin
    implementation project(':unity-ads')
    //unity ads
    //compile 'com.google.android.gms:play-services-ads:11.0.4'
    implementation 'com.android.support:appcompat-v7:26.+'
    implementation 'com.android.support:design:26.+'
    implementation 'com.android.support:support-vector-drawable:26.+'
    implementation 'com.android.support.constraint:constraint-layout:1.0.2'
    implementation 'com.android.support:support-v4:26.+'
    implementation 'com.google.android.gms:play-services:11.6.0'
    implementation 'com.android.support:multidex:1.0.1'
    //compile 'com.github.cooltechworks:ScratchView:v1.1'//not used
    implementation 'com.jackpocket:scratchoff:1.1.0'
    implementation 'com.adcolony:sdk:3.2.1'
    implementation 'com.android.support:support-annotations:26.0.1'
    implementation 'com.google.android.gms:play-services-ads:11.6.0'
    implementation 'com.android.support:cardview-v7:26.1.0'
    implementation 'com.facebook.android:facebook-share:[4,5)'
    testImplementation 'junit:junit:4.12'
    implementation 'com.ironsource.sdk:mediationsdk:6.7.0.1@jar'
    //compile 'com.google.ads.mediation:unity:2.1.1.0' //not used
    implementation 'com.google.firebase:firebase-database:11.6.0'
    implementation 'com.github.bumptech.glide:glide:4.1.1'
    implementation 'commons-net:commons-net:3.3'
    //get server time
    //compile 'com.github.instacart.truetime-android:library-extension-rx:2.0'
    //compile 'com.github.instacart.truetime-android:library:2.0' // not used
    implementation 'com.google.firebase:firebase-auth:11.6.0'
    implementation 'com.google.firebase:firebase-core:11.6.0'
    implementation 'com.google.android.gms:play-services-auth:11.6.0'
    implementation 'com.squareup.retrofit2:retrofit:2.3.0'
    implementation 'com.onesignal:OneSignal:[3.7.1, 3.99.99]'
    implementation files('libs/applovin-sdk-7.7.0-javadoc.jar')
    implementation files('libs/applovin-sdk-7.7.0.jar')
}
apply plugin: 'com.google.gms.google-services'

---

// Top-level build file where you can add configuration options common to all sub-projects/modules.

buildscript {
    repositories {
        jcenter()
        google()
    }
    dependencies {
        classpath 'com.android.tools.build:gradle:3.2.0-alpha09'
        classpath 'com.google.gms:google-services:3.1.0'
        // NOTE: Do not place your application dependencies here; they belong
        // in the individual module build.gradle files
    }
}

allprojects {
    repositories {
        jcenter()
        maven { url "https://maven.google.com" }
        maven { url "https://jitpack.io" }
        maven { url  "https://adcolony.bintray.com/AdColony" }
        maven { url "https://dl.bintray.com/ironsource-mobile/android-sdk" }
        google()
    }
}

task clean(type: Delete) {
    delete rootProject.buildDir
}

Answer 1

Судя по всему, jcenter начал зеркалировать репо Google .Попробуйте переместить google() до jcenter() в allprojects разделе вашего проекта build.gradle (например, так):

repositories {
    google()
    jcenter()
    maven { url "https://maven.google.com" }
    maven { url "https://jitpack.io" }
    maven { url  "https://adcolony.bintray.com/AdColony" }
    maven { url "https://dl.bintray.com/ironsource-mobile/android-sdk" }
}

Answer 2

Вы пытались пересобрать приложение?Также убедитесь, что вы используете последнюю версию GMS.В качестве идентификатора вам не нужно добавлять всю библиотеку gms, вы можете добавить выборочные сервисы.Я вижу, вы добавили gms- и gms-ads, которые уже будут включены в основной gms.