Как установить две отдельные версии приложения из студии Android?

Question

Я работаю с проектом чата Firebase от github.Я пытаюсь сделать 2 приложения, одно на стороне клиента и одно на стороне администратора.У меня есть две копии проекта с разными именами проектов и разными именами приложений.Тем не менее, я не могу запустить оба на одном устройстве с Android Studio.Запуск одного требует удаления другого.Я понимаю, что это может быть довольно простой вещью, но есть предложения?Спасибо

Answer 1

В вашем уровне приложения файл build.gradle под тегом android определяет различные варианты продукта для разных приложений.Найдите приведенный ниже код и внесите изменения в соответствии с вашим проектом.

android {
    compileSdkVersion 26
    buildToolsVersion "26.0.2"
    flavorDimensions "default"
    project.archivesBaseName = "Visualogyx";
    signingConfigs {
        release {
            storeFile file(System.getenv('KEYSTOREPATH'))
            storePassword System.getenv("VISUALOGYX_KEYSTORE_PASSWORD")
            keyAlias System.getenv("VISUALOGYX_KEYALIAS_NAME")
            keyPassword System.getenv("VISUALOGYX_KEYALIAS_PASSWORD")
        }
    }

    defaultConfig {
        applicationId "com.visualogyx.app"
        minSdkVersion 16
        targetSdkVersion 26
        testInstrumentationRunner "android.support.test.runner.AndroidJUnitRunner"
        multiDexEnabled true
        signingConfig signingConfigs.release

        ndk {
            abiFilters "armeabi-v7a"
        }
    }
    lintOptions {
        // Or, if you prefer, you can continue to check for errors in release builds,
        // but continue the build even when errors are found:
        abortOnError false
    }
    dexOptions {
        javaMaxHeapSize "4g"
        jumboMode true
    }
    productFlavors {
        dev {
            versionCode 778899
            versionName "v.1.1.BUILD_NUM"
            applicationIdSuffix ".dev"
            resValue "string", "app_name", "VisualogyxDEV"
            buildConfigField "String", "HOST", System.getenv("VISUALOGYX_HOST_DEV") 
        }
        qa {
            versionCode 778899
            versionName "v.1.0.BUILD_NUM"
            applicationIdSuffix ".qa"
            resValue "string", "app_name", "VisualogyxQA"
            buildConfigField "String", "HOST", System.getenv("VISUALOGYX_HOST_QA") 
        }
        pro {
            versionCode 778899
            versionName "v.1.0.BUILD_NUM"
            resValue "string", "app_name", "Visualogyx"
            buildConfigField "String", "HOST", System.getenv("VISUALOGYX_HOST_PRO")
        }
    }
    buildTypes {
        release {
            minifyEnabled false
            proguardFiles getDefaultProguardFile('proguard-android.txt'), 'proguard-rules.pro'

            applicationVariants.all { variant ->
                variant.outputs.all {
                    outputFileName = "Visualogyx-${variant.baseName}-${variant.versionName}.apk"
                }
            }
        }
    }
    compileOptions {
        sourceCompatibility JavaVersion.VERSION_1_8
        targetCompatibility JavaVersion.VERSION_1_8
    }
    packagingOptions {
        exclude 'META-INF/XXX'
    }
} 

Надеюсь, что это работает. Спасибо.

Answer 2

вам нужно изменить имя пакета в приложении Build.Gradle, найти applicationId и изменить имя пакета вашего проекта

, надеюсь, оно будет работать