Как создать вариограммы в Excel VBA

Question

Я сделал код для создания одной диаграммы с помощью VBA Excel.Но я не могу создать код, в котором я могу создать несколько графиков на одном листе, то есть у меня есть 4 столбца, я хочу создать 4 графика.

Может ли кто-нибудь помочь мне с этой задачей?

Это мой код:

Sub create_BarChart()
   Dim myWorksheet As Worksheet
   Dim mySourceData As Range
   Dim myChart As Chart
   Dim myShape As Shape   
   Dim myChartDestination As Range
   Set myWorksheet = ThisWorkbook.Worksheets("corelacao")
   Set myChartDestination = myWorksheet.Range("D36:H45")
   Set myShape = myWorksheet.Shapes.AddChart(Excel.XlChartType.xl3DBarClustered)
   Set myChart = myShape.Chart
   With myChart
           .SetSourceData Source:=myWorksheet.Range("B1:C32")
           .ChartTitle.Text = "Analise de correlações"
           .Legend.Left = 250  'posição vertical
           .Legend.Width = 300 '100
          .Parent.Height = 200
          .Parent.Width = 269
          .Parent.Left = 95          
   End With
   With myShape
       .Height = 325 ' resize
       .Top = 300     ' reposition
       .Left = 100   ' reposition
       .Fill.ForeColor.RGB = RGB(230, 225, 220)
       .Fill.Solid
   End With
End Sub

Answer 1

Я бы указал входные диапазоны для диаграммы в переменной массива и посмотрел бы массив, чтобы сгенерировать диаграммы:

Dim arr(2) As String
Dim mySourceData As Range
Dim myChart As Chart
Dim myShape As Shape
Dim myChartDestination As Range
Dim myWorksheet As Worksheet
Set myWorksheet = ActiveSheet

'Data area for each chart
arr(1) = "B1:C32"
arr(2) = "B1:B31,D1:D31"

For a = 1 To 2
    Set myChartDestination = myWorksheet.Range("D36:H45")
    Set myShape = myWorksheet.Shapes.AddChart(Excel.XlChartType.xl3DBarClustered)
    Set myChart = myShape.Chart
    With myChart
        .SetSourceData Source:=myWorksheet.Range(arr(a))
        .ChartTitle.Text = "Analise de correlações"
        .Legend.Left = 250
        .Legend.Width = 300
        .Parent.Height = 200
        .Parent.Width = 269
        .Parent.Left = 95
    End With
    With myShape
        .Height = 325
        .Top = 300
        .Left = 100 + ((a - 1) * 250)
        .Fill.ForeColor.RGB = RGB(230, 225, 220)
        .Fill.Solid
    End With
Next