Запуск MS Word, макро-шрифт

Question

(терпение мой удар)

Какие коды для создания таблицы в MS Word, макрос?Мне нужно сделать шрифт таблицы.Если ... Тогда ... Остальное (Ахарони, В. Готика, Ариал).

Помощь?

Извините:(Могу объединить:

Answer 1

Это должно помочь вам начать

Option Explicit

Sub TestInsertTable()

    InsertTableAtSelection "Awesome", "Love," & vbCrLf & "Mum", "I miss you"

End Sub

Sub InsertTableAtSelection(LeftText As String, MidText As String, RightText As String)
' Inserts a 1 row, 3 column table at the cursor or start of the selection

Dim InsertHere                          As Word.Range
Dim my_Table                            As Word.Table
    Set InsertHere = Selection.Range
    InsertHere.Collapse direction:=wdCollapseStart
    Set my_Table = InsertHere.Tables.Add(Range:=InsertHere, numrows:=1, numcolumns:=3)

    With my_Table.Range.Cells(1).Range
        .ParagraphFormat.Alignment = wdAlignParagraphCenter
        .Text = LeftText
        .Font.Name = "Aharoni"
    End With

    With my_Table.Range.Cells(2).Range
        .ParagraphFormat.Alignment = wdAlignParagraphCenter
        .Text = MidText
        .Font.Name = "Century Gothic"
    End With

    With my_Table.Range.Cells(3).Range
        .ParagraphFormat.Alignment = wdAlignParagraphCenter
        .Text = RightText
        .Font.Name = "Arial"
    End With

    my_Table.Borders.Enable = True

End Sub