AIR SQLite ошибка с targetSdkVersion = 26

Question

У меня есть мобильное приложение (android / ios), которое отлично работает, но Google просит разработчиков использовать targetSdkVersion 26 сейчас (у меня до сих пор было 19).И теперь, когда я использую 26, у меня появляется ошибка # 3125:

SQLError: 'Error #3125: Unable to open the database file.', details:'Connection closed.', operation:'open', detailID:'1001'

Вот мой код для открытия базы данных:

static private function openDatabase(datebaseName:String) {

        sqlCon = new SQLConnection();           

        dbDir = File.documentsDirectory.resolvePath("ZANORG");
        dbDirFile = File.documentsDirectory.resolvePath("ZANORG/" + datebaseName + ".db");          

        if (dbDirFile.exists) {
            trace("File exists");
            sqlCon.addEventListener(SQLEvent.OPEN, onDatabaseOpen);
            sqlCon.open(dbDirFile);     // Error #3125 is here                      
        } else {
            trace("File does not exist");

            if (!dbDir.exists){
                trace("Folder doesn't exist > Create");
                try{
                    dbDir.createDirectory();
                }catch (error:Error){                       
                    trace("ERROR");
                    return;
                } 
            }
            sqlCon.addEventListener(SQLEvent.OPEN, onDatabaseCreationOpen);
            sqlCon.open(dbDirFile);             

            var strReq:String = "CREATE TABLE IF NOT EXISTS gamedata (Score INT)";              
            sqlquery(strReq);


            strReq = "INSERT INTO gamedata (Score) values(0)";
            sqlquery(strReq);
        }
    }

Answer 1

После поисков в течение нескольких дней я наконец-то нашел решение, это проблема с разрешениями, как сказал Органис.

Я публикую свое решение для тех, у кого возникла та же проблема, вместо того, чтобы вызывать функцию openDatabase, я вызываю этот checkDatabaseфункция:

private static function checkDatabase(databaseName:String){
        dbDirFile = File.documentsDirectory.resolvePath("ZANORG/" + databaseName + ".db");
        dbDir = File.documentsDirectory.resolvePath("ZANORG");

        if (File.permissionStatus != PermissionStatus.GRANTED){
            dbDir.addEventListener(PermissionEvent.PERMISSION_STATUS, function(e:PermissionEvent):void {
                if (e.status == PermissionStatus.GRANTED){
                    openDatabase(databaseName);
                }else{
                    // permission denied
                }
            });                  

            try {
                dbDir.requestPermission();
            }catch(e:Error){

                // another request is in progress

            }
        }else{
            openDatabase(databaseName);
        }       

    }