Ваши объекты - это просто списки, вам будет сложно различать разные виды фигур.Вы можете добавить ключевое слово, тип тега перед вашими списками (например, :point, :circle и т. Д.), Чтобы лучше распределять ваши операции перемещения в соответствии с этим тегом, но тогда это будет заново изобретать колесо, или объекты.
Простые функции и списки
одна функция, которая может перемещать все фигуры
Вы можете сделать это при условии, что вы можете отправить на фактический типобъект, с которым вы работаете.move должен знать, какая форма перемещается.Измените ваши структуры данных, если вы можете добавить тип объекта в качестве CAR для ваших списков, и использовать CASE для отправки и перемещения каждого объекта по мере необходимости.
или несколько функций с одинаковымиname.
Это невозможно, по крайней мере, в одном пакете.
CLOS
(defpackage :pic (:use :cl))
(in-package :pic)
Несколько фигур имеют цвет, поэтому давайте определим класскоторые представляют объекты, которые имеют компонент цвета:
(defclass has-color ()
((color :initarg :color :accessor color)))
Если вы не знакомы с CLOS (Common Lisp Object System), вышеописанное определяет класс с именем has-color, без суперкласса и одного слота, color.Аксессор называет и общие функции чтения и записи, так что вы можете сделать (color object), чтобы получить объект, и (setf (color object) color), чтобы установить цвет объекта на цвет.:initarg используется для определения ключевого аргумента, который должен использоваться в make-instance.
Здесь ниже мы определяем point, который имеет цвет и дополнительные x и yкоординаты.
(defclass point (has-color)
((x :initarg :x :accessor x)
(y :initarg :y :accessor y)))
То же самое для круга:
(defclass circle (has-color)
((center :initarg :center :accessor center)
(radius :initarg :radius :accessor radius)))
и многоугольника:
(defclass polygon (has-color)
((points :initarg :points :accessor points)))
Наконец, изображение представляет собой последовательность форм:
(defclass picture ()
((shapes :initarg :shapes :accessor shapes)))
Вы можете сделать круг следующим образом:
(make-instance 'circle
:center (make-instance 'point :x 10 :y 30)
:color :black))
Вы также можете определить более короткие функции конструктора, если хотите.
Теперь вы можете использовать универсальныйфункция move ваших объектов.Сначала вы определяете его с помощью DEFGENERIC, который объявляет сигнатуру обобщенной функции, а также дополнительные параметры.
(defgeneric move (object dx dy)
(:documentation "Move OBJECT by DX and DY"))
Теперь вы можете добавить методов к этой универсальной функции, и ваша универсальная функция будет отправлять их на основе одного или нескольких специализаторов и / или классификаторов.
Например, вы перемещаете точку следующим образом:
(defmethod move ((point point) dx dy)
(incf (x point) dx)
(incf (y point) dy))
Вы можете видеть, что мы специализируемся move на основе класса первого параметра, здесь названного point.Метод применяется, когда значение, связанное с point, относится к классу point.Вызов INCF неявно вызывает (setf x) и (setf y), определенные выше.
Перемещение круга означает перемещение его центра:
(defmethod move ((circle circle) dx dy)
(move (center circle) dx dy))
Вы можете специализировать универсальную функцию на любомкласс, например стандартный SEQUENCE класс.Перемещает все объекты в последовательности с одинаковыми смещениями:
(defmethod move ((sequence sequence) dx dy)
(map () (lambda (object) (move object dx dy)) sequence))
Это полезно для полигонов:
(defmethod move ((polygon polygon) dx dy)
(move (points polygon) dx dy))
А также для изображений:
(defmethod move ((picture picture) dx dy)
(move (shapes picture) dx dy))
Неизменная версия
Вы также можете сделать move для создания новых экземпляров, но для этого нужно как-то сделать копии существующих объектов.Простой подход состоит в том, чтобы иметь универсальную функцию, которая заполняет целевой экземпляр экземпляром источника:
(defgeneric fill-copy (source target)
(:method-combination progn))
Комбинация методов здесь означает, что все методы, которые удовлетворяют fill-copy, выполняются, а не только самые конкретныеодин.progn предполагает, что все методы выполняются в блоке progn, один за другим.С помощью приведенного выше определения мы можем определить простую универсальную функцию copy-object:
(defgeneric copy-object (source)
(:method (source)
(let ((copy (allocate-instance (class-of source))))
(fill-copy source copy)
copy)))
. Выше определено универсальная функция с именем copy-object, а также метод по умолчанию для объекта типа T (любойобъект).ALLOCATE-INSTANCE создает экземпляр, но не инициализирует его.Метод использует FILL-COPY для копирования значений слотов.
Например, вы можете определить, как копировать слот color любого объекта, имеющего цвет:
(defmethod fill-copy progn ((source has-color) (target has-color))
(setf (color target) (color source)))
Обратите внимание, что у вас есть многократная диспетчеризация здесь: и исходный, и целевой объекты должны быть класса has-color для вызова метода.Комбинация методов progn позволяет распределить работу fill-copy между различными, не связанными друг с другом методами:
(defmethod fill-copy progn ((source point) (target point))
(setf (x target) (x source))
(setf (y target) (y source)))
Если вы дадите балл fill-copy, можно применить два метода, основанные наиерархия классов point: определенная для has-color и специализированная для класса point (для обоих аргументов).Комбинация методов progn обеспечивает выполнение обоих.
Поскольку некоторые слоты могут быть не связаны, возможно, что fill-copy завершится неудачно.Мы можем исправить это, добавив обработчик ошибок вокруг fill-copy:
(defmethod fill-copy :around (source target)
(ignore-errors (call-next-method)))
Форма (call-next-method) вызывает другие методы (те, которые определены квалификатором progn),но мы обертываем его внутрь ignore-errors.Здесь цвет не определен, но копирование выполнено успешно:
(copy-object (make-point :x 30 :y 20))
=> #<POINT {1008480D93}>
Теперь мы можем сохранить наши существующие, мутирующие, move методы и обернуть их в :around специализированный метод, который сначала делает копию:
(defmethod move :around (object dx dy)
;; copy and mutate
(let ((copy (copy-object object)))
(prog1 copy
(call-next-method copy dx dy))))
Чтобы увидеть, что происходит, определите метод для PRINT-OBJECT:
(defmethod print-object ((point point) stream)
(print-unreadable-object (point stream :identity t :type t)
(format stream "x:~a y:~a" (x point) (y point))))
И теперь перемещение точки создает новую точку:
(let ((point (make-instance 'point :x 10 :y 20)))
(list point (move point 10 20)))
=> (#<POINT x:10 y:20 {1003F7A4F3}> #<POINT x:20 y:40 {1003F7A573}>)
Вам все еще нужно изменить метод для типа SEQUENCE, который в настоящее время отбрасывает возвращаемые значения move, но, кроме этого, в существующий код мало что нужно сделать.
Обратите внимание также, что вышеупомянутый подход в основном используется как способ описания различных применений CLOS, и на практике вы, вероятно, выберете тот или иной путь для перемещения точек (изменяемые или нет), или вы должны иметьразличные функции вместо одной общей (например, mut-move и move).