Как объединить данные из нескольких файлов Excel в один мастер-файл с помощью VBA?

Question

У меня есть несколько файлов с образцом данных. Все файлы выглядят так же, как и файл на изображении

Это моя основная структура файлов

это мой код, поэтому для

   Sub Append()
'Append data from other files
 Path = "E:\NPM PahseIII\"
 Dim c As Range
  'find the second empty cell in ColA
 Set c = ActiveSheet.Cells(Rows.Count, 1).End(xlUp).Offset(2, 0)
  Filename = Dir(Path & "*.xlsx")
     Do While Filename <> ""
If InStr(Filename, ".") > 0 Then
     Filenamenoext = Left(Filename, InStr(Filename, ".") - 1)
End If

 c.Value = Filenamenoext
   Set c = c.Offset(1, 0)

 Workbooks.Open Filename:=Path & Filename, ReadOnly:=True

ThisWorkbook.Activate
ActiveSheet.Range("B3:E6").Select
 Selection.Consolidate Sources:=Array("'" & Path & "[" & Filename & 
 "]Sheet1'!B3:B6")

Workbooks(Filename).Close
Filename = Dir()
Loop

End Sub

После запуска этого кода мой мастер-файл становится таким:

Начиная сНа втором изображении видно, что в мастер-файл записываются только имена файлов, но данные не объединяются из других файлов, я застрял в этом выпуске на целый день и не знаю, что не так с моим кодом. Во-вторых, я хочу, чтобыне должно повторяться, если я снова запускаю этот код, тогда данные не должны дублироваться, в настоящее время они дублируют данные, потому что когда я снова запускаю код, имена файлов снова записываются, начиная с нижней части предыдущей записи.в чем может быть проблема с моим текущим кодом для того, чтобы объединить данные из других файлов и не выполнять дублирование?

Answer 1

Попробуйте и посмотрите, как вы ладите.

Sub Basic_Example_1()
    Dim MyPath As String, FilesInPath As String
    Dim MyFiles() As String
    Dim SourceRcount As Long, Fnum As Long
    Dim mybook As Workbook, BaseWks As Worksheet
    Dim sourceRange As Range, destrange As Range
    Dim rnum As Long, CalcMode As Long

    'Fill in the path\folder where the files are
    MyPath = "C:\Users\Ron\test"

    'Add a slash at the end if the user forget it
    If Right(MyPath, 1) <> "\" Then
        MyPath = MyPath & "\"
    End If

    'If there are no Excel files in the folder exit the sub
    FilesInPath = Dir(MyPath & "*.xl*")
    If FilesInPath = "" Then
        MsgBox "No files found"
        Exit Sub
    End If

    'Fill the array(myFiles)with the list of Excel files in the folder
    Fnum = 0
    Do While FilesInPath <> ""
        Fnum = Fnum + 1
        ReDim Preserve MyFiles(1 To Fnum)
        MyFiles(Fnum) = FilesInPath
        FilesInPath = Dir()
    Loop

    'Change ScreenUpdating, Calculation and EnableEvents
    With Application
        CalcMode = .Calculation
        .Calculation = xlCalculationManual
        .ScreenUpdating = False
        .EnableEvents = False
    End With

    'Add a new workbook with one sheet
    Set BaseWks = Workbooks.Add(xlWBATWorksheet).Worksheets(1)
    rnum = 1

    'Loop through all files in the array(myFiles)
    If Fnum > 0 Then
        For Fnum = LBound(MyFiles) To UBound(MyFiles)
            Set mybook = Nothing
            On Error Resume Next
            Set mybook = Workbooks.Open(MyPath & MyFiles(Fnum))
            On Error GoTo 0

            If Not mybook Is Nothing Then

                On Error Resume Next

                With mybook.Worksheets(1)
                    Set sourceRange = .Range("A1:C1")
                End With

                If Err.Number > 0 Then
                    Err.Clear
                    Set sourceRange = Nothing
                Else
                    'if SourceRange use all columns then skip this file
                    If sourceRange.Columns.Count >= BaseWks.Columns.Count Then
                        Set sourceRange = Nothing
                    End If
                End If
                On Error GoTo 0

                If Not sourceRange Is Nothing Then

                    SourceRcount = sourceRange.Rows.Count

                    If rnum + SourceRcount >= BaseWks.Rows.Count Then
                        MsgBox "Sorry there are not enough rows in the sheet"
                        BaseWks.Columns.AutoFit
                        mybook.Close savechanges:=False
                        GoTo ExitTheSub
                    Else

                        'Copy the file name in column A
                        With sourceRange
                            BaseWks.cells(rnum, "A"). _
                                    Resize(.Rows.Count).Value = MyFiles(Fnum)
                        End With

                        'Set the destrange
                        Set destrange = BaseWks.Range("B" & rnum)

                        'we copy the values from the sourceRange to the destrange
                        With sourceRange
                            Set destrange = destrange. _
                                            Resize(.Rows.Count, .Columns.Count)
                        End With
                        destrange.Value = sourceRange.Value

                        rnum = rnum + SourceRcount
                    End If
                End If
                mybook.Close savechanges:=False
            End If

        Next Fnum
        BaseWks.Columns.AutoFit
    End If

ExitTheSub:
    'Restore ScreenUpdating, Calculation and EnableEvents
    With Application
        .ScreenUpdating = True
        .EnableEvents = True
        .Calculation = CalcMode
    End With
End Sub

https://www.rondebruin.nl/win/s3/win008.htm