Разве ленив в привязках у Вяза? - PullRequest
Новая
       48

Разве ленив в привязках у Вяза?

0 голосов
/ 10 октября 2018

У меня есть две функции A и B, которые могут быть обе отключены, A включена, B включена, но не обе включены одновременно.После просмотра Создание невозможных состояний невозможным Я хотел попробовать применить это на уровне типа.

Упрощенная версия решения, которое я рассматриваю, следующая: 

module Main exposing (main)

import Browser
import Html exposing (Html, button, div, text)
import Html.Events exposing (onClick)

type Model
  = NoneEnabled
  | AEnabled
  | BEnabled

init : Model
init = NoneEnabled

type Msg
  = EnableA
  | DisableA
  | EnableB
  | DisableB

view : Model -> Html Msg
view model =
  let -- Buttons to enable and disable features
      buttons =
        div [] [ button [onClick EnableA] [text "Enable A"]
               , button [onClick DisableA] [text "Disable A"]
               , button [onClick EnableB] [text "Enable B"]
               , button [onClick DisableB] [text "Disable B"]
               ]

      -- All possible feature states
      aEnabled  = div [] [text "A enabled"]
      aDisabled = div [] [text "A disabled"]
      bEnabled  = div [] [text "B enabled"]
      bDisabled = div [] [text "B disabled"]
  in case model of
       NoneEnabled ->
         div [] [buttons, aDisabled, bDisabled]
       AEnabled ->
         div [] [buttons, aEnabled, bDisabled]
       BEnabled ->
         div [] [buttons, aDisabled, bEnabled]

update : Msg -> Model -> Model
update msg model =
  case (msg, model) of
    (EnableA, _) ->
      AEnabled
    (EnableB, _) ->
      BEnabled
    (DisableA, AEnabled) ->
      NoneEnabled
    (DisableB, BEnabled) ->
      NoneEnabled
    _ ->
      model

main : Program () Model Msg
main =
  Browser.sandbox { init = init, update = update, view = view }

Мои aEnabled, aDisabled, bEnabled и bDisabled функции в view потенциально дороги для вычисления.Будут ли они оцениваться независимо от того, какую ветвь case model of принимает, или я могу полагаться только на оцениваемые используемые функции?

Или сформулирован с более коротким примером. 

f c x =
  let a = x + 1
      b = x + 2
  in case c of
       True ->
         a
       False ->
         b

Будет f True 0принудительно вычислить b в выражении let?

1 Ответ

0 голосов
/ 10 октября 2018

Вязы let / in не лениво оцениваются.Вы можете поместить несколько операторов Debug.log, чтобы доказать это: 

f c x =
  let a = Debug.log "a calculated" <| x + 1
      b = Debug.log "b calculated" <| x + 2
  in case c of
       True ->
         a
       False ->
         b

Вызов f только один раз зарегистрирует оба сообщения на консоли, независимо от ввода. Пример здесь .

Один из способов обойти это препятствие - потребовать произвольный параметр для a и b, такой как Unit (): 

f c x =
  let a () = Debug.log "a calculated" <| x + 1
      b () = Debug.log "b calculated" <| x + 2
  in case c of
       True ->
         a ()
       False ->
         b ()

Этот вариант оценивает только функцию a или b.

...