создание вложенных циклов в xslt

Question

У меня есть XML-файл. Я сталкиваюсь с проблемой при вложении раздела level = "2" в section level = "1", а также хочу, чтобы следующий элемент-брат находился внутри раздела level 1., но я не могу его получить.

Входной XML

<section level="1" counter="yes">
    <section level="2" counter="yes">
        <title>Introduction</title>
    </section>
    <para>Started the campaign with reviewing the top procedures for men.</para>
    <para>Gynecomastia (removal of breast tissue).</para>
    <section level="2" counter="yes">
        <title>Capturing the Wave</title>
    </section>
    <para>Our focus initially was to create robust website content.</para>
    <para>Started the campaign with reviewing the top procedures for men.</para>
    <section level="3" counter="yes">
        <title>Our Approach: Build the Platform</title>
    </section>
    <para>Our criteria included that each service and landing page included at least 600 words</para>
    <para>Our focus initially was to create robust website content.</para>
    <section level="4" counter="yes">
        <title>Capturing the Wave</title>
    </section>
    <para>Our content-first strategy, along with a mobile-responsive design</para>
    <para>Our focus initially was to create robust website content.</para>
</section>

Выходной XML: -

<section level="1" counter="yes">
    <section level="2" counter="yes">
        <title>Introduction</title>
        <para>Started the campaign with reviewing the top procedures for men.</para>
        <para>Gynecomastia (removal of breast tissue).</para>
    </section>
    <section level="2" counter="yes">
        <title>Capturing the Wave</title>
        <para>Our focus initially was to create robust website content.</para>
        <para>Started the campaign with reviewing the top procedures for men.</para>
        <section level="3" counter="yes">
            <title>Our Approach: Build the Platform</title>
            <para>Our criteria included that each service and landing page included at least 600 words</para>
            <para>Our focus initially was to create robust website content.</para>
            <section level="4" counter="yes">
                <title>Capturing the Wave</title>
                <para>Our content-first strategy, along with a mobile-responsive design</para>
                <para>Our focus initially was to create robust website content.</para>
            </section>
        </section>
    </section>
</section>

И xslt

    <xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:xs="http://www.w3.org/2001/XMLSchema"
    exclude-result-prefixes="xs"
    version="2.0">
    <xsl:output method="xml" encoding="UTF-8" indent="yes" omit-xml-declaration="no"/>
    <xsl:template match="@*|node()">
        <xsl:copy>
            <xsl:apply-templates select="@*|node()"/>
        </xsl:copy>
    </xsl:template>

   <xsl:template match="section[@level = '2']">
        <xsl:element name="section">
            <xsl:copy-of select="@*"/>
            <xsl:apply-templates select="child::*"/>
            <xsl:variable name="prev-level-value" select="."/>
            <xsl:for-each select="following-sibling::*:section[@level = '3']">
                <xsl:variable name="curr-level" select="@level - 1"/>
                <xsl:variable name="curr-level-value" select="preceding-sibling::*:section[@level = $curr-level][1]"/>
                <xsl:apply-templates select="self::*:section[@level = '3'][$curr-level-value = $prev-level-value]" mode="nested"/>
            </xsl:for-each>
        </xsl:element>
    </xsl:template>

    <xsl:template match="section[@level = '3']" mode="nested">
        <xsl:element name="section">
            <xsl:copy-of select="@*"/>
            <xsl:apply-templates select="child::*"/>
            <xsl:variable name="prev-level-value" select="."/>
            <xsl:for-each select="following-sibling::*:section[@level = '4']">
                <xsl:variable name="curr-level" select="@level - 1"/>
                <xsl:variable name="curr-level-value" select="preceding-sibling::*:section[@level = $curr-level][1]"/>
                <xsl:apply-templates select="self::*:section[@level = '4'][$curr-level-value = $prev-level-value]" mode="nested"/>
            </xsl:for-each>
        </xsl:element>
    </xsl:template>


    <xsl:template match="section[@level = '4']" mode="nested">
        <xsl:element name="section">
            <xsl:copy-of select="@*"/>
            <xsl:apply-templates select="child::*"/>
            <xsl:variable name="prev-level-value" select="."/>
            <xsl:for-each select="following-sibling::*:section[@level = '5']">
                <xsl:variable name="curr-level" select="@level - 1"/>
                <xsl:variable name="curr-level-value" select="preceding-sibling::*:section[@level = $curr-level][1]"/>
                <xsl:apply-templates select="self::*:section[@level = '5'][$curr-level-value = $prev-level-value]" mode="nested"/>

            </xsl:for-each>
        </xsl:element>
    </xsl:template>

    <xsl:template match="section[@level = '5']" mode="nested">
        <xsl:element name="section">
            <xsl:copy-of select="@*"/>
            <xsl:apply-templates select="child::*"/>
            <xsl:variable name="prev-level-value" select="."/>
            <xsl:for-each select="following-sibling::*:section[@level = '6']">
                <xsl:variable name="curr-level" select="@level - 1"/>
                <xsl:variable name="curr-level-value" select="preceding-sibling::*:section[@level = $curr-level][1]"/>
                <xsl:apply-templates select="self::*:section[@level = '6'][$curr-level-value = $prev-level-value]" mode="nested"/>
            </xsl:for-each>
        </xsl:element>
    </xsl:template>

    <xsl:template match="section[@level = '6']" mode="nested">
        <xsl:element name="section">
            <xsl:copy-of select="@*"/>
            <xsl:apply-templates select="child::*"/>
            <xsl:variable name="prev-level-value" select="."/>
            <xsl:for-each select="following-sibling::*:section[@level = '7']">
                <xsl:variable name="curr-level" select="@level - 1"/>
                <xsl:variable name="curr-level-value" select="preceding-sibling::*:section[@level = $curr-level][1]"/>
                <xsl:apply-templates select="self::*:section[@level = '7'][$curr-level-value = $prev-level-value]" mode="nested"/>
            </xsl:for-each>
        </xsl:element>
    </xsl:template>

