Как сформировать трехмерный массив путем распространения 1d-вектора - PullRequest
Новая
       9

Как сформировать трехмерный массив путем распространения 1d-вектора

0 голосов
/ 13 июня 2018

Частой задачей является формирование массива, который содержит переменную, возведенную в комбинацию степеней.Если p - последовательность 1,2,3, тогда я мог бы хотеть X ^ {p (k) + p (l)} для k, l = 1,2,3. Это MWE делает именно это: 

Program Main
use, intrinsic :: iso_c_binding
implicit none
integer(c_int) :: p(3)=(/0,1,0/)
integer(c_int) :: arrayP(3,3)
integer(c_int) :: krow,kcol
real(c_double) :: arrayR(3,3)
arrayP=spread(p,1,3)+spread(p,2,3)
do krow=1,3
   write(*,*)(arrayP(kcol,krow),kcol=1,3)
end do
arrayR=2.0d0**arrayP
! write array as three frames side by side
do krow=1,3
   write(*,fmt="(3(1pe10.2))")(arrayR(kcol,krow),kcol=1,3)
end do
End Program Main

Вывод: 

       0           1           0
       1           2           1
       0           1           0
1.00E+00  2.00E+00  1.00E+00
2.00E+00  4.00E+00  2.00E+00
1.00E+00  2.00E+00  1.00E+00

Мне нужно расширить это до трехмерного массива, чтобы найти X ^ {p (k) + p (l)} + p (m)} для k, l, m = 1,2,3 Очевидное расширение того, что у меня есть в MWE: 

integer(c_int) :: arrayP(3,3,3)
arrayP=spread(p,1,3)+spread(p,2,3)+spread(p,3,3)

, не работает, потому что вы не можете распределить массив в более чем n + 1 измерениях, гдеn - ранг p, в данном случае 1. Ни вопросы 21010295, ни 31573252 не решают эту проблему.Предложения?

1 Ответ

0 голосов
/ 13 июня 2018

Вы можете связать спред, как упомянуто francescalus, чтобы получить трехмерный массив (см. Ниже). 3 первых записи производят все последовательности 1, 2 и 3. Однако вы можете рассмотреть только 3 вложенных цикла, что, на мой взгляд, прощечитать. 

program test_spread
  implicit none
  integer :: a(3) = (/ 1, 2, 3 /)
  integer :: array(3,3,3)
  real    :: arrayR(3,3,3)
  integer :: i,j,k

  array = spread(spread(a, 2, 3),3,3)
  write(6,*) array(:,1,1)

  array = spread(spread(a, 1, 3),3,3)
  write(6,*) array(1,:,1)

  array = spread(spread(a, 1, 3),2,3)
  write(6,*) array(1,1,:)

  arrayR = 2.0**(                           &
     spread(spread(a, 2, 3),3,3) +           &
     spread(spread(a, 1, 3),3,3) +           &
     spread(spread(a, 1, 3),2,3))

  write(6,*) 'arrayR (1)',arrayR
  do k = 1,3
    do j = 1,3
      do i = 1,3
        arrayR(i,j,k) = 2.0**(a(i)+a(j)+a(k))
      end do
    end do
  end do

  write(6,*) 'arrayR (2)',arrayR

 end program test_spread
...