Относительные пути в Терраформе - PullRequest
Новая
       33

Относительные пути в Терраформе

0 голосов
/ 19 декабря 2018

Я пытаюсь создать лямбда-функцию AWS, используя terraform.Моя директория terraform выглядит как

  • terraform
    • iam-policy
      • main.tf
    • lambda
      • files /
      • main.tf
    • main.tf

У меня внутри хранится моя лямбда-функция / terraform / lambda / files / lambda_function.py .

Всякий раз, когда я применяю terraform, у меня есть "null_resource", который выполняет некоторые команды на локальной машине, которые будут архивировать файл python 

variable "pythonfile" {
  description = "lambda function python filename"
  type        = "string"
}

resource "null_resource" "lambda_preconditions" {
  triggers {
    always_run = "${uuid()}"
  }
  provisioner "local-exec" {
    command = "rm -rf ${path.module}/files/zips"
  }
  provisioner "local-exec" {
    command = "mkdir -p ${path.module}/files/zips"
  }
  provisioner "local-exec" {
    command = "cp -R ${path.module}/files/${var.pythonfile} ${path.module}/files/zips/lambda_function.py"
  }
  provisioner "local-exec" {
    command = "cd ${path.module}/files/zips && zip -r lambda.zip ."
  }
}

Мой ресурс "aws_lambda_function" выглядит следующим образом. 

resource "aws_lambda_function" "lambda_function" {
  filename         = "${path.module}/files/zips/lambda.zip"
  function_name    = "${format("%s-%s-%s-lambda-function", var.name, var.environment, var.function_name)}"
  role             = "${aws_iam_role.iam_for_lambda.arn}"
  handler          = "lambda_function.lambda_handler"
  source_code_hash = "${base64sha256(format("%s/files/zips/lambda.zip", path.module))}", length(path.cwd) + 1, -1)}")}"
  runtime          = "${var.function_runtime}"
  timeout          = "${var.function_timeout}"
  memory_size      = "${var.function_memory}"

  environment {
    variables = {
      region      = "${var.region}"
      name        = "${var.name}"
      environment = "${var.environment}"
    }
  }

  vpc_config {
    subnet_ids         = ["${var.subnet_ids}"]
    security_group_ids = ["${aws_security_group.lambda_sg.id}"]
  }

  depends_on = [
    "null_resource.lambda_preconditions"
  ]
}

Проблема: Всякий раз, когда я изменяю файл lambda_function.py и терраформ, применяются снова, все работает нормально, ноФактический код в лямбда-функции не меняется.Также, если я удаляю все файлы состояния terraform и применяю снова, новое изменение распространяется без каких-либо проблем.

Что может быть причиной этого?

1 Ответ

0 голосов
/ 05 февраля 2019

Вместо использования null_resource я использовал источник данных archive_file, который автоматически создает zip-файл при обнаружении новых изменений.Затем я взял ссылку из данных archive_file в атрибуте лямбда-ресурса source_code_hash.

источник данных archive_file 

data "archive_file" "lambda_zip" {
  type        = "zip"
  output_path = "${path.module}/files/zips/lambda.zip"

  source {
    content  = "${file("${path.module}/files/ebs_cleanup_lambda.py")}"
    filename = "lambda_function.py"
  }
}

Ресурс лямбды 

resource "aws_lambda_function" "lambda_function" {
  filename         = "${path.module}/files/zips/lambda.zip"
  function_name    = "${format("%s-%s-%s-lambda-function", var.name, var.environment, var.function_name)}"
  role             = "${aws_iam_role.iam_for_lambda.arn}"
  handler          = "lambda_function.lambda_handler"
  source_code_hash = "${data.archive_file.lambda_zip.output_base64sha256}"
  runtime          = "${var.function_runtime}"
  timeout          = "${var.function_timeout}"
  memory_size      = "${var.function_memory}"

  environment {
    variables = {
      region      = "${var.region}"
      name        = "${var.name}"
      environment = "${var.environment}"
    }
  }

  vpc_config {
    subnet_ids         = ["${var.subnet_ids}"]
    security_group_ids = ["${aws_security_group.lambda_sg.id}"]
  }
}
...