Как загрузить файл в Mojolicious, как CGI Perl? - PullRequest
Новая
       13

Как загрузить файл в Mojolicious, как CGI Perl?

0 голосов
/ 21 февраля 2019

У меня проблема при использовании Mojo::Upload, это не то же самое, что загрузка файла CGI perl.Мне нужно прочитать строки в загруженном CSV-файле, с приведенным ниже кодом CGI, он может работать! 

my $upfile = $cgi->param('file');
my $originhead;

while(my $line = <$upfile>){
    $originhead = $line if($first_count == 0);
    $first_count++;
}

$ originhead = 'id, abc, cda' все в порядке

Для Моджо это не работает 

use Mojo::Upload;
my $upfile = $self->req->upload('file');

 my $originhead;

    while(my $line = <$upfile>){
        $originhead = $line if($first_count == 0);
        $first_count++;
    }
$originhead = null  fail

Заранее спасибо!

1 Ответ

0 голосов
/ 21 февраля 2019

Проверьте Mojo :: Upload документы.Mojo :: Upload не является файловым дескриптором;Чтобы прочитать содержимое загруженного файла, проще всего использовать метод slurp, или, если вы действительно хотите прочитать его построчно, вы можете преобразовать его в ресурс File и извлечь из него дескриптор. 

use Mojo::Base 'Mojolicious::Controller';

sub action {
  my $self = shift;
  my $upfile = $self->req->upload('file');
  my $contents = $upfile->slurp;
  my $originhead = (split /^/, $contents)[0];

  # or
  my $file = $upfile->asset->to_file;
  my $handle = $file->handle;
  my ($originhead, $first_count);
  while (my $line = <$handle>) {
    $originhead = $line unless $first_count;
    $first_count++;
  }
}

Для анализа CSV Text :: CSV обычно намного проще, чем альтернативы. 

use Text::CSV 'csv';
my $array_of_hashes = csv(in => \$contents, headers => 'auto', encoding => 'UTF-8') or die Text::CSV->error_diag;

Или для построчной обработки: 

my $csv = Text::CSV->new({binary => 1, auto_diag => 2});
binmode $handle, ':encoding(UTF-8)' or die "binmode failed: $!";
$csv->header($handle);
while (my $row = $csv->getline_hr($handle)) {
  ...
}
...