Расширение Cython не совместимо с Python2. - PullRequest
Новая
       22

Расширение Cython не совместимо с Python2.

0 голосов
/ 16 декабря 2018

Я использую Cython код расширения, но эта ошибка выброса кода: 

/Users/rkumar/src/fast-geohash/cython/_fast_geohash.pyx in _fast_geohash.encode()
     56                 ch = 0
     57
---> 58         return result[:i].decode('ascii')
     59     finally:
     60         free(result)

TypeError: Expected str, got unicode

Я не получаю эту ошибку на Python 3. Я хочу использовать это расширение на Python2.Я не знаю, как это исправить.Вот код расширения: 

cpdef str encode(double latitude, double longitude, int precision=12):
    """
    Encode a position given in float arguments latitude, longitude to
    a geohash which will have the character count precision.
    """
    cdef (double, double) lat_interval
    cdef (double, double) lon_interval
    lat_interval, lon_interval = (-90.0, 90.0), (-180.0, 180.0)
    cdef char* result = <char *> malloc((precision + 1) * sizeof(char))
    if not result:
        raise MemoryError()
    result[precision] = '\0'
    cdef int bit = 0
    cdef int ch = 0
    even = True
    cdef int i = 0
    try:
        while i < precision:
            if even:
                mid = (lon_interval[0] + lon_interval[1]) / 2
                if longitude > mid:
                    ch |= bits[bit]
                    lon_interval = (mid, lon_interval[1])
                else:
                    lon_interval = (lon_interval[0], mid)
            else:
                mid = (lat_interval[0] + lat_interval[1]) / 2
                if latitude > mid:
                    ch |= bits[bit]
                    lat_interval = (mid, lat_interval[1])
                else:
                    lat_interval = (lat_interval[0], mid)
            even = not even
            if bit < 4:
                bit += 1
            else:
                result[i] = __base32[ch]
                i += 1
                bit = 0
                ch = 0

        return result[:i].decode('ascii')
    finally:
        free(result)

1 Ответ

0 голосов
/ 16 декабря 2018

Python 2 str == Python 3 bytes

Python 2 unicode == Python 3 str.

Cython преобразует ваш C char[] в str в Python 2 и bytes в Python 3 (поскольку это наиболее логичное преобразование в обоих случаях).

В Python 2 str.decode возвращает объект unicode.Вы получаете ошибку, потому что она не соответствует объекту str в сигнатуре функции.На Python 3 bytes.decode возвращает объект str (эквивалент объекта Python 2 unicode).Это соответствует str в сигнатуре функции, и это нормально.

Самое простое решение - прекратить указывать тип возвращаемого значения в сигнатуре функции - редко можно получить большую выгоду от указания точного типаобъектов Python: 

cpdef encode(double latitude, double longitude, int precision=12):
...