Перенос текста в Outlook при использовании преобразования диапазона в HTML с Excel VBA

Question

Я пытаюсь отформатировать .HTMLbody в электронной почте таким образом, чтобы поместить изображение, содержащее диаграмму, рядом с таблицей с данными, на основе которых была создана диаграмма.

Чтобы преобразовать диапазон с данными вHTML Я использую Диапазон Рона де Брюина в HTML-код.

Моя цель - получить тело письма, как показано ниже:

Я получаю это:

Мой код.

Private Sub SendingMail()

    Dim OutApp As Object, OutMail As Object
    Dim strPic1 As String
    Dim strPic1Inserting As String
    Dim strTextOfMessage As String

    strTextOfMessage = "<p style='font-family:arial;font-size:10pt'>" & "Hello ,<br><br>Please Find Report Attached.<br><br>In case of any questions please do not hesitate to contact us." & "</p>"
    ActiveWorkbook.Worksheets("1").ChartObjects("Wykres 1").Chart.Export SCIEZKARAPORT & "TempPicture.png"
    strPic1 = SCIEZKARAPORT & "TempPicture.png"
    strPic1Inserting = "<br/>" & "<img src='cid:" & "TempPicture.png" & "' height=250 width=500>" & "<br/><br/>"

    Set OutApp = CreateObject("Outlook.Application")
    Set OutMail = OutApp.CreateItem(0)

    With OutMail
        .Display
        .To = ""
        .CC = ""
        .Subject = ""
        .Attachments.Add strPic1
        .HTMLBody = strTextOfMessage & RangetoHTML(Range("qqq")) & strPic1Inserting & "<br>" & .HTMLBody
        .Display
    End With

    Set OutMail = Nothing
    Set OutApp = Nothing
End Sub


Function RangetoHTML(rng As Range)

' Changed by Ron de Bruin 28-Oct-2006
' Working in Office 2000-2016

    Dim fso As Object
    Dim ts As Object
    Dim TempFile As String
    Dim TempWB As Workbook

    TempFile = Environ$("temp") & "\" & Format(Now, "dd-mm-yy h-mm-ss") & ".htm"

    'Copy the range and create a new workbook to past the data in
    rng.Copy
    Set TempWB = Workbooks.Add(1)
    With TempWB.Sheets(1)
        .Cells(1).PasteSpecial Paste:=8
        .Cells(1).PasteSpecial xlPasteValues, , False, False
        .Cells(1).PasteSpecial xlPasteFormats, , False, False
        .Cells(1).Select
        Application.CutCopyMode = False
        On Error Resume Next
        .DrawingObjects.Visible = True
        .DrawingObjects.Delete
        On Error GoTo 0
    End With

    'Publish the sheet to a htm file
    With TempWB.PublishObjects.Add( _
         SourceType:=xlSourceRange, _
         FileName:=TempFile, _
         Sheet:=TempWB.Sheets(1).Name, _
         Source:=TempWB.Sheets(1).UsedRange.Address, _
         HtmlType:=xlHtmlStatic)
        .Publish (True)
    End With

    'Read all data from the htm file into RangetoHTML
    Set fso = CreateObject("Scripting.FileSystemObject")
    Set ts = fso.GetFile(TempFile).OpenAsTextStream(1, -2)
    RangetoHTML = ts.readall
    ts.Close
    RangetoHTML = Replace(RangetoHTML, "align=center x:publishsource=", _
                          "align=left x:publishsource=")

    'Close TempWB
    TempWB.Close savechanges:=False

    'Delete the htm file we used in this function
    Kill TempFile

    Set ts = Nothing
    Set fso = Nothing
    Set TempWB = Nothing
End Function

Решение:
К сожалению, теги <div> у меня не сработали.Но, исследуя, почему это может быть, я обнаружил пост, в котором говорится, что теги <table> могут делать именно это.Я добился того, на что надеялся, используя следующую строку:

.HTMLBody = strTextOfMessage & "<table align='left'>" & RangetoHTML(Range("www")) & "</table>" & strPic1Inserting & "<br clear='left'><br>" & .HTMLBody