VBA в Word: Как подсчитать количество абзацев в содержимом буфера обмена

Question

Я пытаюсь написать сценарий VBA, чтобы помочь мне с некоторыми повторяющимися операциями в большом документе Word.В рамках этого мне нужно знать, сколько абзацев в тексте скопировано из другого текстового документа в буфер обмена.(Шаги, которые следуют в моей предполагаемой процедуре, зависят от количества абзацев.)

Я попробовал это (см. Ниже), но застрял в моем подходе, что легко видно из моих комментариев в сценарии:

Sub InsertMultiPara()

'Declarations
   Dim MyData As MSForms.DataObject
   Dim intNumPara As Integer
   Dim strClip As Variant

'Fill them
  Set MyData = New MSForms.DataObject
  MyData.GetFromClipboard
  strClip = MyData.GetText

'Continuing my ideas... various experiments

   'OFF intNumPara = MyData.Paragraphs.Count
        'Error: "Object dosn'nt support this property or method"

   'OFF intNumPara = strClip.Paragraphs.Count
        'Error: "Object required"

'Paste the Clipboard content 
    Selection.PasteSpecial Link:=False, DataType:=wdPasteText, Placement:=wdInLine, DisplayAsIcon:=False

'Expand selection to everything just pasted:   
    Selection.MoveUp Unit:=wdParagraph, Count:=intNumPara, Extend:=wdExtend

'Do some other stuff with that range
    Application.Run MacroName:="Normal.MyMacros.Something-nice-and-useful"

End Sub

Но, как вы видите в комментариях под комментариями «OFF»: это работает не так, как я думал.

Итак, на самом деле простой вопрос: как мне реализовать подсчет прагментов для содержимого, которое находится в буфере обмена (и определенно имеет абзацы, поскольку они присутствуют при вставке содержимого буфера обмена).

Answer 1

Чтобы подсчитать абзацы содержимого в буфере обмена, используя объектную модель Word, сначала необходимо поместить это содержимое в документ Word.Буфер обмена не является частью Word и не «понимает» синтаксис Word.

Хотя это можно сделать, используйте Selection и Activate, но вместо этого более эффективно и менее "раздражает" работать с объектами Word.В этом случае объявите объект Document и установите добавляемый к нему документ.Тогда можно всегда использовать эту переменную объекта - не нужно ее активировать, не нужно использовать Documents(index) для адресации этого документа.

Кроме того, я бы хотел поместить эти шаги в отдельную процедуру, которая возвращаетколичество абзацев.Как правило, это облегчает чтение и обслуживание кода.

Например:

Function InsertAndProcessMultipleParagraphs() As Long

'Declarations    
    Dim MyData As MSForms.DataObject
    Dim intNumPara As Integer
    Dim objDoc as Word.Document
    Dim rng as Word.Range

'Fill them objects
'?Probably not needed for this approach?
'    Set MyData = New MSForms.DataObject
'    MyData.GetFromClipboard

    Set objDoc = Application.Documents.Add
    objDoc.ActiveWindow.Visible = False

'Put clipboard contents into the new document object
   Set rng = objDoc.Content
   rng.PasteSpecial Link:=False, DataType:=wdPasteText, Placement:=wdInLine, DisplayAsIcon:=False

'Read out paragraph number in that document    
    intNumPara = objDoc.Paragraphs.Count

'Close that document (without nasty questions)     
    objDoc.Close SaveChanges:=wdDoNotSaveChanges   
    InsertAndProcessMultipleParagraphs = intNumPara
End Function

Sub MacroThatUsesTheInfo
   Dim intNumPara as Long

   intNumPara = InsertAndProcessMultipleParagraphs

'Paste the Clipboard content into target document at current cursor position 
    Selection.PasteSpecial Link:=False, DataType:=wdPasteText, Placement:=wdInLine, DisplayAsIcon:=False

'Expand selection to cover all the paragraphs inserted    
    Selection.MoveUp Unit:=wdParagraph, Count:=intNumPara, Extend:=wdExtend

'Do something nice and useful with these paragraphs 
    Application.Run MacroName:="Normal.MyMacros.Do-someting-nice-and-useful"

End Sub

Answer 2

Вдохновленный комментарием Синди Мейстер (см. Выше), я нашел следующее решение (которое включает в себя сначала создание нового объекта документа Word, затем вставку в него содержимого буфера обмена, а затем считывание номера его абзаца):

Sub InsertAndProcessMultipleParagraphs()

'Declarations    
    Dim MyData As MSForms.DataObject
    Dim intNumPara As Integer
    Dim objDoc

'Fill them objects
    Set MyData = New MSForms.DataObject
    MyData.GetFromClipboard

    Set objDoc = Application.Documents.Add
    objDoc.ActiveWindow.Visible = False

'Put clipboard contents into the new document object
    Documents(objDoc).Activate
    Selection.PasteSpecial Link:=False, DataType:=wdPasteText, Placement:=wdInLine, DisplayAsIcon:=False

'Read out paragraph number in that document    
    intNumPara = Documents(objDoc).Paragraphs.Count

'Close that document (without nasty questions)     
    Documents(objDoc).Close SaveChanges:=wdDoNotSaveChanges

'By some miracle we should now be back in Word's original target window... 
'Tests show that in practice this is the case. 

'Paste the Clipboard content into target document at current cursor position 
    Selection.PasteSpecial Link:=False, DataType:=wdPasteText, Placement:=wdInLine, DisplayAsIcon:=False

'Expand selection to cover all the paragraphs inserted    
    Selection.MoveUp Unit:=wdParagraph, Count:=intNumPara, Extend:=wdExtend

'Do somethign nice and useful with these paragraphs 
    Application.Run MacroName:="Normal.MyMacros.Do-someting-nice-and-useful"

End Sub

Однако я немного разочарован тем, что мне приходится качать такой большой и тяжелый молоток, как создание целого нового объекта документа в Word только для того, чтобы сосчитать эти абзацы.Создание документа, переключение на него, вставка чего-либо, подсчет абзацев, закрытие документа ... это много операций для очень простой вещи.Нет ли еще доступного более легкого объекта, который мог бы взять содержимое буфера обмена и чей номер абзаца я мог бы тогда прочитать?

Возможно, я попробую и другой метод: подсчитать метки абзаца (возврат каретки или около того) в строке, которую можно извлечь из объекта MyData ...