</xsl:stylesheet>

Я запустил XSLT на входе xml, затем мой выводэто:

    <section level="1" counter="yes">
    <section level="2" counter="yes">
      <title>Introduction</title>
   </section>
    <para>Started the campaign with reviewing the top procedures for men.</para>
    <para>Gynecomastia (removal of breast tissue).</para>
    <section level="2" counter="yes">
      <title>Capturing the Wave</title>
      <section level="3" counter="yes">
         <title>Our Approach: Build the Platform</title>
         <section level="4" counter="yes">
            <title>Capturing the Wave</title>
         </section>
      </section>
   </section>
    <para>Our focus initially was to create robust website content.</para>
    <para>Started the campaign with reviewing the top procedures for men.</para>
    <section level="3" counter="yes">
        <title>Our Approach: Build the Platform</title>
    </section>
    <para>Our criteria included that each service and landing page included at least 600 words</para>
    <para>Our focus initially was to create robust website content.</para>
    <section level="4" counter="yes">
        <title>Capturing the Wave</title>
    </section>
    <para>Our content-first strategy, along with a mobile-responsive design</para>
    <para>Our focus initially was to create robust website content.</para>
</section>

Answer 1

Рассмотрим использование xsl:for-each-group group-starting-with и, кроме того, напишите рекурсивную функцию, которая обрабатывает вложение уровней:

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:xs="http://www.w3.org/2001/XMLSchema"
    xmlns:mf="http://example.com/mf"
    exclude-result-prefixes="#all"
    version="3.0">

  <xsl:mode on-no-match="shallow-copy"/>

  <xsl:output method="xml" indent="yes" />
  <xsl:strip-space elements="*"/>

  <xsl:function name="mf:group" as="node()*">
      <xsl:param name="nodes" as="node()*"/>
      <xsl:param name="level" as="xs:integer"/>
      <xsl:for-each-group select="$nodes" group-starting-with="section[@level = $level]">
          <xsl:choose>
              <xsl:when test="self::section[@level = $level]">
                  <xsl:copy>
                      <xsl:apply-templates select="@*, *"/>
                      <xsl:sequence select="mf:group(current-group() except ., $level + 1)"/>
                  </xsl:copy>
              </xsl:when>
              <xsl:otherwise>
                  <xsl:apply-templates select="current-group()"/>
              </xsl:otherwise>
          </xsl:choose>
      </xsl:for-each-group>
  </xsl:function>

  <xsl:template match="section[@level = 1 and @level &lt; section/@level]">
      <xsl:copy>
          <xsl:apply-templates select="@*"/>
          <xsl:sequence select="mf:group(*, 2)"/>
      </xsl:copy>
  </xsl:template>

</xsl:stylesheet>

https://xsltfiddle.liberty -development.net / 94rmq5W

Этот пример - XSLT 3 (поддерживается с 2017 года в Saxon 9.8 или более поздней версии и Altova 2017 или более поздней версии), но для процессора XSLT 2, конечно, можно указать используемое объявление xsl:mode:

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:xs="http://www.w3.org/2001/XMLSchema"
    xmlns:mf="http://example.com/mf"
    exclude-result-prefixes="#all"
    version="2.0">

    <xsl:template match="@*|node()">
        <xsl:copy>
            <xsl:apply-templates select="@*|node()"/>
        </xsl:copy>
    </xsl:template>

  <xsl:output method="xml" indent="yes" />
  <xsl:strip-space elements="*"/>

  <xsl:function name="mf:group" as="node()*">
      <xsl:param name="nodes" as="node()*"/>
      <xsl:param name="level" as="xs:integer"/>
      <xsl:for-each-group select="$nodes" group-starting-with="section[@level = $level]">
          <xsl:choose>
              <xsl:when test="self::section[@level = $level]">
                  <xsl:copy>
                      <xsl:apply-templates select="@*, *"/>
                      <xsl:sequence select="mf:group(current-group() except ., $level + 1)"/>
                  </xsl:copy>
              </xsl:when>
              <xsl:otherwise>
                  <xsl:apply-templates select="current-group()"/>
              </xsl:otherwise>
          </xsl:choose>
      </xsl:for-each-group>
  </xsl:function>

  <xsl:template match="section[@level = 1 and @level &lt; section/@level]">
      <xsl:copy>
          <xsl:apply-templates select="@*"/>
          <xsl:sequence select="mf:group(*, 2)"/>
      </xsl:copy>
  </xsl:template> 

</xsl:stylesheet>

http://xsltransform.net/jxWYjW3