Можно ли запустить скрипт Xbase из Java во время выполнения? - PullRequest
Новая
       10

Можно ли запустить скрипт Xbase из Java во время выполнения?

0 голосов
/ 16 октября 2018

Я хочу вызвать некоторые скрипты во время выполнения из моего Java-приложения.Но я хочу скрыть внутреннюю модель от пользователя.Поэтому моя идея написать DSL с использованием Xtext.И добавьте возможность написания сценария пользователем в этом DSL, а затем выполните его в приложении.

Возможно ли это?

1 Ответ

0 голосов
/ 17 октября 2018

Об этом нет универсального учебника.Это сильно зависит от ваших правил.В вашей среде и т. Д.

приведен упрощенный пример 

grammar org.xtext.example.mydsl.MyDsl with org.eclipse.xtext.xbase.Xbase

generate myDsl "http://www.xtext.org/example/mydsl/MyDsl"

Model:
    "model" name=ID "{"
        expressions+=NamedExpression*
    "}"
;

NamedExpression:
    name=ID "=" body=XExpression
;

вывод 

/*
 * generated by Xtext 2.16.0-SNAPSHOT
 */
package org.xtext.example.mydsl.jvmmodel

import com.google.inject.Inject
import org.eclipse.xtext.xbase.jvmmodel.AbstractModelInferrer
import org.eclipse.xtext.xbase.jvmmodel.IJvmDeclaredTypeAcceptor
import org.eclipse.xtext.xbase.jvmmodel.JvmTypesBuilder
import org.xtext.example.mydsl.myDsl.Model

/**
 * <p>Infers a JVM model from the source model.</p> 
 *
 * <p>The JVM model should contain all elements that would appear in the Java code 
 * which is generated from the source model. Other models link against the JVM model rather than the source model.</p>     
 */
class MyDslJvmModelInferrer extends AbstractModelInferrer {

    /**
     * convenience API to build and initialize JVM types and their members.
     */
    @Inject extension JvmTypesBuilder

    /**
     * The dispatch method {@code infer} is called for each instance of the
     * given element's type that is contained in a resource.
     * 
     * @param element
     *            the model to create one or more
     *            {@link org.eclipse.xtext.common.types.JvmDeclaredType declared
     *            types} from.
     * @param acceptor
     *            each created
     *            {@link org.eclipse.xtext.common.types.JvmDeclaredType type}
     *            without a container should be passed to the acceptor in order
     *            get attached to the current resource. The acceptor's
     *            {@link IJvmDeclaredTypeAcceptor#accept(org.eclipse.xtext.common.types.JvmDeclaredType)
     *            accept(..)} method takes the constructed empty type for the
     *            pre-indexing phase. This one is further initialized in the
     *            indexing phase using the lambda you pass as the last argument.
     * @param isPreIndexingPhase
     *            whether the method is called in a pre-indexing phase, i.e.
     *            when the global index is not yet fully updated. You must not
     *            rely on linking using the index if isPreIndexingPhase is
     *            <code>true</code>.
     */
    def dispatch void infer(Model element, IJvmDeclaredTypeAcceptor acceptor, boolean isPreIndexingPhase) {
        // Here you explain how your model is mapped to Java elements, by writing the actual translation code.

        // An implementation for the initial hello world example could look like this:
        acceptor.accept(element.toClass("my.company.greeting."+ element.name)) [
            for (x : element.expressions) {
                members += x.toMethod(x.name, inferredType) [
                    body = x.body
                ]
            }
        ]
    }
}

вызов переводчика 

package org.xtext.example.mydsl

import org.eclipse.emf.common.util.URI
import org.eclipse.emf.ecore.resource.ResourceSet
import org.eclipse.xtext.util.CancelIndicator
import org.eclipse.xtext.util.StringInputStream
import org.eclipse.xtext.xbase.interpreter.impl.DefaultEvaluationContext
import org.eclipse.xtext.xbase.interpreter.impl.XbaseInterpreter
import org.xtext.example.mydsl.myDsl.Model

class Sample {

    def static void main(String[] args) {
        val userInput = '''
        model x {
            a = 1
            b = 1 + 2
            c = "Hello"
        }
        '''
        val injector = new MyDslStandaloneSetup().createInjectorAndDoEMFRegistration
        val resourceSet = injector.getInstance(ResourceSet)
        val resource = resourceSet.createResource(URI.createURI("dummy.mydsl"))
        resource.load(new StringInputStream(userInput), null)
        val model = resource.contents.head as Model
        val interpreter = injector.getInstance(XbaseInterpreter)
        for (g : model.expressions) {
            val ctx = new DefaultEvaluationContext
            val result = interpreter.evaluate(g.body, ctx, CancelIndicator.NullImpl)
            println(result.result)
        }
    }

}

, возможно, вам придетсянастройте интерпретатор и дополнительно поместите материал в контекст, чтобы он работал с вашим кодом.

...