Несоответствие типов ABAP с использованием cl_salv_bs_runtime_info => get_data_ref () - PullRequest
Новая
       5

Несоответствие типов ABAP с использованием cl_salv_bs_runtime_info => get_data_ref ()

0 голосов
/ 16 октября 2018

Я нашел здесь решение, которое я пытаюсь применить. 

 cl_salv_bs_runtime_info=>set(
  EXPORTING
    display  = abap_false
    metadata = abap_false
    data     = abap_true
).

SUBMIT ('RM07MLBS')
AND RETURN.


DATA: lt_outtab TYPE STANDARD TABLE OF alv_t_t2.
FIELD-SYMBOLS: <lt_outtab> like lt_outtab.
DATA lo_data TYPE REF TO data.

TRY.
    " get data from SALV model"&nbsp;
    cl_salv_bs_runtime_info=>get_data_ref(
          IMPORTING
            r_data = lo_data
    ).
    ASSIGN lo_data->* to <lt_outtab>.
    BREAK-POINT.

  CATCH cx_salv_bs_sc_runtime_info.
ENDTRY.


return.

Источник: http://zevolving.com/2015/07/salv-table-22-get-data-directly-after-submit/

Но это не работает.Я получаю ошибку несоответствия типов в этой строке: 

ASSIGN lo_data->* to <lt_outtab>.

Что может быть не так?

Обновление: есть ли способ сделать это универсальным?Во время выполнения я не знаю, какой отчет вызывается.Приведенный выше код является лишь примером.

Обновление 2: Моя общая цель - получить отчет в формате XML (или json).

Ответы [ 2 ]

0 голосов
/ 16 октября 2018

С помощью ответа пользователя mkysoft это рабочее решение, которое экспортирует данные в формате json: 

FUNCTION /Z_FOO/CALL_REPORT_XML.
*"----------------------------------------------------------------------
*"*"Lokale Schnittstelle:
*"  EXPORTING
*"     VALUE(EV_RESULT_JSON) TYPE  STRING
*"----------------------------------------------------------------------

DATA: lo_data        TYPE REF TO data.

" Let know the model
cl_salv_bs_runtime_info=>set(
 EXPORTING
   display  = abap_false
   metadata = abap_false
   data     = abap_true
).


SUBMIT ('RM07MLBS')
   WITH WERKS = '0557'
  AND RETURN.


" get data from SALV model
cl_salv_bs_runtime_info=>get_data_ref(
      IMPORTING
        r_data = lo_data
).

field-SYMBOLS <lv_data> type any table.
ASSIGN lo_data->* TO <lv_data>.
ev_result_json = /ui2/cl_json=>serialize( data = <lv_data> pretty_name = /ui2/cl_json=>pretty_mode-low_case ).

cl_salv_bs_runtime_info=>clear_all( ).

ENDFUNCTION.

Это помогло мне сделать это: https://blogs.sap.com/2011/07/07/gain-programmatic-access-to-data-of-sapgui-alv-reports/

0 голосов
/ 16 октября 2018

Я добавил динамическую таблицу, строку и компонент в ваш код для создания рабочего примера. 

REPORT zmky_catch_report.

DATA: lo_data        TYPE REF TO data,
      lr_structdescr TYPE REF TO cl_abap_structdescr,
      lr_tabledescr  TYPE REF TO cl_abap_tabledescr,
      ls_component   TYPE abap_compdescr .
FIELD-SYMBOLS: <fs_table> TYPE table,
               <fs_line>  TYPE any,
               <fs_field> TYPE any.

" Let know the model
cl_salv_bs_runtime_info=>set(
 EXPORTING
   display  = abap_false
   metadata = abap_false
   data     = abap_true
).


SUBMIT ('RM07MLBS')
  AND RETURN.

TRY.
    " get data from SALV model
    cl_salv_bs_runtime_info=>get_data_ref(
          IMPORTING
            r_data = lo_data
    ).
    lr_tabledescr ?= cl_abap_tabledescr=>describe_by_data_ref( lo_data ).
    lr_structdescr ?= lr_tabledescr->get_table_line_type( ).

* Table header
    WRITE 'ROWNUM     '.
    LOOP AT lr_structdescr->components INTO ls_component.
      WRITE ls_component-name.
    ENDLOOP.
    ULINE.

* Lines
    ASSIGN lo_data->* TO <fs_table>.
    LOOP AT <fs_table> ASSIGNING <fs_line>.
      WRITE sy-tabix.
      LOOP AT lr_structdescr->components INTO ls_component.
        ASSIGN COMPONENT ls_component-name OF STRUCTURE <fs_line> TO <fs_field>.
        WRITE <fs_field>.
      ENDLOOP.
      WRITE /.
    ENDLOOP.

  CATCH cx_salv_bs_sc_runtime_info.
ENDTRY.
...