Использование SUMIFS или FILTER для суммирования с критериями текста и даты в Google Sheets

Question

Я действительно застрял, пытаясь суммировать значение, используя несколько фильтров, один для текста и один для года.

Я пробовал две разные формулы.

=SUMIFS('Libya civcas LIVE duplicate'!AD:AD, 'Libya civcas LIVE duplicate'!L:L, "*GNA*", 'Libya civcas LIVE duplicate'!B:B, "*2012*")

Я думалSUMIFS будет работать, но я не могу распознать год как диапазон, отформатированный как дата, а не как обычный текст.Поэтому я безуспешно попробовал вариант ниже:

=SUM(FILTER('Libya civcas LIVE duplicate'!$AC$2:$AC,YEAR('Libya civcas LIVE duplicate'!$A$2:$A)=2012), REGEXMATCH("*GNA*", 'Libya civcas LIVE duplicate'!$K$2:$K))

Данные, с которыми я работаю, выглядят следующим образом:

(Column A)
DATE
13/09/2012
10/08/2013
11/08/2013
20/08/2013

(Column K)
BELLIGERENTS
LNA/GNC
GNC
Unknown

(Column AC)
STRIKES
2
2
1
3

Помощь высоко ценится.Если вам нужна дополнительная информация, просто спросите!

Answer 1

Google-таблица

=sumifs(AC$2:AC, K$2:K, "*gnc*", A$2:A, ">="&date(2012, 1, 1), A$2:A, "<"&date(2013, 1, 1))

excel

=SUMIFS(AC:AC, K:K, "*gnc*", A:A, ">="&DATE(2012, 1, 1), A:A, "<"&DATE(2013, 1, 1))

Answer 2

Вы всегда используете Sumproduct() для обработки нескольких критериев.Для этих данных:

Мы рассчитываем сумму ударов для "птиц" 12 июня 2018 года, используя:

=SUMPRODUCT(--(A2:A25=DATE(2018,6,12))*(K2:K25="bird")*(AC2:AC25))

Я считаю, что Filter() поддерживается только в электронных таблицах Google.Из вашего примера видно, что вы также хотите применить подстановочные знаки к одному из критериев.Чтобы сделать это с Sumproduct(), используйте что-то вроде:

=SUMPRODUCT(--(A2:A25=DATE(2018,6,12))*ISNUMBER(SEARCH("bird",K2:K25,1)*(AC2:AC25)))