Heatmap SAS некоторые метки жирным шрифтом

Question

Я пытаюсь выполнить тепловую карту на SAS с некоторыми жирными метками на оси Y.Я не нашел варианта в тепловой карте sgplot, чтобы сделать это.Я попытался использовать опцию dattrmap и создать подгруппу, но ни один из тестов, которые я выполняю, не работает.

Мой код следующий:

PROC SGPLOT DATA=mydata NOBORDER NOAUTOLEGEND dattrmap=attrheatmap;
HEATMAP X=response Y=item /colorresponse=percent discretex discretey colormodel=(white blue);
text X=response Y=item text=percent/TEXTATTRS=(color=black family="Arial") ;
YAXIS DISPLAY=(nolabel) VALUEATTRS=(Family=Arial) REVERSE;
XAXIS DISPLAY=(nolabel) VALUEATTRS=(Family=Arial);
gradlegend;RUN;

Я добавил опцию dattrmap и указал свойтаблица со следующими данными:

id   textcolor textweight value
text   Black       bold       1
text   Black      normal      2

Затем в наборе данных Mydata я указал 1 или 2 в соответствии с меткой, которая мне нужна, чтобы они были выделены жирным шрифтом, в столбце с именем «подгруппа».Я пробовал следующий тест:

text X=response Y=item text=percent/TEXTATTRS=(color=black family="Arial") textgroup=subgroup textgroupid=text;

и

HEATMAP X=response Y=item /colorresponse=percent discretex discretey colormodel=(white blue) textgroup=subgroup;

У кого-нибудь есть идея?

Answer 1

Вы не можете использовать карту атрибутов непосредственно на оси.

Лучше всего либо использовать аннотацию, либо создать ось таблица , которая это поддерживает.

См. сообщение Санджея в блоге на тему, или мой пример ниже:

data mydata;
 set sashelp.class;
 response=weight;
 item=age;
 percent = weight;
 groupid = ifn(age>13,1,2);
run;
data attrheatmap;

  input id $ textcolor $ textweight $ value;
  datalines;
 text red bold 1
 text Black normal 2
 ;;;;
 run;

PROC SGPLOT DATA=mydata NOBORDER NOAUTOLEGEND dattrmap=attrheatmap;
HEATMAP X=response Y=item /colorresponse=percent discretex discretey colormodel=(white blue);
text X=response Y=item text=percent/TEXTATTRS=(color=black family="Arial") ;
YAXIS DISPLAY=(novalues nolabel) VALUEATTRS=(Family=Arial) REVERSE;
YAXISTABLE item/position=left location=outside textgroup=groupid textgroupid=text stat=mean;
XAXIS DISPLAY=(nolabel) VALUEATTRS=(Family=Arial);
gradlegend;RUN;