Использование Select Case для ссылки на все строки в именованном диапазоне

Question

У меня есть код изменения таблицы ниже.В текущей итерации я бы указывал номера строк вручную в каждом случае, что прекрасно работает.

Число или строки для каждого случая динамически изменяются другим макросом, который вставляет или удаляет строки внутри 2 именованных диапазонов "TotalAcc"&" TotalRate ".

Есть ли способ изменить это так, чтобы регистр ссылался на все строки или ячейки в именованном диапазоне?

Заранее спасибо.

Private Sub Worksheet_Change(ByVal Target As Range)
Dim A As Range, Inte As Range, r As Range

Dim ws1 As Worksheet, ws2 As Worksheet
Set ws1 = ThisWorkbook.Worksheets(1)
Set ws2 = ThisWorkbook.Worksheets(2)

Set A = Range("TotalAcc", "TotalRate")
Set Inte = Intersect(A, Target)
If Inte Is Nothing Then Exit Sub
If Target.Columns.Count > 1 Then Exit Sub

Application.EnableEvents = False
    For Each r In Inte
        Select Case Target.Row
        Case 10, 11, 12, 13, 14, 15
            Range("A" & r.Row).Offset(0, 3).Value = Application.WorksheetFunction.SumIfs(ws2.Range("Y:Y"), ws2.Range("D:D"), ws1.Range("A" & r.Row), ws2.Range("AB:AB"), ws1.Range("B" & r.Row), ws2.Range("M:M"), ws1.Range("C" & r.Row))
            Range("A" & r.Row).Offset(0, 5).Value = Application.WorksheetFunction.SumIfs(ws2.Range("P:P"), ws2.Range("D:D"), ws1.Range("A" & r.Row), ws2.Range("AB:AB"), ws1.Range("B" & r.Row), ws2.Range("M:M"), ws1.Range("C" & r.Row))
        Case 18, 19, 20, 21
            If Range("E" & r.Row).Value <> "" Then
                Range("C" & r.Row).Value = Application.WorksheetFunction.SumIfs(ws2.Range("Y:Y"), ws2.Range("V:V"), ws1.Range("E" & r.Row))
                Range("E" & r.Row).Offset(0, -1).Value = "CONTRACTS@"
                Range("E" & r.Row).Offset(0, 1).Value = Application.WorksheetFunction.Product(Range("C" & r.Row), Range("E" & r.Row))
            Else:
                Range("C" & r.Row).Value = ""
                Range("E" & r.Row).Offset(0, -1).Value = ""
                Range("E" & r.Row).Offset(0, 1).Value = ""
            End If
        End Select
    Next r


Application.EnableEvents = True

Answer 1

Проще вот так:

For Each r In Inte
    If not Application.Intersect(r, Range("TotalAcc")) Is Nothing Then
        'is in TotalAcc
    Else
         'is in TotalRate
    End if
Next r

К вашему сведению в опубликованном вами коде:

Select Case Target.Row

, если в Target есть несколько ячеек, это будет выглядеть только для первой.Должно быть

Select Case r.Row