Delphi: дженерики и TObjectList - PullRequest
Новая
       45

Delphi: дженерики и TObjectList

1 голос
/ 29 октября 2009

Я создал класс как 

TMyClass = class(TObject)
private
  FList1: TObjectList<List1>;
  FList2: TObjectList<List2>;
public
end;

Теперь я хочу метод FillArray(Content);, который желательно реализовать один раз, то есть без перегрузки. Я полагаю, что это возможно, используя дженерики, но я слишком неопытен с этими животными, чтобы на самом деле реализовать это. У кого-нибудь есть подсказка? Заранее спасибо!

1 Ответ

3 голосов
/ 29 октября 2009

Я полагаю, что следующее будет работать только в Delphi 2010. Поскольку это зависит от объявления TArray в системном блоке, которое выглядит следующим образом: 

  TArray<T> = array of T;

Вот блок, который я разработал, чтобы помочь с преобразованиями TArray в список 

unit ListTools;

interface                
uses Generics.Collections;
type
 TListTools = class(TObject)
 public
    // Convert TList<T> to TArray<T>
    class function ToArray<T>(AList: TList<T>): TArray<T>;
    // Append Array elements in AValues to AList
    class procedure AppendList<T>(AList : TList<T>;AValues : TArray<T>);
    // Clear List and Append Values to aList
    class procedure ToList<T>(AList : TList<T>;AValues : TArray<T>);
 end;

implementation

{ TListTools }

class procedure TListTools.AppendList<T>(AList: TList<T>; AValues: TArray<T>);
var
  Element : T;
begin
  for Element in AValues do
  begin
     AList.Add(Element);
  end;
end;

class function TListTools.ToArray<T>(AList: TList<T>): TArray<T>;
// taken from rtti.pas
var
  i : Integer;
begin
  SetLength(Result, AList.Count);
  for i := 0 to AList.Count - 1 do
    Result[i] := AList[i];
end;

class procedure TListTools.ToList<T>(AList: TList<T>; AValues: TArray<T>);
begin
   AList.Clear;
   AppendList<T>(AList,AValues);
end;

end.

Поскольку TList является родительским классом для TObjectList , он должен работать с TObjectList , хотя я не пробовал его.

...