Для значков Research Commons мы изменили dspace-xmlui-mirage2/src/main/webapp/xsl/preprocess.xsl и перехватили рендеринг соответствующих элементов, т.е.
<!-- render frequency counts in sidebar facets as badges -->
<xsl:template match="dri:list[@id='aspect.discovery.Navigation.list.discovery']/dri:list/dri:item/dri:xref">
<xref>
<xsl:call-template name="copy-attributes"/>
<xsl:choose>
<xsl:when test="contains(text(), ' (') and contains(substring-after(text(), ' ('), ')')">
<xsl:variable name="title">
<xsl:call-template name="substring-before-last">
<xsl:with-param name="string" select="text()"/>
<xsl:with-param name="separator"><xsl:text> (</xsl:text></xsl:with-param>
</xsl:call-template>
</xsl:variable>
<xsl:variable name="count">
<xsl:call-template name="remove-parens">
<xsl:with-param name="string" select="normalize-space(substring-after(text(), $title))"/>
</xsl:call-template>
</xsl:variable>
<xsl:value-of select="$title"/>
<xsl:text> </xsl:text>
<hi rend="badge">
<xsl:value-of select="$count"/>
</hi>
</xsl:when>
<xsl:otherwise>
<xsl:apply-templates/>
</xsl:otherwise>
</xsl:choose>
</xref>
</xsl:template>
и аналогичного шаблона для текущего выбранного значения фасета (что IIRC не являетсяссылка):
<!-- better highlight active co-author/subject etc in facet list, incl show count as badge -->
<xsl:template match="dri:list[@id='aspect.discovery.Navigation.list.discovery']/dri:list/dri:item[@rend='selected']">
<item>
<xsl:call-template name="copy-attributes"/>
<xsl:attribute name="rend"><xsl:value-of select="@rend"/> disabled</xsl:attribute>
<xsl:choose>
<xsl:when test="contains(text(), ' (') and contains(substring-after(text(), ' ('), ')')">
<xsl:variable name="title">
<xsl:call-template name="substring-before-last">
<xsl:with-param name="string" select="text()"/>
<xsl:with-param name="separator"><xsl:text> (</xsl:text></xsl:with-param>
</xsl:call-template>
</xsl:variable>
<xsl:variable name="count">
<xsl:call-template name="remove-parens">
<xsl:with-param name="string" select="normalize-space(substring-after(text(), $title))"/>
</xsl:call-template>
</xsl:variable>
<xsl:value-of select="$title"/>
<xsl:text> </xsl:text>
<hi rend="badge">
<xsl:value-of select="$count"/>
</hi>
</xsl:when>
<xsl:otherwise>
<xsl:apply-templates/>
</xsl:otherwise>
</xsl:choose>
</item>
</xsl:template>
Вы увидите, что для обработки случаев, когда само значение фасета содержит круглые скобки, используется пара шаблонов утилит:
<xsl:template name="substring-before-last">
<xsl:param name="string" select="''" />
<xsl:param name="separator" select="''" />
<xsl:if test="$string != '' and $separator != ''">
<xsl:variable name="head" select="substring-before($string, $separator)" />
<xsl:variable name="tail" select="substring-after($string, $separator)" />
<xsl:value-of select="$head" />
<xsl:if test="contains($tail, $separator)">
<xsl:value-of select="$separator" />
<xsl:call-template name="substring-before-last">
<xsl:with-param name="string" select="$tail" />
<xsl:with-param name="separator" select="$separator" />
</xsl:call-template>
</xsl:if>
</xsl:if>
</xsl:template>
<xsl:template name="remove-parens">
<xsl:param name="string" select="''" />
<xsl:if test="starts-with($string, '(') and substring($string, string-length($string))=')'">
<xsl:value-of select="substring($string, 2, string-length($string) - 2)"/>
</xsl:if>
</xsl:template>
Просто добавим , что у нас есть локальные предпочтения для модификации файлов темы XSL по сравнению с изменением кода Java.Вы можете сделать это в коде Java в качестве альтернативы, но вам нужно будет работать в API DRI, например, вызывать .addHighlight("badge") вызовы методов Java вместе с addXref (DRI hi преобразуется в HTML span).См. Документацию DRI по адресу https://wiki.duraspace.org/display/DSDOC5x/DRI+Schema+Reference (для 5.x, но без изменений для 6.x).
Конвейер Cocoon - это Java, создающий DRI (XML) -> preprocess.xsl, и связанные файлы изменяют DRIи вывод по-прежнему DRI -> theme.xsl и связанные файлы преобразуют DRI в HTML.Вы пытаетесь создать HTML "слишком рано" в процессе разработки.Ваш необработанный HTML экранируется дальше по дорожке, поэтому вы видите теги на экране.