Перезаписать вложенный элемент списка с помощью jsonnet - PullRequest
Новая
       20

Перезаписать вложенный элемент списка с помощью jsonnet

0 голосов
/ 26 февраля 2019

У меня есть следующий json 

{
    "namespace": "monitoring",
    "name": "alok",
    "spec": {
        "replicas": 1,
        "template": {
            "metadata": "aaa",
            "spec": {
                "containers": [
                    {
                        "image": "practodev/test:test",
                        "env": [
                            {
                                "name":"GF_SERVER_HTTP_PORT",
                                "value":"3000"
                            },
                            {
                                "name":"GF_SERVER_HTTPS_PORT",
                                "value":"443"
                            },
                        ]
                    }
                ]
            }
        }
    }
}

Как мне добавить deployment_env.json, используя jsonnet? 

{
    "env": [
        {
            "name":"GF_AUTH_DISABLE_LOGIN_FORM",
            "value":"false"
        },
        {
            "name":"GF_AUTH_BASIC_ENABLED",
            "value":"false"
        },

    ]
}

Мне нужночтобы добавить его в spec.template.containers [0] .env = deploy_env.json

Я написал ниже jsonnet, чтобы сделать это.Добавляет новый элемент.Но мне нужно изменить существующий 0-й элемент контейнера в JSON. Подскажите, пожалуйста, как это сделать. 

local grafana_envs = (import 'custom_grafana/deployment_env.json');
local grafanaDeployment = (import 'nested.json') + {
    spec+: {
        template+: {
            spec+: {
                containers:+ [{
                    envs: grafana_envs.env,
                }]
            }
        }
    },
};
grafanaDeployment

Ответы [ 2 ]

0 голосов
/ 06 марта 2019

Альтернативная реализация, не полагаясь на позицию индекса массива, но вместо этого вместо значения image (что более важно, поскольку env должна пониматься реализацией изображения) 

local grafana_envs = (import 'deployment_env.json');

local TARGET_CONTAINER_IMAGE = 'practodev/test:test';

local grafanaDeployment = (import 'nested.json') + {
  spec+: {
    template+: {
      spec+: {
        containers: [
          // TARGET_CONTAINER_IMAGE identifies which container to modify
          if x.image == TARGET_CONTAINER_IMAGE
          then x { env+: grafana_envs.env }
          else x
          for x in super.containers
        ],
      },
    },
  },
};
grafanaDeployment
0 голосов
/ 26 февраля 2019

Ниже приведена реализация, которая позволяет добавлять env в существующий контейнер по его индексу в массиве containers[].

Обратите внимание, что jsonnet гораздо лучше подходит для работы с объектами (т.е.словари / карты), а не массивы, поэтому для изменения записи из соответствующего ей индекса требуется искусственная обработка через std.mapWithIndex(). 

local grafana_envs = (import 'deployment_env.json');

// Add extra_env to a container by its idx passed containers array
local override_env(containers, idx, extra_env) = (
  local f(i, x) = (
    if i == idx then x {env+: extra_env} else x
  );
  std.mapWithIndex(f, containers)
);
local grafanaDeployment = (import 'nested.json') + {
    spec+: {
        template+: {
            spec+: {
                containers: override_env(super.containers, 0, grafana_envs.env)
            }
        }
    },
};
grafanaDeployment
...