Perl с XML :: LibXML Dom (Глобальный поиск и замена XML) - PullRequest
Новая
       35

Perl с XML :: LibXML Dom (Глобальный поиск и замена XML)

0 голосов
/ 14 декабря 2018

Я новичок в DOM и XML-LibXML.

Это мой пример файла mathml (XML).Мое имя файла XML - in.xml, и мне нужен конечный файл имени файла XML out.xml.Я хотел бы найти <mi>bcde</mi> и нужно изменить <mtext>pqsd</mtext> глобально и сохранить в out.xml.Как этого добиться. 

<math xmlns="http://www.w3.org/1998/Math/MathML">
    <mfrac>
         <mi>a</mi>
         <mrow>
            <mi>bcde</mi>
         </mrow>
    </mfrac>
    <msqrt>
        <mi>s</mi>
        <mi>e</mi>
        <mi>f</mi>
    </msqrt>
</math> 


#!/usr/bin/perl
use strict;
use warnings 'all';
use XML::LibXML;

my $mediaIdFrom = "MEDIAID_TEST";
my $VodItemIdFrom = "VODITEM_ID_TEST";
my $mediaId="";
my $vodItemId="";

my $filename = 'sample1.xml';
my $out_filename = "sample2.xml";

my $dom = XML::LibXML -> load_xml(location => $filename);

foreach $mediaId ($dom->findnodes('/ScheduleProvider/Episode/Media/@id')) {
    $mediaId->setValue("xx " . $mediaIdFrom . " yy");
}

foreach $vodItemId ($dom->findnodes('/ScheduleProvider/VoidItem/@id')) {
    $vodItemId->setValue($VodItemIdFrom);
}
#### for storing the output separate XML file
$dom->toFile($out_filename);`

1 Ответ

0 голосов
/ 14 декабря 2018

В вашем XML есть пространство имен, но в запросах XPath этого нет, см. Примечание под findnodes в man XML::LibXML::Node.Этот код должен работать: 

#!/usr/bin/perl
use strict;
use warnings;

use XML::LibXML;
use XML::LibXML::XPathContext;

my $dom = XML::LibXML->load_xml(string => <<'END_OF_XML');
<math xmlns="http://www.w3.org/1998/Math/MathML">
    <mfrac>
         <mi>a</mi>
         <mrow>
            <mi>bcde</mi>
         </mrow>
    </mfrac>
    <msqrt>
        <mi>s</mi>
        <mi>e</mi>
        <mi>f</mi>
    </msqrt>
</math>
END_OF_XML

my $xpc = XML::LibXML::XPathContext->new();
$xpc->registerNs('math', 'http://www.w3.org/1998/Math/MathML');

foreach my $node ($xpc->findnodes('/math:math/math:mfrac/math:mrow/math:mi', $dom)) {
    my $newNode = XML::LibXML::Element->new('mtext');
    $newNode->appendText('pqsd');

    $node->replaceNode($newNode);
}

print $dom->toString();

Вывод: 

$ perl dummy.pl
<?xml version="1.0"?>
<math xmlns="http://www.w3.org/1998/Math/MathML">
    <mfrac>
         <mi>a</mi>
         <mrow>
             <mtext>pqsd</mtext>
         </mrow>
    </mfrac>
    <msqrt>
        <mi>s</mi>
        <mi>e</mi>
        <mi>f</mi>
    </msqrt>
</math>

РЕДАКТИРОВАТЬ Возможно, я неправильно понял ваш вопрос, и вы хотите заменить все вхождения <mi>bcde</mi>?Тогда foreach изменится на 

foreach my $node ($xpc->findnodes('//math:mi[text()="bcde"]', $dom)) {

РЕДАКТИРОВАТЬ 2 , чтобы найти несколько <mi>xyz</mi> и заменить их, вы можете использовать text=replacement параметры командной строки, то есть 

foreach my $argv (@ARGV) {
    next
        unless my($find, $replace) = ($argv =~ /^([^=]+)=(.*)$/);

    foreach my $node ($xpc->findnodes(qq{//math:mi[text()="${find}"]}, $dom)) {
        my $newNode = XML::LibXML::Element->new('mtext');
        $newNode->appendText($replace);

        $node->replaceNode($newNode);
    }
}

и ваш пример замены будет 

$ perl dummy.pl bcde=pqsd

РЕДАКТИРОВАТЬ 3 заменить все <mi>xxx</mi>, где xxx имеет более одного символа на mtext: 

foreach my $node ($xpc->findnodes('//math:mi', $dom)) {
    my $text = $node->textContent();

    # strip surrounding white space from text
    $text =~ s/^\s+//;
    $text =~ s/\s+$//;

    # if text has more than one character then replace "mi" with "mtext"
    if (length($text) > 1) {
        my $newNode = XML::LibXML::Element->new('mtext');
        $newNode->appendText($text);

        $node->replaceNode($newNode);
    }
}
...