Далее - как реализовать слова для доступа к битовым полям в аппаратном регистре?

Question

Я использую Forth для интерактивной отладки и автоматической инициализации аппаратного обеспечения на основе FPGA (см. https://github.com/wzab/AFCK_J1B_FORTH).В прошлый раз я начал добавлять поддержку битовых полей в регистрах, доступных через IPbus или шину Wishbone.Ниже моя реализация слов, используемых для чтения и записи битовых полей:

\ This file implements bitfield operations
\ It assumes, that we have the bus access
\ words:
\ wb@ ( address -- val )
\ wb! ( val address -- )
\ The bitfield is defined by its mask
\ (the ones correspond to the bits used by the field)
\ and by its shift (position of the LSB in the cell)

: bf@ ( address mask shift -- val )
  rot ( mask shift address )
  wb@ ( mask shift val )
  rot ( shift val mask )
  and ( shift val )
  swap ( val shift )
  rshift ( val )
;

: bf! ( val address mask shift -- )
  rot ( val mask shift address )
  >r ( val mask shift ) ( R: address )
  rot (  mask shift val ) ( R: address )
  swap (  mask val shift ) ( R: address )
  lshift ( mask val ) ( R: address )
  over ( mask val mask ) ( R: address )
  and ( mask val ) ( R: address )
  swap invert ( val ^mask ) ( R: address )
  r@ ( val ^mask address )  ( R: address )
  wb@ ( val ^mask oldval ) ( R: address )
  and ( val oldval-masked) ( R: address )
  or ( val ) ( R: address )
  r> ( val address )
  wb!
;

Представленная выше реализация, кажется, работает, однако я боюсь, что она не оптимальна.Могут ли они быть написаны умнее?Однако требуется, чтобы реализация была совместима с Swapforth, работающим на ЦП J1B .

Answer 1

Я не уверен, какое улучшение вы ожидаете.Хотя, вероятно, и быстрее, ваше определение bf! слишком монолитно, чтобы быть наподобие, и я ничего не хочу поддерживать.

Исходя из следующих предположений:

• означает совместимость с Swapforthсделать все в стеках без локальных (если вы имеете в виду что-то еще, уточните, пожалуйста)
• Предоставленные значение и маска предоставляются в том же формате, выровненном по правому краю (предполагая, что маска уже сдвинута, создает множество необоснованных комбинаций)
• Для моего окружения я остался с @ и !, вам нужно заменить их на wb@ и wb!

Я пришел к следующему коду:

\ duplicate existing bitfield information on stack
: bf_dup ( n1 n2 n3 -- n1 n2 n3 n1 n2 n3) 
    2dup 2>r ( n1 n2 n3 R: n2 n3)
    rot dup >r -rot ( n1 n2 n3 R: n2 n3 n1)
    r> 2r> ;

: bf@ ( address mask shift -- val) 2>r @ r> rshift r> and ;

: (mask-old-value) ( addr mask shift -- val) lshift invert swap @ and ;

: (trim-shift-new) ( val addr mask shift -- addr new-value )
    2>r swap 2r> ( addr val mask shift)
    -rot and  ( addr shift val_masked)
   swap lshift ;

: bf! ( val address mask shift -- ) bf_dup (mask-old-value) >r
   (trim-shift-new)
   r> or swap ! ;

Тестирование и применение этих слов намного проще при следующем определении:

  \ store address mask shift (zero-based) in this sequence
   : bitfield create rot , swap , , does> dup @ swap cell+ dup @ swap  cell+ @ ;
   hex 2018 7 3 ( address mask shift) bitfield mybitfield