outlook - всплывающий вопрос, стоит ли отмечать или нет - PullRequest
Новая
       8

outlook - всплывающий вопрос, стоит ли отмечать или нет

0 голосов
/ 14 декабря 2018

есть ли способ спросить (всплывающее окно), хочу ли я пометить письмо или нет после того, как я нажму кнопку отправки?

спасибо,

1 Ответ

0 голосов
/ 14 декабря 2018

Используйте событие Application.ItemSend , чтобы отобразить MsgBox с вопросом, отмечать или нет.

Тогда, как отмечено в в этом вопросе , вынеобходимо прослушать событие Items.ItemAdd в папке «Отправленные» и вызвать MarkAsTask для сообщения, переданного в обработчик события.

Поэтому добавьте следующий код в ThisOutlookSession - используйте Alt + F11 , чтобы вызвать редактор VB.

enter image description here

Private WithEvents Items As Outlook.Items

Private Sub Application_Startup()
    Dim SentItems As Folder
    Set SentItems = Outlook.Application.GetNamespace("MAPI").GetDefaultFolder(olFolderSentMail)
    Set Items = SentItems.Items
End Sub

Private Sub Items_ItemAdd(ByVal Item As Object)
    If TypeOf Item Is Outlook.MailItem Then
        Dim property As UserProperty
        Set property = Item.UserProperties("FlagForFollowUp")

        If property Is Nothing Then Exit Sub

        Item.MarkAsTask olMarkThisWeek
        Item.Save
    End If
End Sub

Private Sub Application_ItemSend(ByVal Item As Object, Cancel As Boolean)
    If TypeOf Item Is Outlook.MailItem Then
        Dim prompt As String
        prompt = "Would you like to flag this item?"

        If MsgBox(prompt, vbYesNo + vbQuestion, "Flag item") = vbYes Then
            Dim property As UserProperty
            Set property = Item.UserProperties.Add("FlagForFollowUp", olYesNo)
            property.Value = True
        End If
    End If
End Sub
...